proc report中关于compute的问题

求解释，为啥这段代码下，weight列并没有被染上色

proc report data = sashelp.class;
        column height weight;
        define height / display;
        define weight / display;
        compute height;
        if height > 60 then do;
                call define("weight","style","style = [color = red background = green]");
        end;
        endcomp;
run;


是因为选择列的时候，只能选择当前列或者更前面的列吗

你把compute height 改成compute weight，是可行的，你选取height列却变化weight不对

Jia1Zhao 发表于 2020-3-11 17:02
你把compute height 改成compute weight，是可行的，你选取height列却变化weight不对

选取height列，可以对当前及前面的列进行变化的，后面的列为什么不能变化，附上code

proc report data = sashelp.class;
        column name height weight;
        define name / display;
        define height / display;
        define weight / display;
        compute height;
        if height > 60 then do;
                call define("name","style","style=[background=yellow]");/*这里name可以被染黄，但是换成weight就不行了*/
        end;
        endcomp;
run;

美人百货 发表于 2020-3-12 08:53
选取height列，可以对当前及前面的列进行变化的，后面的列为什么不能变化，附上code

proc report data ...

真的无解好像，只能对compute指定列及之前的

美人百货 发表于 2020-3-12 08:53
选取height列，可以对当前及前面的列进行变化的，后面的列为什么不能变化，附上code

proc report data ...

真的无解好像，只能对compute指定列及之前的

Jia1Zhao 发表于 2020-3-12 09:56
真的无解好像，只能对compute指定列及之前的

只能这样解释了，感觉好奇怪

确实如此，不过顺着这个思路想下去，应可以给出如下代码：

1.         compute weight;
   
2.         if height > 60 then do;
   
3.                 call define("weight","style","style=[background=yellow]");/*这里name可以被染黄，但是换成weight就不行了*/
   
4.         end;
   
5.         endcomp;

复制代码

• report item 的作用是与一个compute block联系起来：可以是 dataset variable, a computed variable, or a statistic
• report item 在column statement中的位置十分重要：PROC REPORT是从左到右为报告行中的列分配值.
  

所以在你的code中，compute height时，因为weight在height的右边，其值全为missing
有两种解决方案：

1. /*1. compute item 用column statement中的最后一个变量：weight*/
   
2. 
   
3. proc report data = sashelp.class;
   
4.         column height weight;
   
5.         define height / display;
   
6.         define weight / display;
   
7.         compute weight;
   
8.         if height > 60 then do;
   
9.                 call define("weight","style","style = [color = red background = green]");
   
10.         end;
    
11.         endcomp;
    
12. run;
    
13. 
    
14. 
    
15. 
    
16. /*第二种，生成一个dummy report item 放在column statement的最后面，然后不print这个变量。
    
17. 
    
18.   这种情况若调整report中要展示的变量时，如删除本来放在最后的变量weight，这时候不需要修改 compute report item：_lastvar*/
    
19. 
    
20. proc report data = sashelp.class;
    
21.         column height weight _lastvar;
    
22.         define height / display;
    
23.         define weight / display;
    
24.                 define _lastvar/noprint;
    
25.         compute _lastvar;
    
26.         if height > 60 then do;
    
27.                 call define("weight","style","style = [color = red background = green]");
    
28.         end;
    
29.         endcomp;
    
30. run;

复制代码