求助如何根据值加上标星号

a	t
7.8	2.1
3.2	0.4
4.6	0.5
6.2	1.2
5.7	4.7

现在想根据t值大小对a进行上标加星号的操作  
加在a变量上
如果t<=1,则加一个*
如果1<t<=2,则加两个*
如果2<t,则加三个*

加在数字的右上方
谢谢

是要这个效果吧？用VBA吧

1. Sub 按钮1_Click()
   
2.     Dim arr, brr, i&, x&, Rng As Range
   
3.     On Error Resume Next
   
4.     Set Rng = Application.Intersect(ActiveSheet.UsedRange, Application.InputBox("选择数据区域", , , , , , , 8))
   
5.     If Rng.Count < 2 Or Rng.Columns.Count <> 2 Then Exit Sub
   
6. 
   
7.     For i = 1 To Rng.Rows.Count
   
8.         If Rng(i, 2) <= 1 Then
   
9.             x = 1
   
10.         ElseIf Rng(i, 2) <= 2 Then
    
11.             x = 2
    
12.         Else
    
13.             x = 3
    
14.         End If
    
15.         Rng(i, 1) = Rng(i, 1) & String(x, "*")
    
16.         Rng(i, 1).Characters(Start:=Len(Rng(i, 1)) - x + 1, Length:=x).Font.Superscript = True
    
17.     Next
    
18.     Rng(1, 2).Resize(i - 1).NumberFormatLocal = """(""G/通用格式"")"""
    
19. End Sub

复制代码

并给t变量的数值加括号    （）

小鳄鱼a 发表于 2014-10-24 15:57
并给t变量的数值加括号    （）

这个可以设置单元格格式（自定义）来实现
(G/通用格式)

加上标星号可以用VBA来实现，楼上已经有代码了，我也写了一段
Sub jiaxing()
    Dim xrow%, n%, i%, j%
    xrow = Worksheets("sheet1").Range("a1").CurrentRegion.Rows.Count
    For n = 2 To xrow
        i = Len(Worksheets("sheet1").Cells(n, 1))
        If Worksheets("sheet1").Cells(n, 2).Value <= 1 Then
            j = 1
        ElseIf Worksheets("sheet1").Cells(n, 2).Value > 2 Then
            j = 3
        Else
            j = 2
        End If
        Worksheets("sheet1").Cells(n, 1) = Worksheets("sheet1").Cells(n, 1) & WorksheetFunction.Rept("*", j)
        Worksheets("sheet1").Cells(n, 1).Characters(Start:=i + 1, Length:=j).Font.Superscript = True
    Next
End Sub

罗浮山混球 发表于 2014-10-24 22:52
这个可以设置单元格格式（自定义）来实现
(G/通用格式)

谢谢   只是限制给5个论坛币  可以多回复几条  

罗浮山混球 发表于 2014-10-24 22:52
这个可以设置单元格格式（自定义）来实现
(G/通用格式)

请问word宏跟excel的有什么太大区别吗   如果用word好处理吗   

芐雨 发表于 2014-10-24 15:55
是要这个效果吧？用VBA吧

非常感谢   太强大了    我以前太忽视用excel了   请问word宏跟excel的有什么太大区别吗   如果用word好处理吗是否     

小鳄鱼a 发表于 2014-10-24 23:36
非常感谢   太强大了    我以前太忽视用excel了   请问word宏跟excel的有什么太大区别吗   如果用word好处 ...

word宏跟excel宏差不多，关键在于对象不一样，这个也可以用word处理。

芐雨 发表于 2014-10-25 06:28
word宏跟excel宏差不多，关键在于对象不一样，这个也可以用word处理。

程序规则跟vba是一样的吗

芐雨 发表于 2014-10-25 06:28
word宏跟excel宏差不多，关键在于对象不一样，这个也可以用word处理。

https://bbs.pinggu.org/forum.php? ... =3288023&extra=    麻烦再看下    谢谢