SAS新手求助关于SGPLOT如何画条形图 谢谢

jingju11，非常感谢！你说的对，我只需要改变代表RGB颜色的文本。
你的代码非常简洁有效，我现在能指定颜色了，谢谢！

感谢guoluo和jingju11的帮忙，下面是接近完成macro和效果图，我是初学者，所以写的代码相当幼稚，见笑了。
我现在存在的问题在于图片左上角的文字说明，有2方面：
第1个是样式，我所期望的效果如下，然而，如果我插入2个文字说明并分别指定不同的颜色，则2个文字说明会叠加在一起（只能指定位置为左上，左。。。不能指定特定位置）如果我插入1个文字说明并放置多行文字，则我不能为每行文字指定1种颜色。
D    ss=23355    mean=0.124     std=0.013
U    ss=17876    mean=0.123     std=0.014
第2个是不知道怎么从数据集里面提取并连接文字。汇总数据集如下图所示。我猜测应该是用类似下面的程序来实现，但是语法不熟悉，实现不了。

1. define a; /*不知道在macro里面怎么定义宏变量*/
   
2. data xx;
   
3.         do i = 1 to nobs; /*行数我知道怎么获取*/
   
4.                         /*不知道哪个connect函数可以实现这个，如果
   
5.                         只是普通字符，倒是可以用cats之类那些*/
   
6.                 a = connect(UP_DOWN "  " ss "  " mean "  " std);
   
7.         end;
   
8. run;

复制代码

小数：


多组：


负数：

1. libname temp "H:\SAS";
   
2. 
   
3. %let _color_y = cx4F81BD cxC0504D cx9BBB59 cx8064A2 cx4BACC6 cxF79646;
   
4. %let _color_y2 = cx4F81BD cxC0504D cx9BBB59 cx8064A2 cx4BACC6 cxF79646;
   
5. /*%let _color_y2 = cx95B3D7 cxD99795 cxC2D69A cxB2A1C7 cx93CDDD cxFAC090; */
   
6. 
   
7. %CDF(_in = temp.test, _var = par1, _group = UP_DOWN,
   
8.                 _maverick_min = 0.05, _maverick_max = 0.25, _out = test1, _out_path = %str(H:\SAS));
   
9. %CDF(_in = temp.test, _var = par2, _group = NO,
   
10.                 _maverick_min = 0, _maverick_max = 100, _out = test2, _out_path = %str(H:\SAS));
    
11. %CDF(_in = temp.test, _var = par3, _group = UP_DOWN,
    
12.                 _maverick_min = -10, _maverick_max = 0, _out = test3, _out_path = %str(H:\SAS));
    
13. 
    
14. %macro CDF (_in =, _var =, _group =, _maverick_min =, _maverick_max =, _out =, _out_path =);
    
15. data _data_raw;
    
16.         set &_in (keep = &_var &_group);
    
17.         where &_var ^= .;
    
18. run;
    
19. 
    
20. data _tmp_no_maverick;
    
21.         set _data_raw;
    
22.         where &_var <= &_maverick_max and &_var >= &_maverick_min;
    
23. run;
    
24. 
    
25. %minmax(_in = _tmp_no_maverick, _var = &_var);
    
26. %bin(_mean = &g_mean, _std = &g_std);
    
27. 
    
28. data _tmp_bin;
    
29.         set _data_raw;
    
30.         bin = round(&_var, &g_bin);
    
31. run;
    
32. 
    
33. proc means data = _tmp_bin noprint;
    
34.         var &_var;
    
35.         class &_group bin;       
    
36.         output out=_tmp_bin_sum (drop = _FREQ_)
    
37.                 mean = mean
    
38.                 std = std
    
39.                 n = count;
    
40.         options nolabel;
    
41. run;
    
42. %minmax(_in = _tmp_bin_sum, _var = _TYPE_);
    
43. 
    
44. data _tmp_bin_count;
    
45.         set _tmp_bin_sum;
    
46.         where _TYPE_ = &g_max;
    
47. run;
    
48. proc sort data = _tmp_bin_count (drop = _TYPE_ mean std);
    
49.         by &_group bin;
    
50. run;
    
51. 
    
52. data _tmp_bin_input (rename = (count = input));
    
53.         set _tmp_bin_sum;
    
54.         where _TYPE_ = &g_max - 1;
    
55.         options nolabel;
    
56. run;
    
57. proc sort data = _tmp_bin_input (drop = bin _TYPE_ mean std);
    
58.         by &_group;
    
59. run;
    
60. 
    
61. data _data_sum (rename = (bin = &_var));
    
62.         merge _tmp_bin_count _tmp_bin_input;
    
63.         by &_group;
    
64.         per = 100 * count / input;
    
65.         if &_group = lag1(&_group) then cdf + per;
    
66.         else cdf = per;
    
67. run;
    
68. 
    
69. %minmax(_in = _tmp_no_maverick, _var = &_var);
    
70. %xaxis(_mean = &g_mean, _std = &g_std, _max = &g_max, _min = &g_min);
    
71. 
    
72. %minmax(_in = _data_sum, _var = count);
    
73. %y2axis(_mean = &g_mean, _std = &g_std, _max = &g_max, _min = &g_min);
    
74. 
    
75. %nobs_nvars(_in=_tmp_bin_input);
    
76. proc means data = _tmp_no_maverick noprint;
    
77.         var &_var;
    
78.         class &_group;       
    
79.         output out=_tmp_inset (where = (_TYPE_ = 1))
    
80.                 n = ss
    
81.                 mean = mean
    
82.                 std = std;
    
83.         options nolabel;
    
84. run;
    
85. proc sort data = _tmp_inset (drop = _TYPE_ _FREQ_);
    
86.         by &_group;
    
87. run;
    
88.        
    
89. data _tmp_inset;
    
90.         update _tmp_inset _tmp_bin_input (rename = (input = ss));
    
91.         by &_group;
    
92. run;
    
93. 
    
94. proc template;
    
95.         define style nbCDF;
    
96.            parent=Styles.Default;
    
97.         style Graph from Graph /   
    
98.                 OutputWidth = 8in
    
99.               OutputHeight = 5.6in;
    
100.         class color_list /
     
101.               'bgA' = cxC0C0C0;
     
102.         class GraphColors /
     
103.                 'gwalls' = cxFFFFFF
     
104.                 'glegend' = cxFFFFFF
     
105.                 'ggrid' = cx909090
     
106.                 %colorList;
     
107.         class GraphFonts /
     
108.                 'GraphDataFont' = ("<sans-serif>, <MTsans-serif>",14pt)
     
109.               'GraphValueFont' = ("<sans-serif>, <MTsans-serif>",14pt)
     
110.               'GraphLabelFont' = ("<sans-serif>, <MTsans-serif>",14pt)
     
111.               'GraphFootnoteFont' = ("<sans-serif>, <MTsans-serif>",14pt)
     
112.               'GraphTitleFont' = ("<sans-serif>, <MTsans-serif>",16pt,bold);
     
113.     end;
     
114. run;
     
115. 
     
116. options jpegquality = 95;
     
117. ods graphics on /imagefmt= JPEG
     
118.                                  imagename="&_out";
     
119. ods listing gpath="&_out_path"
     
120.                          style=nbCDF;
     
121. proc sgplot data = _data_sum;
     
122.         series x = &_var y = cdf / group = &_group lineattrs = (pattern = solid thickness = 3) name = "y1";
     
123.         series x = &_var y = count / y2axis group = &_group lineattrs = (pattern = longdash thickness = 2);
     
124.         xaxis label = '&_var' grid fitpolicy = rotatethin values = (&g_xmin to &g_xmax by &g_xbin);
     
125.         yaxis label = 'Cumulative Distribution(%)' grid values = (0 to 100 by 10);
     
126.         y2axis label = 'Distribution(N)' grid values = (&g_y2min to &g_y2max by &g_y2bin);       
     
127.         title "&_var CDF Plot by &_group";
     
128.         inset "asdasdasda" "sdfsdfsd" / position = topleft;
     
129.         *keylegend "y1" / position= bottom;
     
130.         *footnote justify = right "XXX";
     
131. run;
     
132. ods listing close;
     
133. ods graphics off;
     
134. 
     
135. proc datasets library=work nolist;
     
136.         delete  _tmp_no_maverick _stat _tmp_bin _tmp_bin_sum _tmp_bin_count _tmp_bin_input _tmp_inset _data_raw _data_sum;
     
137. run;
     
138. 
     
139. %mend CDF;
     
140. 
     
141. %macro colorList;        
     
142.         %do i =1 %to &g_obsnum;
     
143.                 "gcdata&i" = %scan (&_color_y, &i)
     
144.                 "gcdata%eval (&i + &g_obsnum)" = %scan (&_color_y2, &i)
     
145.         %end;
     
146. %mend colorList;
     
147. 
     
148. %macro nobs_nvars (_in = );
     
149. %global g_obsnum g_varnum;
     
150. %let dsid = %sysfunc (open (&_in, i));  
     
151. %let g_obsnum = %sysfunc (attrn (&dsid, nobs));
     
152. %let g_varnum = %sysfunc (attrn (&dsid, nvars));
     
153. %let rc = %sysfunc (close (&dsid));
     
154. %mend nobs_nvars;
     
155. 
     
156. %macro minmax(_in =, _var =);
     
157. %global g_mean g_median g_min g_max g_std g_ss;
     
158. proc means data = &_in noprint;
     
159.         var &_var;
     
160.         output out=_stat
     
161.                 mean = g_mean
     
162.                 median = g_median
     
163.                 min = g_min
     
164.                 max = g_max
     
165.                 std = g_std
     
166.                 n = g_ss;
     
167. run;
     
168. 
     
169. data _null_;
     
170.    set _stat;
     
171.    call symput('g_mean', g_mean);
     
172.    call symput('g_median', g_median);
     
173.    call symput('g_min', g_min);
     
174.    call symput('g_max', g_max);
     
175.    call symput('g_std', g_std);
     
176.    call symput('g_ss', g_ss);
     
177. run;
     
178. %mend minmax;
     
179. 
     
180. %macro bin(_mean =, _std = _max =, _min =);
     
181. %global g_bin;
     
182. data _null_;
     
183.         mean = &_mean;
     
184.         if mean < 0 then mean = abs(mean);
     
185.         step = floor(log10(mean)) - 2;
     
186.         step = 10 ** step;
     
187. 
     
188.         min = &_mean - 3 * &_std;
     
189.         max = &_mean + 3 * &_std;
     
190.         bin = (max - min) / 50;
     
191.         bin = round (bin, step);
     
192. 
     
193.         call symput('g_bin', bin);
     
194. run;
     
195. %mend bin;
     
196. 
     
197. 
     
198. %macro xaxis(_mean =, _std =, _max =, _min =);
     
199. %global g_xmin g_xmax g_xbin;
     
200. data _null_;
     
201.         mean = &_mean;
     
202.         if mean < 0 then mean = abs(mean);
     
203.         step = floor(log10(mean)) - 1;
     
204.         step = 10 ** step;
     
205. 
     
206.         min = &_mean - 3 * &_std;
     
207.         max = &_mean + 3 * &_std;
     
208.         bin = (max - min) / 10;
     
209. 
     
210.         min = round (min, step);
     
211.         max = round (max, step);
     
212.         bin = round (bin, step);
     
213. 
     
214.         call symput('g_xmin', min);
     
215.         call symput('g_xmax', max);
     
216.         call symput('g_xbin', bin);
     
217. run;
     
218. %mend xaxis;
     
219. 
     
220. 
     
221. %macro y2axis(_mean =, _std =, _max =, _min =);
     
222. %global g_y2min g_y2max g_y2bin;
     
223. data _null_;
     
224.         max = &_max;
     
225.         if max < 0 then max = abs(max);
     
226.         step = floor(log10(max));
     
227.         step = 10 ** step;
     
228. 
     
229.         max = &_max * 1.1;
     
230. 
     
231.         min = 0;
     
232.         max = round (max, step);
     
233.         bin = (max - min) / 10;
     
234. 
     
235.         call symput('g_y2min', min);
     
236.         call symput('g_y2max', max);
     
237.         call symput('g_y2bin', bin);
     
238. run;
     
239. %mend y2axis;

复制代码

1. data have;
   
2.        LENGTH L1 L2 $12;
   
3.         x =1  ; y =.    ; y1 =10; y2=.   ; L1 ='DDD33'; L2 =''; output;
   
4.         x =1  ; y =.    ; y1=.     ; y2 =9.5; L1 =''; L2= 'UUUUU'; output;
   
5.         x =10; y =10;                                              L2='         '; output;
   
6.         x =0  ; y =0   ;                                                     output;
   
7. run;
   
8. proc sgplot noautolegend;        
   
9.         scatter x =x y =y1 /markerchar =L1 markercharattrs =(color =red);
   
10.         scatter x =x y =y2 /markerchar =L2 markercharattrs =(color =blue);
    
11.         series  x =x y =y/lineattrs =(color =purple);
    
12. run;

复制代码

用inset写入文本有时候很讨厌。试试以下code，先产生一个合适的数据集。
用空格链接A B C 三个变量，CATX(' ', A, B, C)
我有时候先画出一张图然后在用macro做复制。直接编写macro，有些事倍功半的感觉，也增加不必要的复杂。
京剧

jingju11，非常感谢，我去试试。
按照你的思路，我需要使用类似如下的格式：
Inset "sdsddfdfsdfsdf" "";
Inset "" "sdsdfsdfsdfsdfsfd";
Inset "" "" "sdfsdfsfsdsfd";

我去试试利用你之前的第一次回复那个宏能不能产生上面的文字格式。

谢谢！

1. data test;
   
2.   do scale = 1, 2;
   
3.     do x = -3 to 3 by 0.1;
   
4.           pdf = exp(-0.5*x**2)/(sqrt(2*constant('pi'))*scale);
   
5.           cdf = cdf('norm',x,0,sqrt(scale));
   
6.           output;
   
7.         end;
   
8.   end;
   
9. run;
   
10. 
    
11. proc sgplot data=test nocycleattrs;
    
12. series x = x y = pdf/group=scale lineattrs=(pattern=dash thickness=2);
    
13. series x = x y = cdf/group=scale lineattrs=(pattern=solid thickness=2) y2axis;
    
14. run;

复制代码

1. data test;
   
2.   do scale = 1, 2;
   
3.     do x = -3 to 3 by 0.1;
   
4.           pdf = exp(-0.5*x**2)/(sqrt(2*constant('pi'))*scale);
   
5.           cdf = cdf('norm',x,0,sqrt(scale));
   
6.           output;
   
7.         end;
   
8.   end;
   
9. run;
   
10. 
    
11. data _null_;
    
12.   up_down='D'; ss=23355; mean=0.124; std=0.013;
    
13.   call symputx('a',catt(up_down,' ss=',ss,' mean=',mean,' std=',std));
    
14.   up_down='U'; ss=17876; mean=0.123; std=0.014;
    
15.   call symputx('b',catt(up_down,' ss=',ss,' mean=',mean,' std=',std));
    
16. run;
    
17. 
    
18. 
    
19. proc template;
    
20. define statgraph myplot;
    
21.   begingraph;
    
22.     mvar a b;
    
23.     layout overlay;
    
24.       SeriesPlot X=x Y=pdf / primary=true Group=scale Lineattrs=( Pattern=20 Thickness=2) LegendLabel="pdf";
    
25.       SeriesPlot X=x Y=cdf / yaxis=y2 Group=scale Lineattrs=( Pattern=1 Thickness=2) LegendLabel="cdf";
    
26.       Layout Gridded / Border=false halign=left valign=top;
    
27.         Layout Gridded;
    
28.           Entry halign=left a / PAD=(TOP=0  BOTTOM=0  LEFT=3  RIGHT=3) textattrs=(color=red);
    
29.         endlayout;
    
30.       endlayout;
    
31.       Layout Gridded / Border=false halign=left valign=top;
    
32.         Layout Gridded;
    
33.           Entry halign=left b / PAD=(TOP=12  BOTTOM=12  LEFT=3  RIGHT=3) textattrs=(color=blue);
    
34.         endlayout;
    
35.       endlayout;
    
36.     endlayout;
    
37.   endgraph;
    
38. end;
    
39. run;
    
40. 
    
41. proc sgrender data=test template=myplot;
    
42. run;

复制代码

guoluo，真的非常感谢！
我之前也看到过nocycleattrs这个选项，我还以为是指所有线都同一颜色呢，用了这个选项，我连RGB颜色什么的都不用去指定了，直接用默认模板画图都可以。谢谢！



另外，在上面的数据集中，我通过1个宏确定数据集的观测数目，也就是说分为几个组，然后在data _null_里面通过1个循环把上面的数据集提取为系列的宏变量，如下面代码所示，这时候我得到L1，L2这2个宏变量。但我的疑问是怎么通过某些循环将L1-Ln这几个变量代换你代码中的a,b呢？谢谢了！

1. %macro nobs_nvars (_in = );
   
2. %global g_obsnum g_varnum;
   
3. %let dsid = %sysfunc (open (&_in, i));  
   
4. %let g_obsnum = %sysfunc (attrn (&dsid, nobs));
   
5. %let g_varnum = %sysfunc (attrn (&dsid, nvars));
   
6. %let rc = %sysfunc (close (&dsid));
   
7. %mend nobs_nvars;
   
8. 
   
9. %nobs_nvars(_in=_tmp_bin_input);
   
10. 
    
11. data _null_;
    
12.         set _tmp_inset;
    
13.            do i = 1 to &g_obsnum;
    
14.                   call symputx('L'||left(_n_),catt(up_down,' ss=',ss,' mean=',mean,' std=',std));
    
15.           end;
    
16. run;

复制代码

我在想应该可以利用类似下面的代码实现，但不知道怎么用把L1-Ln分别嵌入到&Li的位置。请指教，谢谢！
proc template;define statgraph myplot;
  begingraph;
    mvar a b;
    layout overlay;
      SeriesPlot X=x Y=pdf / primary=true Group=scale Lineattrs=( Pattern=20 Thickness=2) LegendLabel="pdf";
      SeriesPlot X=x Y=cdf / yaxis=y2 Group=scale Lineattrs=( Pattern=1 Thickness=2) LegendLabel="cdf";
      Layout Gridded / Border=false halign=left valign=top;
        Layout Gridded;
                        %textList;
                endlayout;
      endlayout;

    endlayout;
  endgraph;
end;
run;

*......some macro of color list;


%macro textList;        
        %do i =1 %to &g_obsnum;
                        “Entry halign=left &Li / PAD=(TOP=0  BOTTOM=0  LEFT=3  RIGHT=3) textattrs=(color=&colorlist_i);"
        %end;;
%mend textList;

感谢guoluo，jingju11，soporaeternus等网友的热心帮助，经过你们的指导，我的宏终于大体完成了。
这是我第一个作图的宏，有了这个基础，以后其它宏编写起来肯定会快多了，到时有疑难请各位继续多多指导啊。
万分感谢！

小结一下：
1. 通过下面代码可以自定义一个样式模板。

1. proc template;
   
2.         define style nbCDF;
   
3.            parent=Styles.Default;
   
4. ..........

复制代码

2. 通过下面代码可以做出任意图形。（先通过常规作图结合tmpfmt=path可以得到template，再修改template）

1. ods listing style=nbCDF;

复制代码

这是效果图：



这是代码：

1. libname temp "h:\sas";
   
2. 
   
3. %CDF(_in = temp.test, _var = par2, _group = NO,
   
4.                 _maverick_min = 0, _maverick_max = 100, _out = test2, _out_path = %str(H:\SAS));
   
5. %CDF(_in = temp.test, _var = par3, _group = UP_DOWN,
   
6.                 _maverick_min = -10, _maverick_max = 0, _out = test3, _out_path = %str(H:\SAS));
   
7. 
   
8. %macro CDF (_in =, _var =, _group =, _maverick_min =, _maverick_max =, _out =, _out_path =);
   
9. data _data_raw;
   
10.         set &_in (keep = &_var &_group);
    
11.         where &_var ^= .;
    
12. run;
    
13. 
    
14. data _tmp_no_maverick;
    
15.         set _data_raw;
    
16.         where &_var <= &_maverick_max and &_var >= &_maverick_min;
    
17. run;
    
18. 
    
19. %minmax(_in = _tmp_no_maverick, _var = &_var);
    
20. %bin(_mean = &g_mean, _std = &g_std);
    
21. 
    
22. data _tmp_bin;
    
23.         set _data_raw;
    
24.         bin = round(&_var, &g_bin);
    
25. run;
    
26. 
    
27. proc means data = _tmp_bin noprint;
    
28.         var &_var;
    
29.         class &_group bin;       
    
30.         output out=_tmp_bin_sum (drop = _FREQ_)
    
31.                 mean = mean
    
32.                 std = std
    
33.                 n = count;
    
34.         options nolabel;
    
35. run;
    
36. %minmax(_in = _tmp_bin_sum, _var = _TYPE_);
    
37. 
    
38. data _tmp_bin_count;
    
39.         set _tmp_bin_sum;
    
40.         where _TYPE_ = &g_max;
    
41. run;
    
42. proc sort data = _tmp_bin_count (drop = _TYPE_ mean std);
    
43.         by &_group bin;
    
44. run;
    
45. 
    
46. data _tmp_bin_input (rename = (count = input));
    
47.         set _tmp_bin_sum;
    
48.         where _TYPE_ = &g_max - 1;
    
49.         options nolabel;
    
50. run;
    
51. proc sort data = _tmp_bin_input (drop = bin _TYPE_ mean std);
    
52.         by &_group;
    
53. run;
    
54. 
    
55. data _data_sum (rename = (bin = &_var));
    
56.         merge _tmp_bin_count _tmp_bin_input;
    
57.         by &_group;
    
58.         per = 100 * count / input;
    
59.         if &_group = lag1(&_group) then cdf + per;
    
60.         else cdf = per;
    
61. run;
    
62. 
    
63. %minmax(_in = _tmp_no_maverick, _var = &_var);
    
64. %xaxis(_mean = &g_mean, _std = &g_std, _max = &g_max, _min = &g_min);
    
65. 
    
66. %minmax(_in = _data_sum, _var = count);
    
67. %y2axis(_mean = &g_mean, _std = &g_std, _max = &g_max, _min = &g_min);
    
68. 
    
69. %nobs_nvars(_in=_tmp_bin_input);
    
70. proc means data = _tmp_no_maverick noprint;
    
71.         var &_var;
    
72.         class &_group;       
    
73.         output out=_tmp_inset (where = (_TYPE_ = 1))
    
74.                 n = ss
    
75.                 mean = mean
    
76.                 std = std;
    
77.         options nolabel;
    
78. run;
    
79. proc sort data = _tmp_inset (drop = _TYPE_ _FREQ_);
    
80.         by &_group;
    
81. run;
    
82.        
    
83. data _tmp_inset;
    
84.         update _tmp_inset _tmp_bin_input (rename = (input = ss));
    
85.         by &_group;
    
86. run;
    
87. %deleteLn;
    
88. %getString (_in = _tmp_inset);
    
89. 
    
90. ods path sashelp.tmplmst(read) sasuser.templat(update);
    
91. proc template;
    
92.         define style nbCDF;
    
93.            parent=Styles.Default;
    
94.         style Graph from Graph /   
    
95.                 OutputWidth = 7.5in
    
96.               OutputHeight = 5.5in;
    
97.         class color_list /
    
98.               'bgA' = cxC0C0C0;
    
99.         class GraphColors /
    
100.                 'gwalls' = cxFFFFFF
     
101.                 'glegend' = cxC0C0C0
     
102.                 'ggrid' = cx909090;
     
103.         class GraphFonts /
     
104.                 'GraphDataFont' = ("<sans-serif>, <MTsans-serif>",14pt)
     
105.               'GraphValueFont' = ("<sans-serif>, <MTsans-serif>",14pt)
     
106.               'GraphLabelFont' = ("<sans-serif>, <MTsans-serif>",14pt,bold)
     
107.               'GraphFootnoteFont' = ("<sans-serif>, <MTsans-serif>",12pt)
     
108.               'GraphTitleFont' = ("<sans-serif>, <MTsans-serif>",16pt,bold);
     
109.     end;
     
110. run;
     
111. 
     
112. options jpegquality = 95;
     
113. ods graphics on / imagefmt= JPEG
     
114.                                 imagename="&_out"
     
115.                                 width=7.5in
     
116.                                 height=5.5in;
     
117. ods listing gpath="&_out_path"
     
118.                         style=nbCDF;
     
119. 
     
120. proc template;
     
121.         define statgraph myplot;
     
122.           begingraph;
     
123.             mvar L1 L2 L3 L4 L5 L6 L7 L8 L9 L10 L11 L12;
     
124.                   entrytitle "&_var CDF Plot by &_group";
     
125.                   entryfootnote halign=right "xxx";
     
126.             layout overlay / yaxisopts = (griddisplay = on label = "CDF (%)"
     
127.                                                                         linearopts = (tickvaluesequence = (start = 0 end = 100 increment = 10))
     
128.                                                                         linearopts = (viewmin = 0 viewmax = 100))                                                                         
     
129.                                                 y2axisopts = (griddisplay = on label = "Count (N)"
     
130.                                                                         linearopts = (tickvaluesequence = (start = &g_y2min end = &g_y2max increment = &g_y2bin))
     
131.                                                                         linearopts = (viewmin = &g_y2min viewmax = &g_y2max))
     
132.                                                 xaxisopts = (griddisplay = on label = "&_var"
     
133.                                                                         linearopts = (tickvaluesequence = (start = &g_xmin end = &g_xmax increment = &g_xbin))
     
134.                                                                         linearopts = (viewmin = &g_xmin viewmax = &g_xmax));
     
135.                         seriesplot x = &_var y = cdf / primary = true group = &_group
     
136.                                                         lineattrs = ( pattern = 1 thickness = 3) name = "y1";
     
137.                       seriesplot x = &_var y = count / yaxis = y2 group = &_group
     
138.                                                         lineattrs = ( pattern = 5 thickness = 1) name = "y2";
     
139.                      layout gridded / autoalign = (right) location = inside;
     
140.                                 discretelegend "y1" / title = "" across = 1;
     
141.                  endlayout;
     
142. 
     
143.                       Layout Gridded / Border=false halign=left valign=top;
     
144.                           entry halign = left L1 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx2A25D9 size = 12pt);
     
145.                           entry halign = left L2 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cxB2182B size = 12pt);
     
146.                           entry halign = left L3 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx01665E size = 12pt);
     
147.                           entry halign = left L4 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx543005 size = 12pt);
     
148.                          entry halign = left L5 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx9D3CDB size = 12pt);
     
149.                          entry halign = left L6 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx7F8E1F size = 12pt);
     
150.                           entry halign = left L7 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx2597FA size = 12pt);
     
151.                           entry halign = left L8 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cxB26084 size = 12pt);
     
152.                           entry halign = left L9 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cxD17800 size = 12pt);
     
153.                           entry halign = left L10 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cx47A82A size = 12pt);
     
154.                          entry halign = left L11 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cxB38EF3 size = 12pt);
     
155.                          entry halign = left L12 / pad = (top = 2  bottom = 2 left = 3 right = 3) textattrs = (color = cxF9DA04 size = 12pt);
     
156.                      endlayout;
     
157.             endlayout;
     
158.           endgraph;
     
159. end;
     
160. run;
     
161. 
     
162. proc sgrender data = _data_sum template=myplot;
     
163. run;
     
164. 
     
165. ods listing close;
     
166. ods graphics off;
     
167. ods trace off;
     
168. 
     
169. proc datasets library=work nolist;
     
170.         delete  _tmp_no_maverick _stat _tmp_bin _tmp_bin_sum _tmp_bin_count _tmp_bin_input _tmp_inset _data_raw _data_sum;
     
171. run;
     
172. 
     
173. %mend CDF;
     
174. 
     
175. %macro nobs_nvars (_in = );
     
176. %global g_obsnum g_varnum;
     
177. %let dsid = %sysfunc (open (&_in, i));  
     
178. %let g_obsnum = %sysfunc (attrn (&dsid, nobs));
     
179. %let g_varnum = %sysfunc (attrn (&dsid, nvars));
     
180. %let rc = %sysfunc (close (&dsid));
     
181. %mend nobs_nvars;
     
182. 
     
183. %macro minmax(_in =, _var =);
     
184. %global g_mean g_median g_min g_max g_std g_ss;
     
185. proc means data = &_in noprint;
     
186.         var &_var;
     
187.         output out=_stat
     
188.                 mean = g_mean
     
189.                 median = g_median
     
190.                 min = g_min
     
191.                 max = g_max
     
192.                 std = g_std
     
193.                 n = g_ss;
     
194. run;
     
195. 
     
196. data _null_;
     
197.    set _stat;
     
198.    call symput('g_mean', g_mean);
     
199.    call symput('g_median', g_median);
     
200.    call symput('g_min', g_min);
     
201.    call symput('g_max', g_max);
     
202.    call symput('g_std', g_std);
     
203.    call symput('g_ss', g_ss);
     
204. run;
     
205. %mend minmax;
     
206. 
     
207. %macro bin(_mean =, _std = _max =, _min =);
     
208. %global g_bin;
     
209. data _null_;
     
210.         mean = &_mean;
     
211.         if mean < 0 then mean = abs(mean);
     
212.         step = floor(log10(mean)) - 2;
     
213.         step = 10 ** step;
     
214. 
     
215.         min = &_mean - 3 * &_std;
     
216.         max = &_mean + 3 * &_std;
     
217.         bin = (max - min) / 50;
     
218.         bin = round (bin, step);
     
219. 
     
220.         call symput('g_bin', bin);
     
221. run;
     
222. %mend bin;
     
223. 
     
224. %macro deleteLn;
     
225. %do i = 1 %to 12;
     
226.         %symdel L&i;
     
227. %end;
     
228. %mend deleteLn;
     
229. 
     
230. %macro getString (_in =);
     
231. data _null_;
     
232.         set &_in;
     
233.         length str $1000;
     
234.         array _n _numeric_;
     
235.         array _c _character_;
     
236.     do over _c;
     
237.                    if compress(upcase(vname(_c)))^="STR" then
     
238.               str=catx(" ",str,catx("=",vname(_c),_c));
     
239.     end;
     
240.         do over _n;
     
241.                 if abs(_n) < 1 then
     
242.                         str = catx(" ", str, catx("=", vname(_n), put(_n, 10.3)));
     
243.                 else if abs(_n) < 1000 then
     
244.                         str = catx(" ", str, catx("=", vname(_n), put(_n, 10.1)));
     
245.                 else
     
246.                         str = catx(" ", str, catx("=", vname(_n), put(_n, 10.0)));
     
247.         end;
     
248.         call symputx(compress("L"||_N_),str);
     
249.         %do i=1 %to &g_obsnum;
     
250.                 %global L&i;
     
251.         %end;
     
252. run;
     
253. %mend getString;
     
254. 
     
255. %macro xaxis(_mean =, _std =, _max =, _min =);
     
256. %global g_xmin g_xmax g_xbin;
     
257. data _null_;
     
258.         mean = &_mean;
     
259.         if mean < 0 then mean = abs(mean);
     
260.         step = floor(log10(mean)) - 1;
     
261.         step = 10 ** step;
     
262. 
     
263.         min = &_mean - 3 * &_std;
     
264.         max = &_mean + 3 * &_std;
     
265.         bin = (max - min) / 10;
     
266. 
     
267.         min = round (min, step);
     
268.         max = round (max, step);
     
269.         bin = round (bin, step);
     
270. 
     
271.         call symput('g_xmin', min);
     
272.         call symput('g_xmax', max);
     
273.         call symput('g_xbin', bin);
     
274. run;
     
275. %mend xaxis;
     
276. 
     
277. 
     
278. %macro y2axis(_mean =, _std =, _max =, _min =);
     
279. %global g_y2min g_y2max g_y2bin;
     
280. data _null_;
     
281.         max = &_max;
     
282.         if max < 0 then max = abs(max);
     
283.         step = floor(log10(max));
     
284.         step = 10 ** step;
     
285. 
     
286.         max = &_max * 1.1;
     
287. 
     
288.         min = 0;
     
289.         max = round (max, step);
     
290.         bin = (max - min) / 10;
     
291. 
     
292.         call symput('g_y2min', min);
     
293.         call symput('g_y2max', max);
     
294.         call symput('g_y2bin', bin);
     
295. run;
     
296. %mend y2axis;

复制代码

另外，我觉得你应该不是初学者吧？sas绘图这一块需要对sas概念和结构有一定的理解。我也感到你对问题的解决方法比较对路。
京剧

算是初学者吧，呵呵。
我几年前很粗糙地学过SAS，学习的结果仅仅是了解界面，逻辑库和data,  proc, where, set, by这些语句;
2、3个月前比较认真地学过the little sas book，动机是原始数据很大，JMP处理不过来。学完后写了1个长度和上面这个差不多的宏，用于自动下载，整理，连接数据。处理完以后数据变小了，就又用JMP做统计和作图了；
上面这个程序是我写的第二个程序。我准备再写几个程序作图，例如binX-Y图，X-Y加spline图，有了这个程序的经验（作图）和第一个程序经验（处理数据），剩下的主要是一些体力劳动，对着帮助查找具体设置。
我现在面临最大的问题是宏变量这一块，基本概念都没掌握好，例如上面的程序，我就不知道哪些地方应该用%if哪些不能用%。
想认真从基本学起心态又急于求成，哎。请问有没有比较系统的SAS教程推荐啊？谢谢！

上面的程序没有你们的指导，根本无法完成啊。

上面写漏了：

2. 通过下面代码可以做出任意图形。（先通过常规作图结合tmpfmt=path可以得到template，再修改template）

1. ods listing style=nbCDF;
   
2. 
   
3. proc template;
   
4.         define statgraph myplot;
   
5.           begingraph;

复制代码

厉害，正好遇到类似的问题，你的帖子完全帮助我解决了问题。