如何判断一个数据集为空或0个观测值

NOTE: 数据集 WORK.TEMP2 有 0 个观测和 8 个变量。
NOTE: “PROCEDURE MEANS”所用时间（总处理时间）:
      实际时间          0.02 秒
      CPU 时间          0.03 秒

如何判断一个数据集为空或0个观测值以及如何在macro写条件语句？谢谢！

data _null_;
        if 0 then set sashelp.class nobs=nobs;
        call symputx('nobs',nobs);
        stop;
run;

%macro test;
%if &nobs=0 %then %put empty;
%else %put not empty;
%mend test;

%test

*definition of a simple macro;
%macro  datasetcheck(dsname);
     %global  nobs;
         %let  dsid=%sysfunc(open(&dsname));
          %if  &dsid %then
            %do;
                     %let nobs=%sysfunc(attrn(&dsid,nobs));
                         %let rc=%sysfunc(close(&dsid));
                         %put  The dataset :&dsname has &nobs of observation ;
                %end;
      %else   %put open  dataset &dsname failed %sysfunc(sysmsg()) ;
%mend;

*a demo;
%datasetcheck(sashelp.class)

webgu 发表于 2013-12-8 14:31
*definition of a simple macro;
%macro  datasetcheck(dsname);
     %global  nobs;

%let nobs=%sysfunc(attrn(&dsid,nobs));
和
data test;
rc = open('sashelp.class');
test = attrn(rc,'nobs');
run;

红色的code为什么可以不加''？

zw612003 发表于 2013-12-8 19:55
%let nobs=%sysfunc(attrn(&dsid,nobs));
和
data test;

%sysfunc 是在宏程序的环境里，不需要引号把字符 引起来。