想验证一个eviews程序结果出错,说CONS_gov 是非法或者保留的名字。
具体程序如下,请各位大师帮我解解。
'==========Set Up the Social Accounting Matrix====================================
'Accounts: 1. ACT Activity; 2. COM Commodity; 3. HHD Household; 4.GOV Government; 5.SVI Capital Account; 6. ROW World; 7. TOT Total
MATRIX(7,7) IDMACSAM 'ID is country Code for Indonesia
'Define the Columns of IDMACSAM
FOR %AC ACT COM HHD GOV SVI ROW TOT
VECTOR(7) V{%AC}
NEXT
'Fill in IDMACSAM's Columns with Base Year Data
VACT(3)=1538826
VACT(4)=71186
VACT(7)=@SUM(VACT)
VCOM(1)=1040070
VCOM(4)=12005
VCOM(6)=447626
VCOM(7)=@SUM(VCOM)
VHHD(2)=1042148
VHHD(4)=110845
VHHD(5)=405079
VHHD(7)=@SUM(VHHD)
VGOV(2)=132219
VGOV(5)=61817
VGOV(7)=@SUM(VGOV)
VSVI(2)=325334
VSVI(7)=@SUM(VSVI)
VROW(1)=569942
VROW(3)=19246
VROW(5)=-141562
VROW(7)=@SUM(VROW)
'Load Vectors in IDMACSAM
!COL=1
FOR %AC ACT COM HHD GOV SVI ROW
COLPLACE(IDMACSAM,V{%AC},!COL)
DELETE V{%AC}
!COL=!COL+1
NEXT
'Check Row Totals
!NRWS=@ROWS(IDMACSAM)
FOR !R=1 TO (!NRWS-1)
ROWVECTOR RV{!R}=@ROWEXTRACT(IDMACSAM, !R)
VTOT(!R)=@SUM(RV{!R})
DELETE RV{!R}
NEXT
COLPLACE(IDMACSAM,VTOT, !NRWS)
DELETE VTOT
'Turn the Matrix into a Table
FREEZE(IDTABSAM) IDMACSAM
SETLINE(IDTABSAM,3)
SETCOLWIDTH(IDTABSAM,1,12)
!COL=2
!RW=4
FOR %LB ACTIVITY COMMODITY HOUSEHOLD GOVERNMENT SAVING WORLD TOTAL
SETCELL(IDTABSAM,1,!COL,%LB,"C")
SETCELL(IDTABSAM,!RW,1,%LB,"L")
!COL=!COL+1
!RW=!RW+1
NEXT
'==========Specify the CGE 'Model=============================================
MODEL IDGSS
'Generalized Salter-Swan Model for Indonesia
'*****Production Side*****
'Exports are Derived from the CET Function
IDGSS.APPEND XE = XD*( (PE / PDT) * (1 - alpha_x) / alpha_x )^(1 /(phi_x - 1))
'Domestic Sales as a Residual
IDGSS.APPEND XD=XS - XE
'Domestic price of exports
IDGSS.APPEND PE=EXR*PWE*(1+ te)
'Producer Price of Composite Output (GDP Deflator)
IDGSS.APPEND PX=(PE*XE + PDT*XD)/XS
'Price of Domestic Good
IDGSS.APPEND PDT*XD=(PQ*QQ - PM*QM)'Tax inclusive
IDGSS.APPEND PD=PDT/(1 + td)' Before tax
'*****Consumption Side*****
'Domestic Price of Imports
IDGSS.APPEND PM=EXR*PWM*(1+ tm)
'Domestic price of imports Supply of and Demand for Composite 'Consumption Good defined 'from Armington Aggregation
'of Imports and Demand for Domestically Supplied Good
IDGSS.APPEND QQ=b_q*( beta_q*QM^(-rho_q) + (1-beta_q)*XD^(-rho_q) )^(-1/rho_q)
'Imports are derived from Armington Aggregation
IDGSS.APPEND QM = XD * ( (PDT / PM)*beta_q / (1 - beta_q) )^(1 / (1 + rho_q))
'Price of Composite Consumption Good
IDGSS.APPEND PQ= (CONS_hh + CONS_gov+ INV)/QQ
'*****Government Account*****
IDGSS.APPEND TARIFF=(tm*PWM*EXR*QM)
IDGSS.APPEND INDTAX=(td*PDT/(1 + td)*XD)
IDGSS.APPEND HHTAX=ytx_hh*Y_hh
IDGSS.APPEND Y_gov = TARIFF + INDTAX + HHTAX -(te*PWE*EXR*XE)
'*****Household Income and Savings*****
IDGSS.APPEND Y_hh=PX*XS -INDTAX +(EXR*TR_hh_row)
'Indirect production taxes are paidto the government
IDGSS.APPEND SAV_hh=mps_hh*(1-ytx_hh)*Y_hh
IDGSS.APPEND CONS_hh=(1-mps_hh)*(1 -ytx_hh)*Y_HH/PQ
'*****Aggregate Savings*****
IDGSS.APPEND SAVTOT= SAV_hh + (EXR*FSAV) + SAV_gov
'*****System Constraints and Closure*****
'Full capacity is assumed so that XS is made exogenous
'Domestic Demand Constraint Implicitly defined through XD
'Material Balance for Composite Consumption Good Implicitly 'defined through QQ
'Fiscal Balance
IDGSS.APPEND SAV_gov=(Y_gov - PQ*CONS_gov)
'Balance of Payments in Local Currency
IDGSS.APPEND EXR*FSAV=(PM*QM/(1 + tm) - PE*XE -(EXR*TR_hh_row))
'Investment-Savings Balance
IDGSS.APPEND INV=SAVTOT/PQ
'Further Constraints
'Private and Government Consumptions Remain Fixed
'==========Calibration and 'Initialization==========================================
'Declare Variables
FOR %VR CONS_gov CONS_hh XD EXR FSAV HHTAX INDTAX INV mps_hh omega_x PD PDT PE PM PQ PWE PWM PX QQ QM SAV_gov SAV_hh SAVTOT sigma_q TARIFF TD TE TM TR_hh_row XE XS Y_gov Y_hh ytx_hh MT
SERIES %VR
NEXT
EXR=9311
'LCU (Rupiah) per US$, period average (from LDB on line)
FSAV=IDMACSAM(5,6)/EXR
te=0
PM=1
XD=IDMACSAM(1,2)
SERIES ITX=IDMACSAM(4,1)
td=ITX/(XD-ITX)
PD=1/(1+td)
PDT=PD*(1+ td)
INDTAX=td*PD*XD
QM=IDMACSAM(6,2) + IDMACSAM(4,2)'Imports inclusive of tariff
TARIFF=IDMACSAM(4,2)
tm=TARIFF/(PM*QM - TARIFF)
PE=1
PWE=PE/((1+te)*EXR)
PWM=PM/((1+ tm)*EXR)
PQ=1
PX=1
XS=IDMACSAM(1,7)
TR_hh_row=IDMACSAM(3,6)/EXR
Y_hh=(PX*XS -INDTAX+(EXR*TR_hh_row))
HHTAX=IDMACSAM(4,3)
XE=IDMACSAM(1,6)
ytx_hh=HHTAX/Y_HH
QQ=IDMACSAM(2,7)
INV=IDMACSAM(2,5)
Y_gov=TARIFF +INDTAX + HHTAX -(te*PWE*EXR*XE)
CONS_gov=IDMACSAM(2,4)
SAV_gov=IDMACSAM(5,4)
SAV_hh=IDMACSAM(5,3)
mps_hh=SAV_hh/((1-ytx_hh)*Y_hh)
CONS_hh=(1 - mps_hh)*(1 -ytx_hh)*Y_hh/PQ
SAVTOT=SAV_hh + SAV_gov + (EXR*FSAV)
MODEL CALIBER
omega_x.fill 0.2, 0.5, 0.75, 2, 5 'Different values of export 'transformation elasticity for sensitivity analyis
sigma_q.fill 0.2, 0.5, 1.26, 2, 5
'Different values of trade substitution elasticity;
CALIBER.APPEND rho_q=(1/sigma_q) - 1
CALIBER.APPEND phi_x=(1/omega_x) +1
CALIBER.APPEND alpha_x = 1/((PDT/PE)*(XE/XD)^(1/omega_x) + 1)
'Share for the CET function
CALIBER.APPEND a_x = XS/(alpha_x*XE^phi_x + (1-alpha_x)*XD^phi_x )^(1/phi_x)
'Scalefactor for the CET function
CALIBER.APPEND beta_q=( (PM/PDT)*(QM/XD)^(1+rho_q) )/(1+(PM/PDT)*(QM/XD)^(1/sigma_q) )
'Share factor for the CES function
CALIBER.APPEND b_q = QQ/(beta_q*QM^(-rho_q) + (1-beta_q)*XD^(-rho_q) )^(-1/rho_q)
'Scale factor for the CES function
CALIBER.SCENARIO ACTUALS
CALIBER.SOLVE(s=d, d=s,o=n)
CALIBER.MAKEGROUP CALGRP @ENDOG
FREEZE(CALTAB) CALGRP
'================Simulations================================='===============
IDGSS.SOLVEOPT(s=d, d=s, c=1e-15, o=n)
'*****Baseline Solution*****
IDGSS.SCENARIO(c) BASELINE
SOLVE IDGSS
IDGSS.MAKEGROUP(a) BASEGRP @ENDOG
FREEZE(BASELINE) BASEGRP
'*****An Increase in the World Price of Export*****
SERIES PWE_tot=1.20*PWE
IDGSS.SCENARIO(n, a=tot) BOOM
IDGSS.OVERRIDE PWE
SOLVE IDGSS
IDGSS.MAKEGROUP(c) BOOMGRP @ENDOG
FREEZE(BOOMTAB) BOOMGRP
'*****An Increase in the Tariff Rate*****
SERIES tm_tar=1.50*tm
IDGSS.SCENARIO(n, a=tar) TARIFFUP
IDGSS.OVERRIDE tm
SOLVE IDGSS
IDGSS.MAKEGROUP(c) TARGRP @ENDOG
FREEZE(TARITAB) TARGRP
'END OF PROGRAM
多谢了