求助：各种纠结的数据更新。请大家帮忙，辛苦了。

数据设定为A组ID值包含B组ID值，反言之B组ID值必然会在A组中出现。

数据处理仅对B组ID值对应的A组观测的 NEXIST DE NDE PONE 共4个变量值进行更新。 两组数举例如下，

数据A   

变量ID  TYPE   STATUS  NEXIST  DE  NDE  PONE

       hij   MC        ZC            1         0      0      0

       aaa MC        ZC           1         0      0     0

       bbb MC        ZC            1        0      0     0

       fgh MC        QX            1        0       0     0

数据B  

变量ID  TYPE  STATUS  TIME

        aaa PER    ZC      40

        bbb  PER   QX       29

更新规则如下：

若A组数据ID存在对应的B组ID,则将相应A组ID观测的NEXIST值更改为0，若A组数据ID没有对应的B组ID观测，A组数据相应NEXIST值仍保持为1.

当A组数据ID值在B组数据存有对应ID值，且B组对应ID观测 STATUS为QX时，A组相应观测DE值变为1，否则DE保持为0

当A组数据ID值存在B组数据对应ID值，且B组对应ID观测 STATUS为ZC时，A组相应NDE值变为1，否则NDE保持为0

当A组数据ID值存在B组数据对应ID值，且B组对应ID观测 TIME小于等于30时，A组相应PONE值变为1，否则PONE保持为0

理想结果为  数据A   

变量ID  TYPE   STATUS  NEXIST  DE  NDE  PONE  

        hij     M        ZC           1          0     0       0   

        aaa  M        ZC           0          0     1       0

        bbb M        ZC           0          1     0       1

        fgh  M        QX           1          0     0       0   

  

SAS新手，想了很久也没有结果，所以请大家帮忙解答，谢谢大家了。不知道逻辑写的清不清楚，已经尽量了。

对比A组4各变更变量NEXIST DE NDE和PONE的原始数据与更新后数据

更新前

aaa M  ZC  1  0  0   0

bbb M  ZC  1  0  0   0

更新后

aaa M  ZC  0  0  1   0

bbb M  ZC  0  1  0   1

proc sql;
create table c as
select t.id ,t.type,t.status,
case when t1.type is not null then 0 else t.NEXIST end as NEXIST,
case when t1.STATUS='QX' then 1 else t.DE  end as DE,
case when t1.STATUS='ZC' then 1 else t.NDE  end as NDE,
case when t1.time is not null and t1.time<=30  then 1 else t.PONE end as PONE
from a t
left join
b t1
on t.id=t1.id;
quit;

希望能得到大家的帮助， 先谢过了。

1. data a;
   
2. input ID $ TYPE $ STATUS $ NEXIST  DE  NDE  PONE;
   
3. datalines;
   
4. hij MC ZC 1 0 0 0
   
5. aaa MC ZC 1 0 0 0
   
6. bbb MC ZC 1 0 0 0
   
7. fgh MC QX 1 0 0 0
   
8. ; run;
   
9. 
   
10. data b;
    
11. input ID $ TYPE $ STATUS $ TIME;
    
12. datalines;
    
13. aaa PER ZC 40
    
14. bbb PER QX 29
    
15. ; run;
    
16. 
    
17. proc sort data=a; by id; run;
    
18. proc sort data=b; by id; run;
    
19. 
    
20. data c;
    
21.     merge a(in=ina) b(in=inb rename=(type=type_b status=status_b));
    
22.     by id;
    
23.     if ina;
    
24. run;
    
25. 
    
26. data want;
    
27.     set c;
    
28.    NEXIST = ifc(missing(type_b), 1,0);
    
29.        DE = ifc(not missing(type_b) and status_b='QX', 1, 0);
    
30.       NDE = ifc(not missing(type_b) and status_b='ZC', 1, 0);
    
31.      PONE = ifc(not missing(type_b) and time <= 30, 1,0);
    
32.   drop type_b status_b time;
    
33. run;
    
34. proc print data=want; title 'want'; run;

复制代码

在线等

ziyenano 发表于 2013-7-12 23:12
proc sql;
create table c as
select t.id ,t.type,t.status,

谢谢您的帮忙，水平真的高超，向您学习，希望以后基础雄厚些了也可以像您一样帮助其他朋友解决问题。 再次感谢！

yongyitian 发表于 2013-7-13 00:32

真的是太感谢了，看到您最后一次编辑是在凌晨时间01:12，我只能说是感动的一塌糊涂，辛苦了辛苦了。您的代码看起来调理同样很清晰，用较为常见的代码解决了这个问题，感觉到您的基础功底真的是非常的扎实。虽然没有选择您的答案为最佳答案，但希望您知道我真的是非常的感谢您的帮忙，解决了昨天困扰了好久的问题。谢谢了。