data如何实现2

1. data aaa;
   
2. input id x$ group sev;
   
3. cards;
   
4. 1 aa 1 1
   
5. 1 bb 1 1
   
6. 1 bb 1 2
   
7. 1 bb 1 2
   
8. 1 cc 1 2
   
9. 1 cc 1 1
   
10. 2 dd 1 1
    
11. 2 ff 1 3
    
12. 2 ff 1 2
    
13. 3 aa 2 1
    
14. 3 bb 2 2
    
15. 3 cc 2 3
    
16. 4 aa 2 1
    
17. 4 bb 2 2
    
18. 4 bb 2 1
    
19. 4 cc 2 1
    
20. ;
    
21. run;

复制代码

要求根据id x两个变量保留sev最大的记录，结果如下：1 aa 1 1
1 bb 1 2
1 bb 1 2
1 cc 1 2
2 dd 1 1
2 ff 1 3
3 aa 2 1
3 bb 2 2
3 cc 2 3
4 aa 2 1
4 bb 2 2
4 cc 2 1

data步如何实现？谢谢！

1. data aaa;
   
2.         input id x$ group sev;
   
3. cards;
   
4. 1 aa 1 1
   
5. 1 bb 1 1
   
6. 1 bb 1 2
   
7. 1 bb 1 2
   
8. 1 cc 1 2
   
9. 1 cc 1 1
   
10. 2 dd 1 1
    
11. 2 ff 1 3
    
12. 2 ff 1 2
    
13. 3 aa 2 1
    
14. 3 bb 2 2
    
15. 3 cc 2 3
    
16. 4 aa 2 1
    
17. 4 bb 2 2
    
18. 4 bb 2 1
    
19. 4 cc 2 1
    
20. ;
    
21. run;
    
22. 
    
23. proc sort data=aaa; by id x descending sev ; run;
    
24. 
    
25. data want(where=(sev=max));
    
26.         set aaa;
    
27.         by id x;
    
28.         retain max;
    
29.         if first.x then max=sev; else if sev>max then max=sev;
    
30. run;

复制代码

1. data aaa;
   
2.         input id x$ group sev;
   
3. cards;
   
4. 1 aa 1 1
   
5. 1 bb 1 1
   
6. 1 bb 1 2
   
7. 1 bb 1 2
   
8. 1 cc 1 2
   
9. 1 cc 1 1
   
10. 2 dd 1 1
    
11. 2 ff 1 3
    
12. 2 ff 1 2
    
13. 3 aa 2 1
    
14. 3 bb 2 2
    
15. 3 cc 2 3
    
16. 4 aa 2 1
    
17. 4 bb 2 2
    
18. 4 bb 2 1
    
19. 4 cc 2 1
    
20. ;
    
21. run;
    
22. 
    
23. proc sort data=aaa; by id x sev; run;
    
24. 
    
25. proc sql;
    
26.         create table want as
    
27.         select *
    
28.         from aaa as a
    
29.         where sev=(select max(sev) from aaa where id=a.id and x=a.x)
    
30.         order by id, x, sev
    
31. ;
    
32. quit;

复制代码

橙红的果士 发表于 2023-9-20 09:24

data步如何实现？

橙红的果士 发表于 2023-9-20 09:50

else if sev>max then max=sev;
这一句是否可以去掉？谢谢！

dxystata 发表于 2023-9-21 08:51
else if sev>max then max=sev;
这一句是否可以去掉？谢谢！

这个问题非常好，其实我昨天也是考虑到了，发现这句没啥用，可以直接去掉的。

本题的核心是一个表查询(Table Lookup)问题，即要从一个数据集查询某种结果——本题中是分组最大值——然后返回到另外一个数据集中。SQL 其实非常合适解决这类问题，也可以先求得最大值，然后在数据步中使用merge进行数据拼接。

1. proc sql noprint;
   
2.   create table want1 as
   
3.   select *
   
4.   from aaa
   
5.   group by id, x
   
6.   having sev=max(sev)
   
7.   ;
   
8. quit;

复制代码

SAS中还有一些其它的技术也可以快速地实现表查询，例如双重 set、DOW-Loop、hash、直接索引等等。以 DOW-Loop 为例，本题也可以这样做：

1. data want2;
   
2.   do until(last.x);
   
3.     set aaa;
   
4.     by id x;
   
5.     max=max(max,sev);
   
6.   end;
   
7.   do until(last.x);
   
8.     set aaa;
   
9.     by id x;
   
10.     if sev=max then output;
    
11.   end;
    
12. run;

复制代码

whymath 发表于 2023-9-22 10:16
本题的核心是一个表查询(Table Lookup)问题，即要从一个数据集查询某种结果——本题中是分组最大值——然后 ...

求教啥是双重 set?
上面的样例code看起来感觉是双重set+DOW Loop组合体。。。

whymath 发表于 2023-9-22 10:16
本题的核心是一个表查询(Table Lookup)问题，即要从一个数据集查询某种结果——本题中是分组最大值——然后 ...

我也是最先想到的就是SQL，
然后是Data步
Hash，索引的话感觉有点高端
不过DOW－Loop的写法看起来很古典呀

程序最好都考虑存在缺失的情况