求助，怎么在IF语句里使用Do循环

大概是这样，我想往缺少的时间戳里填补数据。（比如说9:00:01到9:00:05         如果没有数据，那么我就将9:00:00的数据复制给9:00:01到9:00:05，当然我是在9:00:06才能发现9:00:01到9:00:05没有数据的）。

但是发现无法用IF语句来使用循环。(if then do ……do i=1 to tickgap  …. End 这样好像无法运行)。

data a;

    set timelist;

    timegap=intck('second',lag(time),time); /* 检查是否丢失*/

    if timegap>1 then do   /*填补丢失时间*/

    do i=1to tickgap;

    temptime=time;

    tempvalue=value;

   time=time+'0:00:01't;/*循环复制上一个时间的数据到当前行*/

    value=lag(value);

    output;

   time=temptime;/*将最新行恢复为当前时间数据*/

   value=    tempvalue

    end;

    end;

数据格式：
9:00:00 1
9:00:06 6
9:00:07 7
9:00:08 8


希望生成的结果
9:00:00 1
9:00:01 1
9:00:02 1
9:00:03 1
9:00:04 1
9:00:05 1
9:00:06 6
9:00:07 7
9:00:08 8

data timelist;
   input time : time8. n;
   format time time8.;
   cards;
9:00:00 1
9:00:06 6
9:00:07 7
9:00:08 8
;

data a;
    set timelist nobs=nobs;
        if _N_<nobs then do;
        set timelist(firstobs=2 rename=(time=time1 n=n1));
                output;
        do while(time<time1-1);
                   time+1;output;
                end;
        end;
        else output;
        drop time1 n1;
run;
          

pobel 发表于 2014-1-26 09:26
data timelist;
   input time : time8. n;
   format time time8.;

大神啊  学习了

1. data timelist;
   
2. input time time. value;
   
3. format time time.;
   
4. datalines;
   
5. 9:00:00 1
   
6. 9:00:06 6
   
7. 9:00:07 7
   
8. 9:00:08 8
   
9. 9:00:10 10
   
10. ; run;
    
11. 
    
12. /* using hash table */
    
13. data _null_;
    
14.    if 0 then set timelist;
    
15.    declare hash h(dataset: 'timelist', ordered: 'a');
    
16.    declare hiter hi('h');
    
17.    h.definekey('time');
    
18.    h.definedata('time', 'value');
    
19.    h.definedone();
    
20.            hi.last();   maxtime = time;
    
21.       rc = hi.first();  mintime = time;
    
22.    do while(rc=0);
    
23.        do time = mintime to maxtime;
    
24.           if h.find() then  h.add();
    
25.        end;
    
26.        rc=hi.next();
    
27.    end;
    
28.      rc=h.output(dataset: 'bbb');      
    
29. run;
    
30. 
    
31. /* data step */
    
32. data a;
    
33.     set timelist;
    
34.     time_lag = lag(time);
    
35.    value_lag = lag(value);
    
36.     if  time - time_lag > 1 then do;   
    
37.        tempvalue = value;
    
38.            value = value_lag;
    
39.          do time = time_lag +1 to time-1;
    
40.             output;
    
41.          end;  
    
42.            value = tempvalue; output;
    
43.      end;
    
44.      else output;
    
45.     keep time value;;
    
46. run;

复制代码

pobel 发表于 2014-1-26 09:26
data timelist;
   input time : time8. n;
   format time time8.;

多谢大神！  
set timelist nobs=nobs; 这句怎么理解

yongyitian 发表于 2014-1-26 13:03

加入哈希表的作用是做什么呢，BBB木有看懂。。。。

wildpanda 发表于 2014-1-27 10:50
多谢大神！  
set timelist nobs=nobs; 这句怎么理解

请查看帮助里的SET语句 nobs=选项

wildpanda 发表于 2014-1-27 11:30
加入哈希表的作用是做什么呢，BBB木有看懂。。。。

先把数据集timelist按变量time的升序排列放入hash表中，然后从最小的time到最大的time值循环查找, 把缺失的添加到表中。最后将hash表的数据输出到数据集bbb。

下面的数据步和你的code差不多。

yongyitian 发表于 2014-1-27 11:54
先把数据集timelist按变量time的升序排列放入hash表中，然后从最小的time到最大的time值循环查找, 把缺失 ...

多谢  BBB只出现在HASH步，后面不需要引用BBB吗