where and if statement区别

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

有谁能具体说说 WHERE 和 IF STATEMENT 的区别吗?
举个例子, 请教!! 谢谢!!

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏2 回帖

关键词：statement Statemen Statem Where State statement Where

一些例子，希望对你有点用处：

*** The general rule when comparing IF statement and WHERE statement is that when reading data from datasets, SAS first select observations based on the WHERE condition and then take other actions, while the IF statement would have to wait their turn. Using the WHERE statement may improve the efficiency of your SAS programs because SAS is not required to read all observations from the input data set.;

data test1;
     set sashelp.class;
     if sex="M";
run;

/*
log:
NOTE: There were 19 observations read from the data set SASHELP.CLASS.
NOTE: The data set WORK.TEST1 has 10 observations and 5 variables.
*/

data test2;
    set sashelp.class;
    where sex="M";
run;

/*log:
NOTE: There were 10 observations read from the data set SASHELP.CLASS.
      WHERE sex='M';
NOTE: The data set WORK.TEST2 has 10 observations and 5 variables.
*/

*** When using two or more WHERE statements in the same DATA step, then which comes last rules.
     When using two or more IF statements, both(all) of them take effect;

*** Both of the two IF statements are applied to the data, TEST3 contains only female students whose age is less than 14;
data test3;
     set sashelp.class;
     if sex="F";
     if age<14;
run;

*** Only the latter WHERE statement takes effect and dataset test4 contains all students with age lt 14, irrespective of their gender.;
data test4;
    set sashelp.class;
    where sex="F";
    where age<14;
run;

*** Check out the following example;

data class;
     set sashelp.class;
run;

*** Using FIRSTOBS= and OBS= data set option;
*** SAS selects 9 records (from the second through the tenth);
data class1;
     set sashelp.class(firstobs=2 obs=10);
run;

*** Using WHERE statement;
*** SAS first select all female records, then try to set the 2-10 observations.;
data class2;
     set sashelp.class(firstobs=2 obs=10);
     where sex="F";
run;

*** Using IF statement;
*** SAS first select the 2-10 records, then select Female students;
data class3;
     set sashelp.class(firstobs=2 obs=10);
     if sex="F";
run;


*** Another example about IF condition and WHERE condition;
data temp;
     do x=1 to 10;
        output;
     end;
run;

*** Where condition;
data temp1;
    set temp;
    where '0';
run;

*** IF condition;
data temp2;
    set temp;
    if '0';
run;

*** The WHERE statement evaluated the '0' as true and selected all observations, while the IF statement evaluated '0' as false and select no observations.

The WHERE processor converted the character value directly to a logical value, the rule being that all-blank strings are false and any other strings are true. The IF statement triggered a more general sort of conversion in the DATA step, first converting the character string to a 0 (zero) numeric value, then interpreting that as false (the rule being that zeroes and missing values are false, while positive and negative values are true). ;

*** Small tip:
If you use both the WHERE= data set option and the WHERE statement in the same DATA step, SAS ignores the WHERE statement for data sets with the WHERE= data set option. ;

Here is something may help:
http://www2.sas.com/proceedings/sugi31/238-31.pdf

The variable used in the WHERE statement should exist in the input datasets. No such restrictions are for subsetting IF statement.

jiayuan67 发表于 2010-10-25 13:56


The variable used in the WHERE statement should exist in the input datasets. No such restrictions are for subsetting IF statement.

这个图很好啊。存起来备用。

thank you!!!

2# pobel
Good points!

绝对的好贴

受启发了，不懂再来看看

en ..。。不错，算是很清楚了