Tobit Model with Multiplicative Heteroskedasticity
* References:
* The data set and application of the Tobit model is presented in:
* Ernst R. Berndt, The Practice of Econometrics, Addison-Wesley, 1991.
* Chapter 11, Exercise 4, pp. 657-658.
* For Multiplicative Heteroskedasticity in the Tobit Model see:
* W.H. Greene, Econometric Analysis, Fourth Edition, 2000.
* Chapter 20, Example 20.11, p. 913
SAMPLE 1 753
READ (mroz.txt) / NAMES
* Analyze wife's property income
GENR PRIN=(FAMINC-WW*WHRS)/1000
GENR WA2=WA*WA
DIM LWW 753
* Restrict the sample to those who work
SAMPLE 1 428
GENR LWW=LOG(WW)
* Estimate a wage determination equation
OLS LWW WA WA2 WE CIT AX
* Estimate a predicted wage for non-workers
FC / PREDICT=LWW BEG=429 END=753
* TOBIT estimation
SAMPLE 1 753
TOBIT WHRS LWW PRIN KL6 K618 WA WE / COEF=ALPHA
* Get the regression coefficients
GEN1 SIGMA=SQRT($SIG2)
SAMPLE 1 7
GENR BHAT=ALPHA*SIGMA
* Now use the NL command for maximum likelihood estimation to
* replicate the results of the TOBIT command.
* First, use OLS to set some starting values for the estimation.
* Restrict the sample to those who work
SAMPLE 1 428
DIM BCON 8
OLS WHRS LWW PRIN KL6 K618 WA WE / HETCOV COEF=BETA
GEN1 BCON:8=SQRT($SIG2)
* Calculate the Goldberger-Greene adjusted estimates as
* suggested in Berndt, Exercise 4 (b), p. 657.
* Proportion working
GEN1 P=428/753
PRINT P
SAMPLE 1 7
GENR BCON=BETA/P
PRINT BHAT BETA BCON
* Define an equation in a SHAZAM character string.
* Description of character strings is in the chapter SHAZAM PROCEDURES
* in the SHAZAM User's Reference Manual.
* Note that the expression is enclosed by brackets -- this is to
* ensure correct evaluation of the expression when it is used later on
* the EQ command.
XB:(B1*LWW+B2*PRIN+B3*KL6+B4*K618+B5*WA+B6*WE+B0)
SAMPLE 1 753
GENR const=-LOG(2*$PI)
* Set LIMIT=1 when WHRS > 0 and LIMIT=0 otherwise
GENR LIMIT=DUM(WHRS)
* On the NL command, the LOGDEN option specifies that the log-density
* of a single observation is entered on the EQ command.
* See Greene, Equation (20-13), p. 911.
* Note that the use of this option requires careful checking and
* testing of both the specification of the log-likelihood function
* and the SHAZAM commands that program the formula.
* NCDF(z) is the standard normal cumulative distribution function.
* Starting values are specified with the START= option on the NL command.
DIM BTOBIT 14
NL 1 / NCOEF=8 LOGDEN START=BCON COEF=BTOBIT
EQ (1-LIMIT)*LOG(1-NCDF([XB]/sig))+ &
LIMIT*(const-LOG(sig**2)-((WHRS-[XB])/sig)**2)/2
END
* The value of the log-likelihood function is available in the
* temporary variable $LLF.
GEN1 LLF0=$LLF
* Now specify the form of the variance equation for a model
* with Multiplicative Heteroskedasticity - see Greene, p. 913.
SIG:(A0*(EXP(A1*LWW+A2*PRIN+A3*KL6+A4*K618+A5*WA+A6*WE)**(1/2)))
* Estimation of the Tobit Model with Multiplicative Heteroskedasticity.
* The starting values are the coefficient estimates from the
* previous Tobit estimation - note that the value of the
* log-likelihood function at the first iteration is identical
* to the Tobit log-likelihood function value.
NL 1 / NCOEF=14 LOGDEN START=BTOBIT
EQ (1-LIMIT)*LOG(1-NCDF([XB]/[SIG]))+ &
LIMIT*(const-LOG([SIG]**2)-((WHRS-[XB])/[SIG])**2)/2
END
GEN1 LLF1=$LLF
* Likelihood ratio test statistic for heteroskedasticity
GEN1 LR=2*(LLF1-LLF0)
* Calculate p-value for the test
SAMPLE 1 1
DISTRIB LR / TYPE=CHI DF=6 CDF=cdf
GEN1 p_value=1-cdf
PRINT LR p_value
STOP
[此贴子已经被作者于2006-4-28 2:28:22编辑过]