求助补齐观测

想把观测补齐    一种是按照起始时间   

第二种是给定一个结束的时间   比如1998 1

请下载   例子   文件啊    不要下载另一个了

小鳄鱼a 发表于 2015-11-2 14:21
谢谢  能否解释下这段啊

生成连续的季度时间啊
first.name时候的qtr就是开始时间，从开始时间循环到你要的结束时间，循环一次输出一条

不知道有没更好的方法

1. data rawdata;
   
2. input name$ year qtr var var1$;
   
3. qtr2=yyq(year,qtr);
   
4. format qtr2 yyq6.;
   
5. cards;
   
6. a        1996        3        2        or
   
7. a        1996        4        3        or
   
8. a        1997        1        6        or
   
9. a        1997        4        9        or
   
10. b        1995        1        7        ob
    
11. b        1996        1        6        ob
    
12. ;
    
13. run;
    
14. 
    
15. proc sort data=rawdata;
    
16. by name qtr2;
    
17. run;
    
18. 
    
19. **取开始和结尾时间;
    
20. data test;
    
21.         set rawdata;
    
22.         retain begin_qtr;
    
23.         by name;
    
24.         if first.name then begin_qtr=qtr2;
    
25.         if last.name then do; end_qtr=qtr2; output;end;
    
26.         keep name begin_qtr end_qtr var1;
    
27.         format begin_qtr end_qtr yyq6.;
    
28. run;
    
29. 
    
30. **生成连续时间数据集;
    
31. data test2;
    
32.         set test;
    
33.         con_qtr=intnx('qtr',begin_qtr,-1);       
    
34.         do until(con_qtr=end_qtr);
    
35.                 con_qtr=intnx('qtr',con_qtr,1);
    
36.                 output;
    
37.         end;
    
38.         format con_qtr yyq6.;
    
39.         drop begin_qtr end_qtr;
    
40. run;
    
41. 
    
42. **合并;
    
43. data test3;
    
44.         merge test2(rename=(con_qtr=qtr2)) rawdata(keep=name qtr2 var);
    
45.         by name qtr2;
    
46.         year=year(qtr2);
    
47.         qtr=qtr(qtr2);
    
48.         drop qtr2;
    
49. run;

复制代码

木叶知秋 发表于 2015-11-2 00:26
不知道有没更好的方法

谢谢     如果 对所有name给定一个结束的时间   比如1998 1  该怎么写呢

小鳄鱼a 发表于 2015-11-2 08:45
谢谢     如果 对所有name给定一个结束的时间   比如1998 1  该怎么写呢

那就更简单了 你把end_qtr改成1998Q1就行了

1. data rawdata;
   
2. input name$ year qtr var var1$;
   
3. qtr2=yyq(year,qtr);
   
4. format qtr2 yyq6.;
   
5. cards;
   
6. a        1996        3        2        or
   
7. a        1996        4        3        or
   
8. a        1997        1        6        or
   
9. a        1997        4        9        or
   
10. b        1995        1        7        ob
    
11. b        1996        1        6        ob
    
12. ;
    
13. run;
    
14. 
    
15. proc sort data=rawdata;
    
16. by name qtr2;
    
17. run;
    
18. 
    
19. **生成连续时间数据集;
    
20. data test;
    
21.         set rawdata;
    
22.         by name;
    
23.         if first.name then do;
    
24.                         con_qtr=intnx('qtr',qtr2,-1);        
    
25.                 do until(con_qtr=yyq(1998,1));
    
26.                         con_qtr=intnx('qtr',con_qtr,1);
    
27.                         output;
    
28.                 end;
    
29.                 end;
    
30.                 format con_qtr yyq6.;
    
31.                 keep name con_qtr var1;
    
32. run;
    
33. 
    
34. 
    
35. **合并;
    
36. data test2;
    
37.         merge test(rename=(con_qtr=qtr2)) rawdata(keep=name qtr2 var);
    
38.         by name qtr2;
    
39.         year=year(qtr2);
    
40.         qtr=qtr(qtr2);
    
41.         drop qtr2;
    
42. run;

复制代码

木叶知秋 发表于 2015-11-2 10:42
那就更简单了 你把end_qtr改成1998Q1就行了

谢谢  能否解释下这段啊   


    if first.name then do;
                        con_qtr=intnx('qtr',qtr2,-1);        
                do until(con_qtr=yyq(1998,1));
                        con_qtr=intnx('qtr',con_qtr,1);
                        output;
                end;
                end;

木叶知秋 发表于 2015-11-2 10:42
那就更简单了 你把end_qtr改成1998Q1就行了

这个是怎么保证加一个季度或者年的呢    有没有i=i+1之类的   

                do until(con_qtr=yyq(1998,1));
                        con_qtr=intnx('qtr',con_qtr,1);
                        output;

小鳄鱼a 发表于 2015-11-2 15:25
这个是怎么保证加一个季度或者年的呢    有没有i=i+1之类的   

                do until(con_qtr=yyq ...

con_qtr=intnx('qtr',con_qtr,1);就是循环控制语句啊
intnx函数就是把con_qtr每次循环加一个季度

木叶知秋 发表于 2015-11-2 15:32
con_qtr=intnx('qtr',con_qtr,1);就是循环控制语句啊
intnx函数就是把con_qtr每次循环加一个季度

是不是如果不在循环结构中只有跳到某个日期的功能，在循环结构中就有了循环控制功能

小鳄鱼a 发表于 2015-11-2 15:44
是不是如果不在循环结构中只有跳到某个日期的功能，在循环结构中就有了循环控制功能

就是用跳到某个日期的功能  循环控制语句不是只有i+1这种
这里的退出循环条件是con_qtr=yyq(1998,1)，con_qtr每次增加一个季度，到1998Q1就退出循环