求SAS %Lexis宏文件

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

首先祝大家中秋节快乐！
最近老板给了一个SAS程序里面涉及到了一个宏%Lexis，我查了相关文献，据说在http://wwww.biostat.ku.dk/~bxc/Lexis/Lexis.sas上可以获得，but我怎么都进不去，google翻墙失败，
求助各位大神，在哪里可以下载到这个宏，或者哪位大神电脑里有是否可以分享一下！、
小女子谢过各位！

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏0 回帖

关键词：EXI Lex Biostat Google 中秋节快乐 SAS

是这个吗？

1. /**************************************************************************
   
2. Author: Bendix Carstensen, 1999-2002
   
3. Update: Paul Dickman, BxC, November 2003
   
4. Bug-fix: BxC, December 2007:
   
5.          If the origin= argument had missing values erroneous output would
   
6.          be generated (too much risk time). Now remedied so that
   
7.          observations with missing values of origin are excluded.
   
8. This macro is in: http://BendixCarstensen.com/Lexis/Lexis.sas
   
9. Example program:  http://BendixCarstensen.com/Lexis/xLexis.sas
   
10. ***************************************************************************/
    
11. 
    
12. %macro Lexis ( data = ,       /* Data set with original data,             */
    
13.                               /*    defaults to _last_                    */
    
14.                 out = ,       /* Where to put the result,                 */
    
15.                               /*    defaults to &data.                    */
    
16.               entry = entry,  /* Variable holding the entry date          */
    
17.                exit = exit,   /* Variable holding the exit date           */
    
18.                fail = fail,   /* Variable holding the exit status         */
    
19.                               /* If any of the entry, exit or fail        */
    
20.                               /*    variables are missing the person is   */
    
21.                               /*    discarded from the computations.      */
    
22.              breaks = ,       /* Specification of the cutpoints on        */
    
23.                               /*    the transformed scale.                */
    
24.                               /*    Syntax as for a do statement.         */
    
25.                               /*    The ONLY Mandatory argument.          */
    
26.                cens = 0,      /* Code for censoring (may be a variable)   */
    
27.               scale = 1,      /* Factor to transform from the scale       */
    
28.                               /*    of entry and exit to the scale        */
    
29.                               /*    where breaks and risk are given       */
    
30.              origin = 0,      /* Origin of the transformed scale          */
    
31.                risk = risk,   /* Variable recieving the risk time         */
    
32.               lrisk = lrisk,  /* Variable recieving the log(risk time)    */
    
33.                left = left,   /* Variable recieving left  endpoint of int */
    
34.               other = ,       /* Other dataset statements to be used such */
    
35.                               /*     as: %str( format var ddmmyy10. ; )   */
    
36.                               /*     or: %str( label risk ="P-years" ; )  */
    
37.                disc = discrd, /* Dataset holding discarded observations   */
    
38.            /*-------------------------------------------------------------*/
    
39.            /* Variables for making life-tables and other housekeeping:    */
    
40.            /* These will only appear in the output dataset if given here  */
    
41.            /* The existence of these arguments are tested in the macro so */
    
42.            /* they cannot have names that are also logical operators such */
    
43.            /* as: or, and, eq, ne, le, lt, gt.                            */
    
44.            /*-------------------------------------------------------------*/
    
45.               right = ,       /* Variable recieving right endpoint of int */
    
46.                lint = ,       /* Variable recieving interval length       */
    
47.             os_left = ,       /* Variable recieving left  endpoint of int */
    
48.            os_right = ,       /* Variable recieving right endpoint of int */
    
49.             os_lint = ,       /* Variable recieving interval length       */
    
50.                               /*    - the latter three on original scale  */
    
51.                cint = ,       /* Variable recieving censoring indicator   */
    
52.                               /*    for the current input record          */
    
53.                nint =         /* Variable recieving index of follow-up    */
    
54.                               /*       interval;                          */
    
55.               );
    
56. 
    
57. %if &breaks.= %then %put ERROR: breaks MUST be specified. ;
    
58. %if &data.  = %then %let data = &syslast. ;
    
59. %if &out.   = %then %do ;
    
60.                     %let out=&data. ;
    
61.                     %put
    
62. NOTE: Output dataset not specified, input dataset %upcase(&data.) will be overwritten. ;
    
63.                   %end ;
    
64. 
    
65. data &disc. &out. ;
    
66.   set &data. ;
    
67.   if ( nmiss ( &entry., &exit., &fail., &origin. ) gt 0 )
    
68.      then do ; output &disc. ;
    
69.                goto next ;
    
70.           end ;
    
71.   * Labelling of variables ;
    
72.   label &entry.  = 'Entry into interval' ;
    
73.   label &exit.   = 'Exit from interval' ;
    
74.   label &fail.   = 'Failure indicator for interval' ;
    
75.   label &risk.   = 'Risktime in interval' ;
    
76.   label &lrisk.  = 'Natural log of risktime in interval' ;
    
77.   label &left.   = 'Left endpoint of interval (transformed scale)' ;
    
78. %if    &right.^= %then  label &right. = 'Right endpoint of interval (transformed scale)' ; ;
    
79. %if     &lint.^= %then  label &lint. = 'Interval width (transformed scale)' ; ;
    
80. %if  &os_left.^= %then  label &os_left. = 'Left endpoint of interval (original scale)' ; ;
    
81. %if &os_right.^= %then  label &os_right. = 'Right endpoint of interval (original scale)' ; ;
    
82. %if  &os_lint.^= %then  label &os_lint. = 'Interval width (original scale)' ; ;
    
83. %if     &cint.^= %then  label &cint. = 'Indicator for censoring during the interval' ; ;
    
84. %if     &nint.^= %then  label &nint. = 'Sequential index for follow-up interval' ; ;
    
85.   &other. ;
    
86.   drop _entry_ _exit_ _fail_
    
87.        _origin_ _break_
    
88.        _cur_r _cur_l _int_r _int_l
    
89.        _first_ _cint_ _nint_;
    
90. 
    
91. /*
    
92. Temporary variables in this macro:
    
93. 
    
94.   _entry_  holds entry date on the transformed timescale
    
95.   _exit_   holds exit  date on the transformed timescale
    
96.   _fail_   holds exit  status
    
97.   _break_  current cut-point
    
98.   _origin_ origin of the time scale
    
99.   _cur_l   left  endpoint of current risk interval
    
100.   _cur_r   right endpoint of current risk interval
     
101.   _int_l   left  endpoint of current break interval
     
102.   _int_r   right endpoint of current break interval
     
103.   _first_  indicator for processing of the first break interval
     
104.   _cint_   indicator for censoring during the interval
     
105.   _nint_   sequential index of interval
     
106. 
     
107. If a variable with any of these names appear in the input dataset it will
     
108. not be present in the output dataset.
     
109. */
     
110. 
     
111.   _origin_ = &origin. ;
     
112.   _entry_  = ( &entry. - _origin_ ) / &scale. ;
     
113.   _exit_   = ( &exit.  - _origin_ ) / &scale. ;
     
114.   _fail_   = &fail. ;
     
115.   _cur_l   = _entry_ ;
     
116.   _first_  = 1 ;
     
117. 
     
118.   do _break_ = &breaks. ;
     
119.      if _first_ then do ;
     
120.         _nint_=-1;
     
121.         _cur_l = max ( _break_, _entry_ ) ;
     
122.         _int_l = _break_ ;
     
123.      end ;
     
124.      _nint_ + 1;
     
125.      _first_ = 0 ;
     
126.      _int_r = _break_ ;
     
127.      _cur_r = min ( _exit_, _break_ ) ;
     
128.      if _cur_r gt _cur_l then do ;
     
129. /*
     
130. Endpoints of risk interval are put back on original scale.
     
131. If any of left or right are specified the corresponding endpoint
     
132. of the break-interval are output.
     
133. */
     
134.         &entry.  = _cur_l * &scale. + _origin_ ;
     
135.         &exit.   = _cur_r * &scale. + _origin_ ;
     
136.         &risk.   = _cur_r - _cur_l ;
     
137.         &lrisk.  = log ( &risk. ) ;
     
138.         &fail.   = _fail_ * ( _exit_ eq _cur_r ) +
     
139.                    &cens. * ( _exit_ gt _cur_r ) ;
     
140.         _cint_   = not( _fail_ ) * ( _exit_ eq _cur_r ) ;
     
141.         %if     &left.^= %then &left.     = _int_l ; ;
     
142.         %if    &right.^= %then &right.    = _int_r ; ;
     
143.         %if     &lint.^= %then &lint.     = _int_r - _int_l ; ;
     
144.         %if  &os_left.^= %then &os_left.  = _int_l * &scale. + _origin_ ; ;
     
145.         %if &os_right.^= %then &os_right. = _int_r * &scale. + _origin_ ; ;
     
146.         %if  &os_lint.^= %then &os_lint.  = ( _int_r - _int_l ) * &scale. ; ;
     
147.         %if     &cint.^= %then &cint.     = _cint_ ; ;
     
148.         %if     &nint.^= %then &nint.     = _nint_ ; ;
     
149.         output &out. ;
     
150.      end ;
     
151.      _cur_l = max ( _entry_, _break_ ) ;
     
152.      _int_l = _break_ ;
     
153.   end ;
     
154.   next: ;
     
155. run ;
     
156. 
     
157. %mend Lexis ;

复制代码

这是个什么宏？

Arsaces 发表于 2016-9-15 23:43
是这个吗？

这是个什么宏？

Arsaces 发表于 2016-9-15 23:43
是这个吗？

多谢帮助！真是一个忧桑的宏