请教Winsorize的方法

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

烦请各位高手指点一下Winsorize数据的方法，用SPSS能做吗？SAS的程序是怎样的？急啊，谢谢！

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏4 回帖

关键词：Winsorize winsor wins SOR Win 请教 Winsorize

1# yakilili

/**********************************************************
Purpose: trim or winsorize SAS dataset to remove the impact from extreme values

Input
dsetin  : dataset to winsorize/trim
byvar   : define subset to winsorize/trim,e.g. 'date'. type 'none' for the whole dataset
type    : 'delete' or 'winsor' (delete will trim, winsor will winsorize
vars    : subsetting variables to winsorize/trim on; type 'none for no byvar
pctl    : the percenagte of left and right tails to trim/winsorize

Output
dsetout : dataset to output with winsorized/trimmed values
************************************************************/

%macro winsor(dsetin=, dsetout=, byvar=none, vars=, type=winsor, pctl=1 99);

%if &dsetout = %then %let dsetout = &dsetin;
   
%let varL=;
%let varH=;
%let xn=1;

%do %until ( %scan(&vars,&xn)= );
    %let token = %scan(&vars,&xn);
    %let varL = &varL &token.L;
    %let varH = &varH &token.H;
    %let xn=%EVAL(&xn + 1);
%end;

%let xn=%eval(&xn-1);

data xtemp;
    set &dsetin;
    run;

%if &byvar = none %then %do;

    data xtemp;
        set xtemp;
        xbyvar = 1;
        run;

    %let byvar = xbyvar;

%end;

proc sort data = xtemp;
    by &byvar;
    run;

proc univariate data = xtemp noprint;
    by &byvar;
    var &vars;
    output out = xtemp_pctl PCTLPTS = &pctl PCTLPRE = &vars PCTLNAME = L H;
    run;

data &dsetout;
    merge xtemp xtemp_pctl;
    by &byvar;
    array trimvars{&xn} &vars;
    array trimvarl{&xn} &varL;
    array trimvarh{&xn} &varH;

    do xi = 1 to dim(trimvars);

        %if &type = winsor %then %do;
            if not missing(trimvars{xi}) then do;
              if (trimvars{xi} < trimvarl{xi}) then trimvars{xi} = trimvarl{xi};
              if (trimvars{xi} > trimvarh{xi}) then trimvars{xi} = trimvarh{xi};
            end;
        %end;

        %else %do;
            if not missing(trimvars{xi}) then do;
              if (trimvars{xi} < trimvarl{xi}) then delete;
              if (trimvars{xi} > trimvarh{xi}) then delete;
            end;
        %end;

    end;
    drop &varL &varH xbyvar xi;
    run;

%mend winsor;

什么是winsorise 原理是啥？

dreamingboy7 发表于 2010-5-26 17:10
什么是winsorise 原理是啥？

Winsorize的原理：如果一个样本某变量的值大于该变量的99分位数，则该样本的值被强制指定为99分位数的值；类似的，如果一个样本某变量的值小于该变量的1分位数，则该样本该变量的值被强制指定为1分位数。

受教了！

stata可以，用winsor 命令
winsor var1, gen(var11) p(.05)

肿么我看到代码就晕乎乎

Joycelyn小乔 发表于 2014-1-8 22:06
stata可以，用winsor 命令
winsor var1, gen(var11) p(.05)

怎么安装WINSORIZE呢。我用Findit winsorize 没有找到可以安装的？谢谢

这是ＳＡＳ的方法
data a;
do i=1 to 200;
x=ranuni(0);
output;
end;
run;
proc univariate data=a noprint;
var x;
output out=b pctlpts=1 pctlpts=99 pctlpre=p_;
run;
data c;
set a;
if (_n_=1) then set b;
if x gt p_99 then y=p_99;
else if x lt p_1 then x=p_1;
else y=x;
run;