事件研究[sas code]

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

分享一个关于盈余公告事件的SAS code：利用国泰安数据， Follow Dellavigna, S., & Pollet, J. M. (2009) 方法。

这里完成了事件研究数据处理的工作，并计算的相关变量。但是并没有做之后的回归，回归分析我是在Stata里面做的，sas在回归结果的输出、多维固定效应回归方面没有Stata成熟。

1. /* 用中国A股数据复制 Dellavigna, S., & Pollet, J. M. (2009).
   
2. Investor inattention and friday earnings announcements.
   
3. The Journal of Finance, 64(2), 709–749. */
   
4. 
   
5. 
   
6. /*用到的数据集，来自CSMAR：
   
7.         IAR_Rept：盈余公告日期
   
8.         Trd_Index：指数交易数据
   
9.         dsf：个股交易数据
   
10.         af_forecast：分析师预测数据
    
11.         af_actual：实际盈余
    
12.         Stk_mkt_thrfacday：日度三因子数据 */
    
13. 
    
14. * 输入数据和输出数据;
    
15. libname csmar ( "F:\CSMAR\AF"  "F:\CSMAR\FAnn"  "F:\CSMAR\TR" );
    
16. libname temp "C:\Users\wang123\Desktop\temp";
    
17. 
    
18. 
    
19. * 盈余公告日期，2007-2015年年报 ;
    
20. data FAnn (drop=Reptyp label='盈余公告日期（只包括2006-2015年年报）');
    
21.         set csmar.IAR_Rept (keep=stkcd accper Annodt Reptyp
    
22.                 where=(Reptyp=4 and '01Jan2007'd<=accper<='31Dec2015'd));
    
23.         run;
    
24. 
    
25. * 建立交易日期的索引，‘2006-01-04’标记为1，下一个交易日标记为2，以此类推 ;
    
26. data tr_calendar (label='构建交易日历：将交易日和日历日建立1-1对应' drop=indexcd);
    
27.          set csmar.Trd_Index (where=(indexcd=1 and '01Jan2005'd<=Trddt<='31Dec2016'd)
    
28.                                                  keep=Trddt indexcd);
    
29. run;
    
30. 
    
31. proc sort data=tr_calendar; by Trddt; run;
    
32. 
    
33. data tr_calendar;
    
34.         set tr_calendar;
    
35.         tr_index+1;
    
36.         run;
    
37. 
    
38. * 确定事件日;
    
39. * 如果盈余公告日是交易日日，以盈余公告日作为事件日；
    
40.   如果盈余公告日在非交易日期，则取下一个交易日期为事件日，如果下一个交易日发生距公告日不超过5天 ;
    
41. proc sql;  /* cost 53 secs */
    
42.         create table evt_date as
    
43.         select a.stkcd, a.accper, a.annodt, b.trddt, b.tr_index from fann a
    
44.                 left join tr_calendar b
    
45.         on a.annodt<=b.trddt<=a.annodt+5
    
46.         group by a.stkcd, a.annodt
    
47.         having b.trddt-a.annodt=min(b.trddt-a.annodt);
    
48.         quit;
    
49. 
    
50. data evt_date (label='事件时期数据');
    
51.         set evt_date;
    
52.         rename Trddt=evtdate;
    
53.         label  
    
54.                 Stkcd='股票代码'
    
55.                 Trddt='事件日期'
    
56.                 Accper='会计截止日期'
    
57.                 tr_index='自2005年以来第i个交易日'
    
58.                 Annodt='报告公布日期';
    
59. run;
    
60. 
    
61. * 日度股票交易数据，剔除B股数据 ;
    
62. data dsf (drop=Markettype label='日各股交易数据');
    
63.         set csmar.dsf (keep=stkcd Trddt Clsprc Dretwd Markettype
    
64.                 where=('01Jan2005'd<=Trddt<='31Dec2016'd and Markettype in (1,4,16) and
    
65.                                 nmiss(stkcd, Trddt, Clsprc, Dretwd, Markettype)=0 and
    
66.                                 dretwd <0.11 and dretwd >-0.11));
    
67.         label
    
68.                 stkcd="证券代码"
    
69.                 Trddt="交易日期"
    
70.                 Clsprc="日收盘价"
    
71.                 Dretwd="考虑现金红利再投资的日个股回报率";
    
72.         run;
    
73. 
    
74. 
    
75. * 分析师预测数据过滤，形成公司-年-分析师数据：
    
76.         （1）只保留盈余公告日最近12个月的盈利预测，并且
    
77.         （2）如果一个分析师有多项预测，则仅保留最近的一次预测 ;
    
78. proc sql;
    
79.         create table af_forecast as
    
80.         select a.stkcd "股票代码", a.Fenddt "会计截止日期", a.Feps "EPS预测"
    
81.                 from csmar.af_forecast(where=('01Jan2006'd<=Fenddt<='31Dec2015'd)) a
    
82.         inner join evt_date b
    
83.         on a.stkcd=b.stkcd and a.fenddt=b.accper and
    
84.                 intnx('month', b.Annodt, -12, 'B')<a.Rptdt<b.Annodt
    
85.         where nmiss(a.stkcd, a.Fenddt, a.Feps)=0
    
86.         group by a.stkcd, a.Fenddt, a.AnanmID
    
87.                 having a.Rptdt=max(a.Rptdt);
    
88. quit;
    
89. 
    
90. 
    
91. * EPS一致预测（EPS consensus forecast），公司-年数据;
    
92. proc sql;
    
93.         create table eps_cons as  
    
94.         select stkcd, Fenddt, median(Feps) as eps_cons from af_forecast
    
95.                 group by stkcd, Fenddt;
    
96.         quit;
    
97. 
    
98. 
    
99. data af_actual (label='实际公告的EPS');
    
100.         set csmar.af_actual (keep= stkcd Ddate Meps
     
101.                 where=('01Jan2006'd<=ddate<='31Dec2015'd));
     
102.         run;
     
103. 
     
104. * 盈余公告日前5个交易日收盘价，作为SUE的分母;
     
105. proc sql;
     
106.         create table prc as
     
107.         select a.stkcd, a.accper, b.Clsprc as prc '基准收盘价'
     
108.         from evt_date a
     
109.                 inner join Tr_calendar c
     
110.         on a.tr_index-5=c.tr_index   
     
111.                 inner join dsf b
     
112.         on a.stkcd=b.stkcd and b.Trddt=c.Trddt;
     
113.         quit;
     
114. 
     
115. * 盈余惊喜（earnings surprise）;
     
116. proc sql;
     
117.         create table sue as
     
118.         select a.stkcd, a.fenddt, (a.eps_cons-b.Meps)/c.prc as sue "盈余惊喜" from eps_cons a
     
119.                 inner join af_actual b
     
120.         on a.stkcd=b.stkcd and a.fenddt=b.ddate
     
121.                 inner join prc c
     
122.         on a.stkcd=c.stkcd and a.fenddt=c.Accper
     
123.         where not missing(calculated sue);
     
124.         quit;
     
125. 
     
126. 
     
127. * 事件研究估计窗口选择，取[-280, -34];
     
128. proc sql;
     
129.         create table pre_event as
     
130.         select a.stkcd, a.accper, b.Dretwd,
     
131.                    d.RiskPremium1 as rm, d.SMB1 as smb, d.HML1 as hml from evt_date a
     
132.         left join tr_calendar c
     
133.                 on a.tr_index-280 <=c.tr_index<=a.tr_index -34
     
134.         left join dsf b
     
135.                 on b.Trddt=c.Trddt and b.stkcd=a.stkcd
     
136.         left join csmar.Stk_mkt_thrfacday (keep=TradingDate RiskPremium1 SMB1 HML1 MarkettypeID   
     
137.                                                                            where=(MarkettypeID='P9709')) d
     
138.                 on b.Trddt=d.TradingDate
     
139.         where nmiss(Dretwd, rm, smb, hml)=0
     
140.         order by stkcd, accper;
     
141. quit;
     
142. 
     
143. 
     
144. /* 对每个事件，计算三因子模型的因子载荷 */
     
145. proc printto log=junk; run;
     
146. proc reg data=pre_event noprint outest=ff_est edf;
     
147.         by stkcd accper;
     
148.         model Dretwd = rm smb hml;
     
149.         quit;
     
150. proc printto; run;
     
151. 
     
152. data ff_est;
     
153.         set ff_est;
     
154.         obs=_EDF_+_P_;
     
155.         keep stkcd accper Intercept rm smb hml obs _RMSE_;
     
156.         if obs>120;                        /* 要求估计窗口的交易日期至少达到120天 */
     
157.         label Intercept="截距项估计值"
     
158.                   rm="市场因子系数"
     
159.                   smb="市值因子系数"
     
160.                   hml="价值因子系数"
     
161.                   obs="估计所用样本数目"
     
162.                   _RMSE_="标准误（se）";
     
163.         run;
     
164. 
     
165. 
     
166. * 利用事件前窗口估计所得系数，建立基准资产组合的收益率
     
167.         估计[0,75]的AR, CAR, BHAR;
     
168. proc sql;
     
169. create table post_event as
     
170.     select a.stkcd, a.accper, a.annodt, a.evtdate,
     
171.                    c.tr_index-a.tr_index as re_date "相对于事件日的相对交易日", b.Dretwd,
     
172.                    e.Intercept+e.rm*d.RiskPremium1+e.smb*d.SMB1+e.hml*d.HML1
     
173.                    as ret_bench "由三因子模型确定的基准收益率" from evt_date a
     
174.         left join tr_calendar c
     
175.                 on a.tr_index <=c.tr_index<=a.tr_index +75
     
176.         left join dsf b
     
177.                 on b.Trddt=c.Trddt and b.stkcd=a.stkcd
     
178.         left join csmar.Stk_mkt_thrfacday (keep=TradingDate RiskPremium1 SMB1 HML1 MarkettypeID   
     
179.                                                                            where=(MarkettypeID='P9709')) d
     
180.                 on b.Trddt=d.TradingDate
     
181.         left join ff_est e
     
182.                 on a.stkcd=e.stkcd and a.accper=e.accper
     
183.         where nmiss(Dretwd, calculated ret_bench)=0
     
184.         order by stkcd, accper, re_date;
     
185. quit;
     
186. 
     
187. data evt_stat (keep=stkcd accper re_date bhar label='时间研究所得的异常收益，个股层面');
     
188.         set post_event;
     
189.         by stkcd accper;
     
190.         ar=Dretwd-ret_bench;
     
191.         retain cumret cumbenchret car;
     
192.         cumret=cumret*(1+Dretwd);
     
193.         cumbenchret=cumbenchret*(1+ret_bench);
     
194.         car=car+ar;
     
195.         if first.accper then do;
     
196.                 car=ar;
     
197.                 cumret=1+Dretwd;
     
198.                 cumbenchret=1+ret_bench;
     
199.         end;
     
200.         bhar=cumret-cumbenchret;
     
201. run;
     
202. 
     
203. 
     
204. data evt_car (label="股价的短期和长期反应"
     
205.                            where=(nmiss(bhar_s, bhar_all)=0));
     
206.         merge evt_stat (rename=(bhar=bhar_s) where=(re_date=1))
     
207.                   evt_stat (rename=(bhar=bhar_all) where=(re_date=75));
     
208.         by stkcd accper;
     
209.         run;
     
210. 
     
211. data evt_car;
     
212.         set evt_car;
     
213.         bhar_l=(bhar_all+1)/(bhar_s+1)-1;
     
214.         label bhar_s="股价的短期反应BHAR[0, 1]"
     
215.           bhar_all="股价的全部反应[0,75]"
     
216.                   bhar_l="股价的短期反应BHAR[2, 75]";
     
217.         run;
     
218. 
     
219. * 和原文不同，我们对比在周五、周六(我们样本中周日没有公告)相对于周内公告的情况
     
220.         因为美国在周末几乎没有公告，国内周六公告仍然较多;
     
221. proc sql;
     
222.         create table evt_car as
     
223.         select a.*, weekday(b.Annodt)-1 as dayinweek "用1-7代指周一至周日",
     
224.                 weekday(b.Annodt) in (1, 6, 7) as weekend "周末公告的虚拟变量",
     
225.                 c.sue from evt_car a
     
226.         inner join fann b on a.stkcd=b.stkcd and a.accper=b.accper
     
227.         inner join sue c on a.stkcd=c.stkcd and a.accper=c.fenddt;
     
228. quit;
     
229. 
     
230. proc freq data=evt_car;
     
231.         tables dayinweek  accper*weekend / nopercent nocol norow nocum;
     
232. run;
     
233. 
     
234. 
     
235. * 在每年，分别对“周末公告组”和“周内公告组”按照盈余惊喜从小到大分成10组;
     
236. proc sort data=evt_car; by accper weekend; run;
     
237. 
     
238. proc rank data=evt_car groups=10 out=car_by_sue;
     
239.         by accper weekend;
     
240.         var sue;
     
241.         ranks sue_rank;
     
242.         run;
     
243. 
     
244. data car_by_sue (label='按照SUE分组的盈余公告异常收益');
     
245.         set car_by_sue;
     
246.         sue_rank+1;
     
247.         run;
     
248. 
     
249. proc sql;
     
250.         create table caar as
     
251.         select weekend, sue_rank "SUE组合，10为盈余最高",
     
252.                 mean(bhar_s) as bhaar_s "每组平均BHAR[0,1]",
     
253.                 mean(bhar_l) as bhaar_l "每组平均BHAR[2,75]",
     
254.                 mean(bhar_all) as bhaar_all "每组平均BHAR[0,75]",
     
255.                 mean(sue) as sue_avg "每组平均SUE"
     
256.         from car_by_sue
     
257.         group by weekend, sue_rank;
     
258.         quit;
     
259. 
     
260. 
     
261. * 画图pp721-722;
     
262. 
     
263. proc sgplot data=caar;
     
264.         series x=sue_rank y=bhaar_s / group=weekend;
     
265.         refline 0 / axis=x;
     
266. run;
     
267. 
     
268. proc sgplot data=caar;
     
269.         series x=sue_rank y=bhaar_l / group=weekend;
     
270. run;
     
271. 
     
272. proc sgplot data=caar;
     
273.         series x=sue_avg y=bhaar_l / group=weekend;
     
274. run;

复制代码

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏2 回帖

41行到48行的proc sql为什么没有from指令呀？
有点儿看不懂。
a b的数据集是不是都没有标示出来

github上抄来的吧