高手进！关于增加一行累加结果的观测

data kkk;                                                                                                                           
input a $3.  b 4. c 4. ;                                                                                                               
cards;                                                                                                                                 
K1 1    4                                                                                                                              
K2 2    5                                                                                                                              
K3 3    6                                                                                                                              
;                                                                                                                                       
run;         

简单举例如上，假如一共有Kn 个观测，现想增加一行观测在最后一行的Kn下面，增加的最后的观测，a 字段名称为ALL , B、C字段 是 K1-Kn的加总和，如何用代码实现？？求高手解答！请附上代码~ 非常感谢！！

1. data lll;
   
2. do until(eof);
   
3. set kkk end=eof;
   
4. _b= sum(_b, b);
   
5. _c = sum(_c, c);
   
6. output;
   
7. end;
   
8. a='ALL';
   
9. b=_b;
   
10. c=_c;
    
11. output;
    
12. drop _b _C;
    
13. 
    
14. *or use proc tabulate/report etc;
    
15. proc tabulate data=kkk order=data out=lll;
    
16. class a;
    
17. var b c;
    
18. tables a all, b*sum c*sum;
    
19. data lll;
    
20. set lll(keep=a b_sum c_sum rename=(b_sum=b c_sum=c));
    
21. if a=' ' then a='ALL';
    
22. run;

复制代码

干嘛的

proc sql;
  create table summary as
  select sum(b) as b,sum(c) as c
    from kkk;
quit;
data final;
  set kkk summary;
  if a=' ' then a='ALL';
run;

or

data sum_down(drop = sum_b sum_c);
  set kkk end=last;
  sum_b+b;sum_c+c;output;
  if last then do;
    a='ALL';
    b=sum_b;
    c=sum_c;
    output;
  end;
run;

data bbb;
   set kkk end=eof;
   sum_b + b;
   sum_c + c;
   if eof then do;
   a = 'All';
   b = sum_b;
   c = sum_c;
   output;
   end;
   drop sum_b sum_c;
run;
data result;
    set kkk bbb;
run;

邓贵大 发表于 2013-5-3 21:26

第二种，tabulate 的思路给我启发，非常感谢！

rdwalk 发表于 2013-5-3 21:51
proc sql;
  create table summary as
  select sum(b) as b,sum(c) as c

非常感谢您的思路和代码~！由于楼上答案也是准确的在先，所以不能把分给你了，谢谢！