sas 数据集名字批量添加到每个数据集中形成新的变量和数据集

希望能在每个数据集中增加一个新的变量，变量内容是该数据集的名字。已经用proc contents 把library里所有数据集的名字搞到一个新数据集里了，也将这些数据集名称赋给宏变量。但是后面怎么批量添加到每个数据集中，形成新的数据集，没能实现。希望大神能用宏程序帮忙实现，非常感谢！

我看下来，你是不是想给逻辑库里的一批数据集增加一个字段，值是该数据集的名称？
下面我举了一个例子来实现这个想法，希望对你有帮助
/**获取所有WORK逻辑库里所有数据集的名称**/
proc sql;
create table tablename as
select memname from dictionary.tables/*dictionary.tables是SAS数据字典表，固定用法*/
where libname eq "WORK";/*填写逻辑库名*/
QUIT;

data tablename;
set tablename;
call symput ('numvars',_n_);run;/*获取数据集的数量*/

%macro datesetname;
%do i=1 %to &numvars.;
data _null_;
set tablename;
if _n_=&i.;
call symput ('dname',memname);run;/*按顺序读取数据集的名称**/

data &dname.;
set &dname.;
format datesetname $20.;
datesetname="&dname.";/**添加一个字段，值为数据集名称*/
run;
%end;
%mend;

%datesetname;

自己写了一个，P1-P3是原有数据集的名字，
%let numvars=%str(P1|P2|P3|);
%let nvars=%sysfunc(countw(&numvars,"|"));

%macro addsetname (nvars,numvars);
%do i=1 %to &nvars;
   %let numvar&i=%scan(&numvars,&i,"|");

    data &&numvar&i;
    set &&numvar&i;
        datasetname="&&numvar&i";
run;
%end;
%mend;

%addsetname(nvars=&nvars,numvars=&numvars)

绣球 发表于 2021-7-13 16:49
我看下来，你是不是想给逻辑库里的一批数据集增加一个字段，值是该数据集的名称？
下面我举了一个例子来实 ...

就是这个意思呢，谢谢~~~