表的合并（填补缺失值）。

code	date	a	b
1	1
1	2	0.1	0.2
1	3	0.1	0.2
1	4	0.1	0.2
1	5	0.1	0.2
1	6	0.1	0.2
1	7	0.1	0.2
1	8	0.1	0.2
1	9	0.1	0.2
1	10	0.1	0.2
1	11	0.1	0.2
2	3
2	4	0.1	0.2
2	5	0.1	0.2
2	6	0.1	0.2
2	7	0.1	0.2
2	8	0.1	0.2
2	9	0.1	0.2
2	10	0.1	0.2
2	11	0.1	0.2
2	12	0.1	0.2
2	13	0.1	0.2

code	a	b
1	222	333
2	444	555

根据上面的表格生成下面的表格。第一个表格中有的数据是缺失的，将表2的数据填补到相应的位置。

鉴于表格1的数据量太大，程序请避免使用sql和proc sort。表格1实际上date是排列好的了。每一个code的第一行数据a和b是缺失值。

code	date	a	b
1	1	222	333
1	2	0.1	0.2
1	3	0.1	0.2
1	4	0.1	0.2
1	5	0.1	0.2
1	6	0.1	0.2
1	7	0.1	0.2
1	8	0.1	0.2
1	9	0.1	0.2
1	10	0.1	0.2
1	11	0.1	0.2
2	3	444	555
2	4	0.1	0.2
2	5	0.1	0.2
2	6	0.1	0.2
2	7	0.1	0.2
2	8	0.1	0.2
2	9	0.1	0.2
2	10	0.1	0.2
2	11	0.1	0.2
2	12	0.1	0.2
2	13	0.1	0.2

1. data one;
   
2.     infile datalines truncover;
   
3.     input code date a b;
   
4. datalines;
   
5. 1 1
   
6. 1 2 0.1 0.2
   
7. 1 3 0.1 0.2
   
8. 1 4 0.1 0.2
   
9. 1 5 0.1 0.2
   
10. 2 3
    
11. 2 4 0.1 0.2
    
12. 2 5 0.1 0.2
    
13. 2 6 0.1 0.2
    
14. 2 7 0.1 0.2
    
15. 3 10
    
16. 3 11 0.1 0.2
    
17. 3 12 0.1 0.2
    
18. 3 13 0.1 0.2
    
19. ;
    
20. data two;
    
21.     input code a b;
    
22. datalines;
    
23. 1 222 333
    
24. 2 444 555
    
25. ;
    
26. data out;
    
27.     length date code a b 8.;
    
28.     if _n_=1 then do;
    
29.         declare hash h(hashexp:16,dataset:'two',ordered:'yes');
    
30.         h.definekey('code');
    
31.         h.definedata('a','b');
    
32.         h.definedone();
    
33.         call missing(code,a,b);
    
34.     end;
    
35.     set one;
    
36.     by code;
    
37.     if first.code then do;
    
38.         rc=h.find();
    
39.         if rc then call missing(a,b);
    
40.     end;
    
41.     drop rc;
    
42. run;

复制代码

hash看不懂，但是谢谢您的回复。
运行的时候遇到一个问题，我的code是字符型的，该如何修改程序呢？

1. data one;
   
2.     infile datalines truncover;
   
3.     input code $ date a b;
   
4. datalines;
   
5. a1 1
   
6. a1 2 0.1 0.2
   
7. a1 3 0.1 0.2
   
8. a1 4 0.1 0.2
   
9. a1 5 0.1 0.2
   
10. a2 3
    
11. a2 4 0.1 0.2
    
12. a2 5 0.1 0.2
    
13. a2 6 0.1 0.2
    
14. a2 7 0.1 0.2
    
15. a3 10
    
16. a3 11 0.1 0.2
    
17. a3 12 0.1 0.2
    
18. a3 13 0.1 0.2
    
19. ;
    
20. data two;
    
21.     input code $ a b;
    
22. datalines;
    
23. a1 222 333
    
24. a2 444 555
    
25. ;
    
26. data out;
    
27.     length date 8 code $8 a b 8.;
    
28.     if _n_=1 then do;
    
29.         declare hash h(hashexp:16,dataset:'two',ordered:'yes');
    
30.         h.definekey('code');
    
31.         h.definedata('a','b');
    
32.         h.definedone();
    
33.         call missing(code,a,b);
    
34.     end;
    
35.     set one;
    
36.     by code;
    
37.     if first.code then do;
    
38.         rc=h.find();
    
39.         if rc then call missing(a,b);
    
40.     end;
    
41.     drop rc;
    
42. run;

复制代码

length date 8 code $8 a b 8.;

规定一样的长度 是不是必须的呀？

不是必须的.

4# hopewell
前辈
if rc then call missing(a,b);  这句话有什么用，不解啊。已经匹配了 干嘛还要令a b缺失，而且删掉结果也没变，小弟hash不熟，还望指教。

7# sopching
匹配的话rc为0
故不匹配if才成立

8# soporaeternus
哦 明白了 我以为rc 取1是匹配成功呢。

sopching 发表于 2010-10-12 14:08
8# soporaeternus
哦 明白了 我以为rc 取1是匹配成功呢。

1. data one;
   
2. modify one two;
   
3. by code;
   
4. run;

复制代码