请教sas做象限图

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

请教高手，sas如何做象限图

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏0 回帖

关键词：请教高手 请教 SAS 象限

SAS官网的一个例子，程序注释详细，annotate语句相关内容比较多，关键语句不多。

1. /* AXIS and BUBBLE statement options create a bubble */
   
2. /* plot divided by reference lines into quadrants. The */
   
3. /* Annotate facility positions the labels for the */
   
4. /* quadrant, reference lines and bubbles. */
   
5. /*******************************************************/
   
6. 
   
7. 
   
8. goptions reset=global gunit=pct cback=gray88 ctext=white
   
9. ftext=swissl htext=2.5 border;
   
10. 
    
11. /* Create input data set, AUTODATA. AUTODATA contains */
    
12. /* the results of an informal local survey of selected */
    
13. /* automobiles. SHARE is the percent of total autos */
    
14. /* surveyed. RATING indicates practicality vs. */
    
15. /* sportiness on a scale of 1 to 10. PRICE is cost in */
    
16. /* thousands of dollars. */
    
17. 
    
18. data autodata;
    
19. input auto $ 17. share rating price;
    
20. datalines;
    
21. Mazda Miata .10 9.4 15.2
    
22. Chevy S-10 .10 2.9 13.8
    
23. Infiniti M30 .075 7.2 24.3
    
24. Ford Taurus .10 4.3 13.3
    
25. Plymouth Voyager .20 1.8 13.2
    
26. Toyota Cressida .15 6.0 23.7
    
27. Honda Civic .10 3.7 7.0
    
28. Acura Integra .175 6.5 12.1
    
29. ;
    
30. 
    
31. 
    
32. /* Create the annotate data set, LABELS. LABELS adds */
    
33. /* text to the quadrants and labels the bubbles with the */
    
34. /* make of auto represented. Because the value of WHEN */
    
35. /* is a (after), Annotate adds the text after the plot */
    
36. /* is drawn. */
    
37. 
    
38. data labels;
    
39. length color $ 8 text $ 17;
    
40. retain function 'label' hsys '3' style 'swissi' when 'a';
    
41. 
    
42. if _n_=1 then
    
43. do;
    
44. xsys='1'; ysys='1'; size=3; color='blue';
    
45. /* The labels are positioned using the absolute percent */
    
46. /* of the data area, the coordinate system 1. */
    
47. 
    
48. y=97; /* Vertical position for labels across the top of the plot. */
    
49. x=1; position='C'; text='Economical and'; output;
    
50. position='F'; text='Sporty'; output;
    
51. 
    
52. x=50; position='B'; output; /* The value of TEXT remains 'Sporty'. */
    
53. 
    
54. x=99; position='A'; text='Expensive and'; output;
    
55. position='D'; text='Sporty'; output;
    
56. 
    
57. y=50; /* Vertical position for the two vertical reference line labels. */
    
58. x=1; position='F'; text='Economical'; output;
    
59. x=99; position='D'; text='Expensive'; output;
    
60. 
    
61. y=5; /* Vertical position for labels across the bottom of the plot. */
    
62. x=1; position='C';text='Economical and'; output;
    
63. position='F'; text='Practical'; output;
    
64. 
    
65. 
    
66. x=50; position='E'; output; /* The value of TEXT remains 'Practical'. */
    
67. 
    
68. x=99; position='A'; text='Expensive and'; output;
    
69. position='D'; text='Practical'; output;
    
70. end;
    
71. 
    
72. /* Values from AUTODATA provide the text and position of the bubble labels. */
    
73. /* Since the values of plot variables position the bubble labels, the */
    
74. /* coordinate system is absolute data values (2). */
    
75. 
    
76. set autodata;
    
77. drop share rating price auto;
    
78. text=auto; x=price; y=rating; xsys='2'; ysys='2'; position='5';
    
79. style='swiss'; size=2.5; color='red'; output;
    
80. run;
    
81. 
    
82. /* Add the title and footnotes. */
    
83. 
    
84. title1 height=5
    
85. 'Market Analysis of Selected Automobiles';
    
86. footnote1 justify=left ' SAS/GRAPH' move=(+0,+.5) '02'x move=(+0,-.5)
    
87. ' Software' justify=right 'MARKET ';
    
88. 
    
89. /* Create axis definitions */
    
90. 
    
91. /* ORIGIN= aligns the plot with the title by specifying the same */
    
92. /* distance from the left edge as the MOVE= in TITLE1. */
    
93. 
    
94. axis1 order=(5 to 27) origin=(3,10) length=65 label=none value=none
    
95. major=none minor=none;
    
96. 
    
97. /* OFFSET= offsets the ends of the vertical axis to prevent a collision */
    
98. /* between the bubble and the axis frame. Other options suppress lables */
    
99. /* and tick marks. */
    
100. 
     
101. axis2 order=(0 to 10) offset=(2,2) length=80 value=none label=none
     
102. major=none minor=none ;
     
103. 
     
104. 
     
105. /* Produce the bubble plot. Reference line options in the BUBBLE */
     
106. /* statement draw and color the dashed lines that divide the quadrants. */
     
107. /* BCOLOR= selects the color of the bubbles. CTEXT= affects the color */
     
108. /* of the bubble value displayed by BLABEL. The BUBBLE statment includes */
     
109. /* the annotation defined in the LABELS data set. NOTE statements */
     
110. /* explicitly place text to the right of the plot. */
     
111. 
     
112. proc gplot data=autodata;
     
113. format share percent7.1;
     
114. note height=2 move=(70,25) 'Bubble size and labels'
     
115. move=(70,20) 'represent the market share,'
     
116. move=(70,15) 'in percent, of autos'
     
117. move=(70,10) 'in this survey.';
     
118. bubble rating*price=share / bsize=12 bcolor=red blabel ctext=red
     
119. href=16 chref=blue lhref=2 haxis=axis1
     
120. vref=5 cvref=blue lvref=2 vaxis=axis2
     
121. cframe=white annotate=labels;
     
122. run;
     
123. quit;

复制代码

2# horace_chen
谢谢了。

感激horace_chen

好复杂啊 看不懂

受用了
有没有比较小篇幅的专门介绍sas画图的书可推荐的？

2# horace_chen

请教在SAS 官网的哪个部分可以看到sas code 的例子呢？

proc gsplot 用refline啊，很简单的说。

网上免费资源可以看一看的。http://saslist.net/archives/124

sxlion 发表于 2011-4-27 17:49
网上免费资源可以看一看的。http://saslist.net/archives/124

好人！！！