请问：怎样用if语句，根据数据集B的list，将数据集A的对应观测筛选出来？

大家好。

我想问一个问题：怎样通过if条件语句，根据数据集B的list(在这里具体是num和t)，将数据集A的对应观测筛选出来，并生成新的数据集pickout?

dataA;

            input num    t   x;

            cards;

                        1        78        4

                        1        79        5

                        2        79        .

                        3        80        2

                        3        81        3

                        4        79        0

                        5        55        3

                        5        4         1

            ;

run;

dataB;

            input num  t;

            cards;

                        1  78

                        3  80

                        5  4

            ;

run;

期望的数据集pickout应该是:

                        1        78        4

                        3        80        2

                        5        4         1

我知道用procsql的select, exists可以很快地做出来，但不清楚是否可以在data语句中的用if来完成同样的工作？

谢谢！

Data步：

data A;
            input num    t   x;
            cards;
1        78        4
1        79        5
2        79        .
3        80        2
3        81        3
4        79        0
5        55        3
5        4         1
;
run;


data B;
  input num  t;
  cards;
  1  78
  3  80
  5  4
;
run;

*****************************;
data c;
    set b;
        do i=1 to nobs;
           set a(rename=(num=num1 t=t1)) nobs=nobs point=i;
           put num= num1=;
       if num=num1 and t=t1 then output;
        end;
        keep num t x;
run;

*********************************;
proc sort data=a ; by num t;run ;
data d;
   merge a b(in=inb);
   by num t;
   if inb;
run;

**********************************;
data e;
    if 0 then set b;
        if _n_=1 then do;
            declare hash b(dataset:"b");
                           b.definekey('num','t');
                           b.definedata('num','t');
                           b.definedone();
        end;
        set a;
        if b.find()=0;
run;

1. data pickout;
   
2.   if _n_=1 then do;
   
3.   if 0 then set a;
   
4.   declare hash ht (dataset : "a");
   
5.   ht.definekey("num","t");
   
6.   ht.definedata("x");
   
7.   ht.definedone();
   
8. end;
   
9. set b;
   
10. ht.find(key: num,key :t);
    
11.   run;

复制代码

pobel 发表于 2012-9-19 15:52
Data步：

data A;

NB~~

lbnjin 发表于 2012-9-20 01:30
NB~~

呵呵，webgu的更加精简呀