根据aaa1和aaa2数据集如何得到这样的数据集

1. data aaa1;
   
2. input x;
   
3. cards;
   
4. 2
   
5. 3
   
6. 4
   
7. ;
   
8. run;
   
9. 
   
10. data aaa2;
    
11. input _x;
    
12. cards;
    
13. 1
    
14. ;
    
15. run;

复制代码

根据aaa1和aaa2数据集如何得到这样的数据集：
x _x
2  1
3  1
4  1

谢谢！

1. data want;
   
2.   set aaa1;
   
3.   if _n_=1 then set aaa2;
   
4. run;

复制代码

在 DATA 步中，仅有通过 INPUT 语句读取的新变量，或通过赋值语句新衍生的变量，会在隐性循环中被初始化为缺失值， 通过 SET、MERGE、UPDATE、MODIFY 语句读取的变量都不会被初始化。因此，相比两年前的答案，我们可以进一步地省去 RETAIN 语句。

1. data aaa1_by;
   
2.       set aaa1;
   
3.       key = 1;
   
4. run;
   
5. 
   
6. data aaa2_by;
   
7.       set aaa2;
   
8.       key = 1;
   
9. run;
   
10. 
    
11. data out;
    
12.       merge aaa1_by aaa2_by;
    
13.       by key;
    
14.       drop key;
    
15. run;

复制代码

1. data aaa1;
   
2. input x;
   
3. cards;
   
4. 2
   
5. 3
   
6. 4
   
7. ;
   
8. run;
   
9. 
   
10. data aaa2;
    
11. input _x;
    
12. cards;
    
13. 1
    
14. ;
    
15. run;
    
16. proc sql;
    
17.         create table want as
    
18.         select a.*, b.*
    
19.         from aaa1 as a
    
20.         left join aaa2 as b on 1=1
    
21. ;
    
22. quit;

复制代码

如果可以用proc sql， 那么代码可以更简单一点(目标输出是aaa1和aaa2的Cartesian product)：

1. proc sql;
   
2.     create table out as
   
3.         select aaa1.*, aaa2.*
   
4.         from aaa1, aaa2
   
5.     ;
   
6. quit;

复制代码

你在两年前问过这个问题：https://bbs.pinggu.org/forum.php?mod=viewthread&tid=10526341

whymath 发表于 2023-5-25 10:53
你在两年前问过这个问题：https://bbs.pinggu.org/forum.php?mod=viewthread&tid=10526341

我记得data步应该有好方法，记不清啦，论坛无法检索我在SAS版块发的所有主题帖。

whymath 发表于 2023-5-25 11:17

data want;

  set aaa1;

  if _n_=1 then set aaa2;

run;

在 DATA 步中，仅有通过 INPUT 语句读取的新变量，或通过赋值语句新衍生的变量，会在隐性循环中被初始化为缺失值， 通过 SET、MERGE、UPDATE、MODIFY 语句读取的变量都不会被初始化。因此，相比两年前的答案，我们可以进一步地省去 RETAIN 语句。

能否解释下data步运行机制，谢谢！

dxystata 发表于 2023-5-25 12:38
能否解释下data步运行机制，谢谢！

http://documentation.sas.com/doc ... 7n14h8x7y7u34y4.htm

whymath 发表于 2023-5-25 10:53
你在两年前问过这个问题：https://bbs.pinggu.org/forum.php?mod=viewthread&tid=10526341

记性还是非常好的