将宏变量中的标点符号全部变成空格

我想做一个筛选药物分类的程序，其中第一步列举了要筛选药物的商品名等，
但是各药物之间以各种符号隔开，有全角也有半角，有逗号，括号，顿号等
我建立了一个宏变量如下：

%let drugname=%nrstr(普萘洛尔(心得安),美托洛尔(倍他乐克)，阿替洛尔(氨酰心安),比索洛尔（康可）,
卡维地洛、拉贝洛尔
氨酰心安、美多心安、醋丁酰心安, 心得静、甲磺胺心安、噻吗心安、柳胺苄心安, 维拉帕米(异搏定，
戊脉安，凡拉帕米，异搏停)，
地尔硫卓(恬尔心、硫氮卓酮、合心爽、蒂尔丁)，狄戈辛，地毒,拉诺辛;强心素,异羟基洋地黄毒甘,地高辛,异羟基洋地黄毒甙);
%put &drugname;


现在想新生成一个宏变量，将drugname中的所有符号变成"|"或者是空格，并且多个相邻的｜或空格变成一个，
如何处理，谢谢各位。

%let drugname=%nrstr(普萘洛尔(心得安),美托洛尔(倍他乐克),;强心素,异羟基洋地黄毒甘,地高辛,异羟基洋地黄毒甙);
%put &drugname;

data kk;
length name $300.;
name=prxchange("s/[()、;,，]+/｜/",-1,"&drugname");
run;

结果
普萘洛尔｜心得安｜美托洛尔｜倍他乐克｜强心素｜异羟基洋地黄毒甘｜地高辛｜异羟基洋地黄毒甙

lutian08 发表于 2013-7-7 18:18
%let drugname=%nrstr(普萘洛尔(心得安),美托洛尔(倍他乐克),;强心素,异羟基洋地黄毒甘,地高辛,异羟基洋地黄 ...

正规真强大啊，我用一个宏程序写了半年才出来

All can be done within a macro environment.

%let drugname=%nrstr(a,b,;c,d(b),e;f);
%put &drugname;

%let drugname2=%sysfunc(translate(%sysfunc(compbl(%sysfunc(
                translate(&drugname, %str( ), %str(,;%(%)) )))),%str(|), %str( )));

%put &drugname2;

bobguy 发表于 2013-7-7 20:51
All can be done within a macro environment.

%let drugname=%nrstr(a,b,;c,d(b),e;f);

对全角的符号好像没办法

Imasasor 发表于 2013-7-7 20:58
对全角的符号好像没办法

对全角=、 (?) is not a problem.


%let drugname=%nrstr(a,b、b3,;c,d(b),e;f);
%put &drugname;

%let drugname2=%sysfunc(translate(%sysfunc(compbl(%sysfunc(
                translate(&drugname, %str( ), %str(,、;%(%)) )))),%str(|), %str( )));

%put &drugname2;

%let drugname=%nrstr(普萘洛尔(心得安),美托洛尔(倍他乐克)，阿替洛尔(氨酰心安),比索洛尔（康可）,
卡维地洛、拉贝洛尔
氨酰心安、美多心安、醋丁酰心安, 心得静、甲磺胺心安、噻吗心安、柳胺苄心安, 维拉帕米(异搏定，
戊脉安，凡拉帕米，异搏停)，
地尔硫卓(恬尔心、硫氮卓酮、合心爽、蒂尔丁)，狄戈辛，地毒,拉诺辛;强心素,异羟基洋地黄毒甘,地高辛,异羟基洋地黄毒甙);


data kk;
length ktran $500 ktran1 $500;
ktran=ktranslate("&drugname",' ',"(),;（）、，");
ktran1=compbl(ktran);
run;

这个可以的，用ktranslate函数把字符全部转化为空格，然后用compbl保留一个空格

bobguy 发表于 2013-7-8 07:08
对全角=、 (?) is not a problem.

用中文试，就是楼主的那些文字，中文在处理过程中经常出问题，有时部分中文会出现乱码

好强大