将一列数据分成几列输出到新的数据集

我刚学sas..有个问题比如有一列不知道多少行的数据，想让它变成一列有4个数字的矩阵，改怎么做。。
就是这样：
本来的数据：                           要变成：
1                                             1   1   ...
4                                             4   6   ...
2                                             2   3   ...
4                                             4   9   ...
1
6
3
9
...
...
...
...

/*建立测试数据集test*/
data test;
   do x=1 to 100;
      output;
   end;
run;

/*将数据集test（1个变量）改变存储形式，折叠成数据集test1（4个变量）*/
data test1;
   array y[4];
   /*数据集test有nobs个观测，折叠后的test1有ceil(nobs/4)个观测*/
   do i=1 to ceil(nobs/4);
      /*test中的4个观测，变成test1中的1个观测*/
      do j=1 to 4;
         k=(i-1)*4+j;
         /*利用"nobs=nobs"获得数据集test观测数nobs,并且每次data循环读取第k条观测*/
         set test point=k nobs=nobs;
         y[j]=x;
      end;
      output;
   end;
   stop;
   keep y:;
run;

/*test1转置成test2*/
proc transpose data=test1 out=test2(keep=col:);
run;

/************************************************/
/****或者****/
/************************************************/

/*test基础上形成新变量j（其值1、2、3、4循环），新数据集为test3*/
data test3;
   set test;
   j=mod(_n_,4);
   if j=0 then j=4;
run;

/*根据j排序，为转置做准备*/
proc sort data=test3;
   by j;
run;

/*将test3直接转置成所需格式，形成test4*/
proc transpose data=test3 out=test4(keep=col:);
   by j;
   var x;
run;

l1i2n3i4n5g 发表于 2017-10-14 21:08
data test;
   do x=1 to 100;
      output;

楼主果然高手，不过楼主还是能对程序本身做一些解释，会更好。

8112mmw 发表于 2017-10-15 08:16
楼主果然高手，不过楼主还是能对程序本身做一些解释，会更好。

好的，如没注释时间长了自己也会看不明白！

1. data a;
   
2.    do x=1 to 103;
   
3.       output;
   
4.    end;
   
5. run;
   
6. 
   
7. data b;
   
8. set a end=jj;
   
9. cc=ceil(_n_/4);
   
10. if jj then nn=ceil(_n_/4);
    
11. run;
    
12. 
    
13. /*get the max col numble*/
    
14. proc sql noprint;
    
15. select nn into: n  from b where nn ne .;quit;
    
16. 
    
17. %macro jj;
    
18. %do i=1 %to &n.;
    
19. data z&i;
    
20. set b;
    
21. ord=mod(_n_,4);
    
22. if ord=0 then ord=4;/*meger order*/
    
23. if &i=cc then do; y&i.=x; output z&i;end;/*output each 4 obs to each z&i dataset*/
    
24. %end;
    
25. run;
    
26. 
    
27. %if &n lt 2 %then %do;
    
28. data z1(keep=ord y:);
    
29. set z1;
    
30. /*in case the raw obs le 4*/
    
31. run;
    
32. %end;
    
33. %else %do;
    
34. /*meger z1-z&j. to get the need dataset z1*/
    
35.         %do j=2 %to &n.;
    
36. data z1(keep=ord y:);
    
37. merge z1 z&j.;
    
38. by ord;
    
39. run;
    
40.         %end;
    
41. %end;
    
42. %mend;
    
43. %jj;

复制代码