一个双录入比对程序

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

研究生时候写的一个问卷双录入比对程序。程序最开始的说明部分有点罗嗦与模糊请谅解。希望各位网友大能不吝赐教。

1. /*功能：完成两数据集排序、找共同记录、比较等功能，并可将结果存入指定的文件中，
   
2. 测试系统：win7
   
3. 测试版本：sas9.2
   
4. 编写人员：dahufa
   
5. 测试人员：dahufa
   
6. 联系方式：dahufa123@126.com
   
7. 权益保护：可以使用不得传播。如有发现问题或有改动联系作者。
   
8. */
   
9. 
   
10. /*
    
11. 宏参数有以下几个:
    
12. base：基础数据集；
    
13. compare：比较的数据集；
    
14. id：两个数据集比较的依据变量，需两组中变量相同
    
15. drop：量比较数据集中不用进行比较的变量，存在多个时彼此间用空格隔开；
    
16. transpose：是否转置，即比较的结果是否以每条记录的方式显示，取值范围为0,1。如为0不转置，以变量方式显示；如为1转置，以变量方式显示。默认为不转置；
    
17. path：比较差异结果输出的全路径，包括盘号:\文件夹\文件名.后缀名。可以省略，省略及不输出。
    
18. 
    
19. 必须定义的变量为base、compare，此时默认比较依据变量为id，不转置，不输出，不去变量。
    
20. */
    
21. 
    
22. /*
    
23. 运行前work中与该程序中间产生的数据集同名的文件需保存。如：
    
24.   a、cs、f、s fir1，fir2、fns、sec1、sec2、snf及可能产生的f1、f2、f3……和s1、s2、s3……等。
    
25. 
    
26. 判读结果时可能用到的数据集：
    
27. fir2：base数据集中id号重复的记录；
    
28. sec2：compare数据集中id号重复的记录；
    
29. fns：在base数据集中存在而在compare数据集中不存在的变量；
    
30. snf：在compare数据集中存在而在base数据集中不存在的变量；
    
31. 在校对前需尽可能保证fns与snf中不存在记录，尽可能发现fir2中sec2中id与fir1、sec1相同却不是指一问卷的记录。
    
32. 
    
33. 其余数据集的含义：
    
34. fir1、sec1：base、compare数据集中id第一次出现的记录；
    
35. f、s： base、compare数据集中最后进入比较的记录；
    
36. */
    
37. 
    
38. /*
    
39. 另及小提示：        
    
40. 
    
41. 在比较前可以对数据进行一些整理，建议在保留原始记录的基础上用程序进行
    
42. 上述的改动（即都通过程序改动数据，而不直接改动数据集），使用更改后的数据集进行比较，而在校对时在原始记录上改错误，
    
43. 这样如要得到最后的结果跑一遍改动的程序即可。
    
44. */
    
45. %macro compare (base=,compare=,id=id,drop= ,transpose=0,path= );
    
46. %put &base &compare;
    
47. %symdel nw nobs eob;
    
48. /*清除本宏中可能出现的全局宏变量，以防止干扰。运行时就此处出现绿字提示“WARNING: 删除宏变量 NW 失败，未找到该变量。
    
49. ”等乃正常现象，说明系统中没有此宏变量。*/
    
50. 
    
51.   %if  &transpose=1  %then %let transpose=transpose;
    
52.   %else %let transpose=;
    
53.   /*程序开始*/
    
54. proc sort data=&base;
    
55. by &id;
    
56. proc sort data=&compare;
    
57. by &id;
    
58. run;
    
59. 
    
60. data fir1 fir2;
    
61. set &base;
    
62.   if first.&id then output fir1;
    
63.    else output fir2;
    
64. by &id;
    
65. run;
    
66. 
    
67. data sec1 sec2;
    
68. set &compare;
    
69.   if first.&id then output sec1;
    
70.    else output sec2;
    
71. by &id;
    
72. run;
    
73. data s fns snf;
    
74. merge fir1(in=ok1) sec1(in=ok2);
    
75.   by &id;
    
76.    if ok1=1 and ok2=1 then output s;
    
77.    if ok1=1 and ok2=0 then output fns;
    
78.    if ok1=0 and ok2=1 then output snf;
    
79. run;
    
80. data f;
    
81. merge sec1(in=ok1) fir1(in=ok2);
    
82.   by &id;
    
83.    if ok1=1 and ok2=1 then output f;
    
84. run;
    
85. /*这一段准备数据库，除含宏变量外与普通宏程序完全相同*/
    
86. 
    
87. data _null_;
    
88. if nobs=0 then do;        
    
89.   call symput('nobs',"0"); /*空集非得如此,非空可直接：data _null_;set f nobs=nobs;call symput('obc',nobs);run;*/
    
90. end;
    
91. else call symput('nobs',put(nobs,best12.));
    
92. stop;
    
93. set f nobs=nobs;
    
94. run;
    
95. %put 两数据集间都存在的id唯一的记录有 &nobs 条;
    
96. /*以上定f是否是空集, &nobs=0为空集。*/
    
97. 
    
98. %if &nobs=0 %then %do;
    
99. %window both color=yellow
    
100.            #5 @28 '两个数据集之间没有共同记录！' attr=highlight
     
101.               color=red
     
102.                         #8 @32 '请敲击ENTER键继续' attr=highlight
     
103.               color=blue;
     
104. %display both delete;
     
105. %end;
     
106. /*空集直接终止程序，弹出窗口，由用户交互后推出程序。非空执行下面程序*/
     
107. 
     
108. %else %do;
     
109. 
     
110. ods output comparesummary=cs;
     
111. options nodate source    linesize=100 pagesize=30000;
     
112.   proc compare data=f  (drop=&drop )
     
113.    compare=s (drop=&drop )
     
114.     maxprint=(10000 32767) nodate  &transpose;
     
115.      id &id;
     
116.   run;
     
117. ods output close;
     
118. dm 'clear output';
     
119. /*初步比较了解不等值总数*/
     
120. 
     
121. data _null_;
     
122. set cs;        
     
123.   where batch contains "部分比较变量不等的观测数";
     
124.     call symput('eob',compress(batch,,'kd'));
     
125. run;
     
126. %put 部分比较变量不等的观测数 &eob;
     
127. /*看部分比较变量不等的观测数，如eob为0表完全相等*/
     
128. 
     
129. %if &eob=0 %then %do;
     
130. %window results color=white
     
131.            #5 @28 '恭喜你，现在没有发现两遍之间存在差别！' attr=highlight
     
132.               color=red
     
133.                         #8 @40 '请敲击ENTER键继续' attr=highlight
     
134.               color=blue;
     
135. %display results delete;
     
136. %end;
     
137. /*完全相等退出程序*/
     
138. 
     
139. %else %do;
     
140. data _null_;
     
141. set cs;        
     
142.   where batch contains "比较不等值总数";
     
143.     call symput('nw',compress(batch,,'kd'));
     
144. run;
     
145. %put 比较不等值总数为 &nw;
     
146. /*找不等值总数*/
     
147. 
     
148. %if &path^= %then %do;
     
149.   proc printto print="&path" new;quit;
     
150. %end;
     
151. /*从现在开始如Path为非空，则将结果存入path文件*/
     
152. 
     
153. %let n=%sysevalf(&nw/32767);
     
154. %put 比结果将会是sas容许打印的 &n 倍;
     
155. %if &n<1 %then %do;
     
156.   options nodate source    linesize=100 pagesize=30000;
     
157.    proc compare data=f  (drop=&drop )
     
158.     compare=s (drop=&drop )
     
159.          maxprint=(10000 32767) nodate  &transpose;
     
160.           id &id;
     
161.           title "比较数据集&base. 和&compare. 的结果";
     
162.   run;        
     
163.    proc datasets lib=work nolist;
     
164.     delete cs;
     
165.    quit;
     
166. %end;
     
167. /*如果sas能一次打印完全则直接打印（sas最多打印32767行），不然分段打印*/
     
168. 
     
169. %else %do;
     
170.   %do i=1 %to %eval(&n+1);
     
171.      data f&i;
     
172.        %if &i=%eval(&n+1) %then %do;
     
173.          set f(firstobs=%sysevalf(&nobs*(&i-1)/(&n+1)+1,int) obs=max);
     
174.                %end;
     
175.        %else %do;
     
176.          set f(firstobs=%sysevalf(&nobs*(&i-1)/(&n+1)+1,int) obs=%sysevalf(&nobs*&i/(&n+1),int));
     
177.         %end;
     
178.      run;
     
179. 
     
180.      data s&i;
     
181.        %if &i=%eval(&n+1) %then %do;
     
182.          set s(firstobs=%sysevalf(&nobs*(&i-1)/(&n+1)+1,int) obs=max);
     
183.                    %end;
     
184.              %else %do;
     
185.          set s(firstobs=%sysevalf(&nobs*(&i-1)/(&n+1)+1,int) obs=%sysevalf(&nobs*&i/(&n+1),int));
     
186.               %end;
     
187.      run;
     
188.         /*将数据分段，分段后逐段比较并将结果输出以保证sas将所有错误一次打印完全*/
     
189. 
     
190.    options nodate source    linesize=100 pagesize=30000;
     
191.     proc compare data=f&i  (drop=&drop )
     
192.      compare=s&i (drop=&drop )
     
193.        maxprint=(10000 32767) nodate nosummary &transpose;
     
194.      id &id;
     
195.           title "比较数据集 &base. 和 &compare. 的结果part&i";
     
196.    run;
     
197. 
     
198.    proc datasets lib=work nolist;
     
199.     delete a cs f1-f%eval(&n+1) s1-s%eval(&n+1);
     
200.    quit;
     
201.    /*删除中间的数据库*/
     
202.   %end;
     
203. %end;
     
204. 
     
205. %if &path^= %then %do;
     
206. Proc printto;quit;         /*将结果输出*/
     
207. %end;
     
208. %end;
     
209. %end;
     
210. %mend compare;
     
211. 
     
212. /*
     
213. 调用示例：
     
214. 1.启动sas后第一次调用时先将本文件打开，全选并运行，然后在新建的增强型程序编辑器中写入语句：
     
215.   “
     
216.   %compare(base=h.firfir,compare=h.secsec,id=id,transpose=0,drop=writer freq,path=g:\sas 比较.txt) ;
     
217.   ”
     
218.   上例是所有宏参数都指定的情况，宏参数指定最少的情况如下：
     
219.   “
     
220.   %compare(base=h.firfir,compare=h.secsec) ;
     
221.   ”
     
222.   第二次及以后要调用该宏仅需运行上述语句即可。
     
223. 
     
224. 2.找到本文件存放的路劲如：“d:\sas\compare.sas”,然后在sas程序编辑器中写入：
     
225.   “
     
226.   %include "d:\sas\compare.sas"        ;
     
227.   options mfile mprint MLOGICNEST; *此句及下句允许sas在log窗口中显示宏处理后的程序;
     
228.   filename mprint 'f:\a.sas' ;
     
229.   %compare(base=h.firfir,compare=h.secsec) ;
     
230.   ”
     
231.   运行即可。
     
232. 
     
233. 建议选第二种，这样可以保证sas程序不会被随便改动。
     
234. */
     
235. 
     
236. 
     
237. 
     
238. /*另：
     
239. base中的id变量与compare中不同的情况下，最好先改相同再比.
     
240. */
     
241. 
     
242. 
     
243. 
     
244. /*
     
245. 2011.7.13追加更正：
     
246. 1.两数据库间没有共同id记录的情况；
     
247. 2.两数据库间没有找到差别的情况；
     
248. 3.改进了寻找不同值数目的方法。
     
249. */

复制代码

      其实真正要实现这一比较工作很多其他的工具可以办到，但打印出异同点的就少了许多。再次sas实现该操作也简单，不过sort、merge、compare几个步骤而已，这里面其实是多了个最后的判断罢了。其实没有任何用处，纯粹个人意淫。悲催。

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享1 收藏6 回帖

关键词：比对程序 双录入 Transpose highlight compress 程序 录入 双录入 比对程序 sas merge compare