请问如何在data步中选择性的output新的dataset

webgu 发表于 2013-8-15 15:18

call execute也是我经常用的，挺好的一种处理方法。但是这里你要把原始数据集多n变，有几个不同ID就要读几遍。我下面给一个我也经常用到拼code的方法，只读一遍原数据集就可以了。
data have;
input id $ num;
datalines;
a 1
a 2
c 1
c 2
;
run;
proc sql noprint;
create table tmp as
select distinct id
from have;

select 'want_'||id into: dataname separated by ' '
from tmp;
quit;

%put &dataname.;


data Code1;
length code $100.;
code="data &dataname.; set have;";
run;
data Code2;
length code $100.;
set tmp;
if _n_=1 then code=cats('if ID="', ID, '" then output want_', ID, ';');
else code=cats('else if ID="', ID, '" then output want_', ID, ';');
keep code;
run;
data code3;
length code $100.;
code='run;';
run;

data Code;
length Code $100.;
set Code1-Code3;
file "Code.txt";
put Code $;
run;
%include "Code.txt";

好用的话，给钱加分～ 哈哈哈

webgu 发表于 2013-8-15 15:18

为什么我发的程序要经过审核？？？

webgu 发表于 2013-8-15 15:18

学习了

看不懂~call……

chenys625 发表于 2013-8-16 14:41
call execute也是我经常用的，挺好的一种处理方法。但是这里你要把原始数据集多n变，有几个不同ID就要读几 ...

多谢你的方法
只不过这种方法真是没法用
关键可读性太差，写完之后过不了几天就不明白了

webgu 发表于 2013-8-15 15:18

太帅了~学习~~

playmore 发表于 2013-8-31 21:49
多谢你的方法
只不过这种方法真是没法用
关键可读性太差，写完之后过不了几天就不明白了

其实我那程序后面不用%include，直接call execute也可以。主要是想避免反复data set读原始数据，拼代码的处理就复杂一些了。

playmore 发表于 2013-8-31 21:49
多谢你的方法
只不过这种方法真是没法用
关键可读性太差，写完之后过不了几天就不明白了

我突然有想到一个新的思路，找时间试一下，争取晚些时候发上来。

playmore 发表于 2013-8-31 21:49
多谢你的方法
只不过这种方法真是没法用
关键可读性太差，写完之后过不了几天就不明白了

看看这个方法觉得怎么样？

data have;
         input id $ num;
         datalines;
         a 1
         a 2
         c 1
         c 2
         b 4
         ;
run;

proc sql noprint;
      create table temp as select distinct id        from have;
quit;

data b;
      set temp end=end;
      a="ID"||_n_;
      call symput(cats("ID_",_n_),strip(ID));
      call symput(cats("DataName_",_n_),cats("want_",ID));
      if end then call symput('n',_n_);
run;

%macro a;
data  %do i=1 %to &n.;
              &&DataName_&i.
        %end;
        ;
      set have;
      if ID="&ID_1." then output &DataName_1;
      %do i=2 %to &n.;
             else if ID="&&ID_&i." then output &&DataName_&i.;
      %end;
run;
%mend;
%a;

chenys625 发表于 2013-9-1 14:17
看看这个方法觉得怎么样？

data have;

大侠你这回的方法看起来就明白多了
让你花时间想这个问题真是过意不去啊，呵呵

后来我的解法是先让这些子表格都output出来
然后用一个宏统一drop掉没有观测值的表格