请求sas中输出的问题

在sas中生成了table s1和s2,各有2列，我想新生成一个table：my_data，把s1和s2的第二列粘贴过来放在my_data中，请问怎么编程实现。

比如：
s1    2010-3-1          334
          2010-3-2         786
          2010-3-3         378

s1    2010-3-1         124
          2010-3-2         346
          2010-3-3         675

要生成my_data：
334    124
786    346
378    675

data s1;
    input date $ col1;
    datalines;
2010-3-1          334
2010-3-2         786
2010-3-3         378
;
data s2;
   input date $ col2;
   datalines;
2010-3-1         124
2010-3-2         346
2010-3-3         675
;
data my_data;
    merge s1 s2;
by date;
keep col1 col2;
run;

我想请问一下，因为s1和s2是sas输出的table，第一列是日期，第二例分别是num for s1 和num for s2，我使用merge的时候，keep num for s1  num for s2发生了错误，我想是因为num for s1这个label名称之间有空格， 请问该怎么修改呢

一般SAS变量名只能包括字母，数字和下划线（以字母或下划线开头），不能有空格。
Keep num_for_s1 num_for_s2;

谢谢楼上的回答。s1和s2是forecast模块输出的，因此s1的第二列自动命名为num for s1，请问有什么方法处理吗？感谢您的回答

"num for s1" 应该是变量的label吧，keep语句需要用变量名。

或者用drop date；语句。

谢谢您的回答，确实是label。现在的麻烦是由sas输出的s1，s2.。。。。等table中第二列的name都是num，这样怎么才能合并呢？改name？谢谢您的回答。
btw：我怎么才能再赠送您论坛币呢

data s1;
input date $9. num@;
datalines;
2010-3-1         334
2010-3-2         786
2010-3-3         378
;
run;
data s2;
input date $9. num@;
datalines;
2010-3-1         124
2010-3-2         346
2010-3-3         675
;
run;
/*        ********用sort+merge************************************************************************
proc sort data=s1 out=s1(rename=(num=num1));
by date;
run;
proc sort data=s2 out=s2(rename=(num=num2));
by date;
run;
data result;
merge s1 s2;
by date;
drop date;
run;
*/
/*        *******SQL***********************************************************************************
proc sql;
create table resultsql as select s1.num as num1,s2.num as num2 from s1 join s2 on s1.date=s2.date;
quit;
*/
/*        APPEND+LAG*************************************************************************************
proc append base=s1 data=s2;
run;
data s1;
set s1;
num1=lag3(num);
if num1^=.;
drop date;
run;
*/

还有一个方法就是
data s1;
input date $9. num@;
datalines;
2010-3-1         334
2010-3-2         786
2010-3-3         378
;
run;
data s2;
input date $9. num@;
datalines;
2010-3-1         124
2010-3-2         346
2010-3-3         675
;
run;
data _null_;
set s2;
call symput("num"||left(_n_),num);
run;
data s1;
set s1;
num2=symget("num"||left(_n_));
drop date;
run;

非常感谢版主啊，解决了