如何将字符型变量按照指定顺序排序

例如，我有如下数据集：

data aaa;
input x $ @@;
cards;
a a s s d d f f d s d a f s d a f s
;
run;

我就想把x按照：a d s f（我自己指定的顺序）排序，请问有无办法，谢谢。

我不想用衍生变量，我希望寻求直接的方法。

data aaa;
input x $ @@;
cards;
a a s s d d f f d s d a f s d a f s
;
run;

data tmp;
input x $ @@;
id=_n_;
cards;
a d s f
;
run;

proc sql;
create table bbb as
select t.x from
aaa t
inner join
tmp t1
on t.x=t1.x
order by t1.id;
quit;

这个算不算辅助变量？

you can define a auxiliary variable as below and sort by that auxiliary variable.

proc format ;
value $myorder
a=1
d=2
s=3
f=4
;
run;

data aaa;
input x $ @@;
xorder=put(x, $myorder.);
cards;
a a s s d d f f d s d a f s d a f s
;
run;

proc sort data=aaa; by xorder; run;

proc print;run;

bobguy 发表于 2013-8-13 10:32
you can define a auxiliary variable as below and sort by that auxiliary variable.

proc format ;

Yes. Auxiliary variable must be the effectively way to deal with the problem. But I only wonder if here exist another directly way, such a proc stop, a option in proc sort, to solve this problem.

1. data aaa_sort;
   
2.     set  aaa(where = (x='a'))
   
3.          aaa(where = (x='d'))
   
4.          aaa(where = (x='s'))
   
5.          aaa(where = (x='f'));
   
6. run;

复制代码

{:3_42:}

yongyitian 发表于 2013-8-13 12:46

Really a good idea!