请问如何删除每组第一个观测，仅有一个则不删

有如下所示的数据集

data have;
input Cat $ Val;
datalines;
A 1
A 2
B 3
C 4
C 5
C 6
;
run;

我的目的是：如果一个组里只有一个观测，则保留；若有多个，则删除第一个，保留余下的
我估计用data步的话，一步是不行的
我想用一步proc sql解决，不知道having子句该怎么写
请教大神了

不知道这样是不是楼主想要的结果：

data have;
input Cat $ Val;
datalines;
A 1
A 2
C 88
B 3
C 4
C 5
C 6
;
run;

proc sql;
  create table wanted(drop=tmp) as
   select *,monotonic() as tmp
    from have
        group by cat
    having count(*)=1 or tmp>min(tmp)
    order by tmp;
quit;

好，谢谢

多个排序
proc sort data=have;
by cat;
run;

data want;
set have;
by cat;
if first.cat and ^last.cat then delete;
run;

看需求的话，数据的顺序应该是不能动的：
data want;
set have;
by cat notsorted;
if first.cat and ^last.cat then delete;
run;

pobel 发表于 2013-7-22 17:16
不知道这样是不是楼主想要的结果：

data have;

对，就是这样，多谢pobel神

我只想到了得用个辅助变量，但是不知道这一步
create table wanted(drop=tmp) as

我还想着必须要再加一步删变量呢
还是sql用得不熟啊

pobel 发表于 2013-7-22 17:16
不知道这样是不是楼主想要的结果：

data have;

很赞，学习了~~

1. data have;
   
2. input Cat $ Val;
   
3. datalines;
   
4. A 1
   
5. A 2
   
6. B 3
   
7. C 4
   
8. C 5
   
9. C 6
   
10. ;
    
11. run;
    
12. 
    
13. proc sort data=have;
    
14.         by cat;
    
15. run;
    
16. 
    
17. data want;
    
18.         set have;
    
19.         by Cat;
    
20.         if first.cat and first.cat^=last.cat then delete;
    
21. run;

复制代码

可~乐 发表于 2013-7-22 18:03

嗯，这样也行
之前没想到，就想着用sql了

用First和Last的较为传统的解决方案。