Dueker JBES 1997 MS-GARCH models using Winrats

0关注
1粉丝

已卖：347份资源

博士生

73%

还不是VIP/贵宾

-

TA的文库 其他...

Research Paper Writing(写作)

OxMetrics NewOccidental

Eviews NewOccidental

0%

威望: 0 级
论坛币: 2817 个
通用积分: 6.1195
学术水平: 48 点
热心指数: 19 点
信用等级: 46 点
经验: 4060 点
帖子: 115
精华: 4
在线时间: 7 小时
注册时间: 2014-6-21
最后登录: 2016-8-20

楼主

东西方咨询 发表于 2014-6-23 23:57:57 |AI写论文

是否 +2 论坛币

k人参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

Dueker JBES 1997 MS-GARCH models

by TomDoan » Mon Sep 12, 2011 1:30 pm

These are replication files for Dueker(1997), "Markov Switching in GARCH Processes and Mean-Reverting Stock-Market Volatility," J of Business & Economic Statistics, vol. 15, no 1, 26-34 using a reconstruction of the original data file. Dueker fits several different models with different types of switching. All of models allow the mean to switch, but two of these have "variances" switching, and two have the degrees of freedom in the conditional t density switching in different ways.

Switching GARCH (as opposed to ARCH) models require "collapsing" the history of the regimes in some fashion. Dueker waits one period longer for this than Gray(1996) does. This actually makes it easier to adapt the technique to different models than Gray's.

Switching ARCH/GARCH models is one of the topics in the Structural Breaks and Switching Models course materials.

dueker_swgarch.rpfGARCH model with switching mean (only)(4.66 KiB) Downloaded 363 times

dueker_swgarch_nf.rpfGARCH model with switching variance(5.53 KiB) Downloaded 374 times

dueker_swgarch_df.rpfGARCH model with switching degrees of freedom in t error process(5.26 KiB) Downloaded 279 times

dueker_swgarch_k.rpfGARCH model with switching degrees of freedom(5.29 KiB) Downloaded 278 times

dueker_swarch.rpfSWARCH model(4.65 KiB) Downloaded 317 times

sp500.xls(Reconstructed) data file(93 KiB) Downloaded 333 times

扫码加我拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏0 回帖

关键词：GARCH Models WinRATS models winrat model different Business original several files

本帖被以下文库推荐

· Winrats NewOccidental|主题: 74, 订阅: 8

沙发

songlinjl 发表于 2014-6-24 05:51:04 来自手机

东西方咨询发表于 2014-6-23 23:57
Dueker JBES 1997 MS-GARCH modelsby TomDoan &#187; Mon Sep 12, 2011 1:30 pmThese are re ...

手机版上链接无效

藤椅

gssdzc

发表于 2014-7-27 09:10:58

貌似无法打开链接

板凳

农村固定观察点 发表于 2017-2-12 23:22:37

*
* Replication file for Dueker(1997), "Markov Switching in GARCH
* Processes and Mean-Reverting Stock-Market Volatility," J of Business &
* Economic Statistics, vol. 15, no 1, 26-34.
*
* Data set is a reconstruction.
*
* SWARCH(2) model with switching normalization factors and means with
* conditionally t distributed errors.
*
open data sp500.xls
data(format=xls,org=columns,top=17,left=2,nolabels) 1 2529 spchange
*
* Copy the data over to y to make it easier to change the program.
*
set y = spchange
*
* This is the number of ARCH lags.
*
compute q=2
*
@MSSetup(states=2,lags=q)
*
* GV will be the relative variances in the regimes.
*
dec vect gv(nstates)
*
* This will be the vector of ARCH parameters. The constant in the ARCH
* equation is fixed at 1 as the normalization.
*
dec vect msg(q)
dec real nu
*
* We have three parts of the parameter set: the mean equation parameters
* (separate mu's for each regime), the GARCH model parameters, and the
* Markov switching parameters.
*
dec vector mu(nstates)
nonlin(parmset=meanparms) mu
nonlin(parmset=archparms) msg gv nu
nonlin(parmset=msparms) p
*
* uu and u are used for the series of squared residuals and the series of
* residuals needed to compute the ARCH variances.
*
clear uu u
*
* These for the lagged residuals and lagged squared residuals, which are
* regime-dependent because of the regime-dependent means.
*
dec vect[series] uus(nstates) us(nstates)
************************************************************************
*
* ARCHRegimeH returns the VECTOR of the H values across augmented regime
* settings.
*
function ARCHRegimeH time
type vector ARCHRegimeH
type integer time
*
local integer i k
*
dim ARCHRegimeH(nexpand)
do i=1,nexpand
compute h=1.0
do k=1,q
compute h=h+msg(k)*uus(%MSLagState(i,k))(time-k)/gv(%MSLagState(i,k))
end do k
compute ARCHRegimeH(i)=h
end do i
end
************************************************************************
*
* ARCHRegimeVGaussF returns a vector of likelihoods for the expanded
* regimes at <<time>> given regime "h" factors <<hv> and regime residuals
* <<ev>> using conditionally Gaussian errors.
*
function ARCHRegimeVGaussF time hv ev
type vector ARCHRegimeVGaussF
type integer time
type vector hv ev
*
local integer i k
local real h
*
dim ARCHRegimeVGaussF(nexpand)
do i=1,nexpand
compute k=%MSLagState(i,0)
compute ARCHRegimeVGaussF(i)=%if(hv(i)>0,exp(%logdensity(hv(i)*gv(k),ev(k))),0.0)
end do i
end
************************************************************************
*
* ARCHRegimeVTF returns a vector of likelihoods for the expanded
* regimes at <<time>> given regime "h" factors <<hv> and regime residuals
* <<ev>> using conditionally student-t errors.
*
function ARCHRegimeVTF time hv ev
type vector ARCHRegimeVTF
type integer time
type vector hv ev
*
local integer i k
local real h
*
dim ARCHRegimeVTF(nexpand)
do i=1,nexpand
compute k=%MSLagState(i,0)
compute ARCHRegimeVTF(i)=%if(hv(i)>0,exp(%logtdensity(hv(i)*gv(k),ev(k),nu)),0.0)
end do i
end
*********************************************************************
function ARCHRegimeResids time
type vector ARCHRegimeResids
type integer time
*
* Compute the residuals for each current regime
*
local integer i
*
dim ARCHRegimeResids(nstates)
do i=1,nstates
compute ARCHRegimeResids(i)=y(time)-mu(i)
end do i
end
*********************************************************************
linreg y
# constant y{1}
set uu = %seesq
set u = %resids
do i=1,nstates
set uus(i) = %sigmasq
set us(i) = %resids
end do i
*
* Run a GARCH model for guess values. Use the same range that will be
* used for the MS process.
*
garch(q=2,distrib=t) 3 * y
compute gstart=%regstart(),gend=%regend()
*
ewise mu(i)=%beta(1)
compute msg=%xsubvec(%beta,3,4),nu=%beta(5)
*
* Start with guess values for GV that scale the original constant down
* and up.
*
compute gv(1)=%beta(2)/2.0
compute gv(2)=%beta(2)*2.0
*
* These are our guess values for the P matrix.
*
compute p=||.80,.20||
*
gset pt_t gstart gend = %zeros(nexpand,1)
gset pt_t1 gstart gend = %zeros(nexpand,1)
*
frml logl = hvec=ARCHRegimeH(t),evec=ARCHRegimeResids(t),f=ARCHRegimeVTF(t,hvec,evec),$
%pt(us,t,evec),%pt(uus,t,evec.^2),fpt=%MSProb(t,f),log(fpt)
*
maximize(parmset=meanparms+archparms+msparms,$
start=%(pstar=%MSInit()),$
method=bfgs,iters=400,pmethod=simplex,piters=5) logl gstart gend
*
@MSSmoothed gstart gend psmooth
set p1 = psmooth(t)(1)
set p2 = psmooth(t)(2)
graph(max=1.0,footer="Probabilities of Regimes in Two Lag Two-Regime student t SWARCH",$
style=stacked) 2
# p1
# p2

复制代码

报纸

ReneeBK 发表于 2017-2-12 23:26:03

*
* Replication file for Dueker(1997), "Markov Switching in GARCH
* Processes and Mean-Reverting Stock-Market Volatility," J of Business &
* Economic Statistics, vol. 15, no 1, 26-34.
*
* GARCH model with switching intercepts only.
*
open data sp500.xls
data(format=xls,org=columns,top=17,left=2,nolabels) 1 2529 spchange
*
* Copy the data over to y to make it easier to change the program.
*
set y = spchange
*
* This sets the number of regimes. The analysis requires one lagged
* regime.
*
@MSSetup(states=2,lags=1)
*
* GV will be the relative variances in the regimes.
*
dec vect gv(nstates)
*
* This will be the vector of GARCH parameters. The constant in the GARCH
* equation is fixed at 1 as the normalization.
*
dec vect msg(2)
dec real nu
*
* We have three parts of the parameter set: the mean equation parameters
* (separate mu's for each regime), the GARCH model parameters, and the
* Markov switching parameters.
*
dec vect mu(nstates)
nonlin(parmset=meanparms) mu
nonlin(parmset=garchparms) msg gv nu
nonlin(parmset=msparms) p
*
* uu and u are used for the series of squared residuals and the series of
* residuals needed to compute the GARCH variances.
*
clear uu u h
*
* These are used for the lagged variance for each regime.
*
compute DFFilterSize=nstates^nlags
dec vect[series] hs(DFFilterSize)
*
* And these for the lagged squared residuals
*
dec vect[series] uus(nstates)
************************************************************************
*
* GARCHRegimeH returns the VECTOR of the H values across augmented
* regime settings.
*
function GARCHRegimeH time
type vector GARCHRegimeH
type integer time
*
local integer i
*
dim GARCHRegimeH(nexpand)
do i=1,nexpand
compute GARCHRegimeH(i)=1.0+msg(2)*hs(%MSLagState(i,1))(time-1)+$
msg(1)*uus(%MSLagState(i,1))(time-1)/gv(%MSLagState(i,1))
end do i
end
**************************************************************************
*
* Do a GARCH model to get initial guess values and matrices for random
* walk M-H.
*
linreg y
# constant y{1}
set u = %resids
set uu = %sigmasq
do i=1,nstates
set uus(i) = %sigmasq
end do i
*
* We'll start this at entry 2 to match the MS model
*
garch(p=1,q=1,distrib=t) 2 * y
compute gstart=%regstart(),gend=%regend()
*
* Spread the mu's apart since they're the only thing switching in this
* model.
*
compute mu(1)=%beta(1)-%stderrs(1)
compute mu(2)=%beta(1)+%stderrs(1)
*
compute msg=%xsubvec(%beta,3,4)
compute nu=%beta(5)
*
* The "H" series used in the Hamilton-Susmel formulation need scaling by
* the normalization factor to become variances. So we scale the
* pre-sample values down to match.
*
set h = %sigmasq/%beta(2)
do i=1,nstates
set hs(i) = %sigmasq/%beta(2)
end do i
*
* These are the same (and will be pegged to stay that way).
*
compute gv(1)=%beta(3)
compute gv(2)=%beta(3)
*
compute p=||.9,.1||
**************************************************************************
*
* This does a single step of the Dueker (approximate) filter
*
function DuekerFilter time
type integer time
*
local real e
local vector fvec evec hvec ph
*
dim fvec(nexpand) evec(nstates)
*
* Compute the "H" matrices for each expanded regime
*
compute hvec=GARCHRegimeH(time)
*
* Compute the residuals for each current regime
*
do i=1,nstates
compute evec(i)=y(time)-mu(i)
end do i
*
* Compute the likelihood for each expanded regime.
*
do i=1,nexpand
compute e=evec(%MSLagState(i,0))
compute fvec(i)=%if(hvec(i)>0,exp(%logtdensity(hvec(i)*gv(%MSLagState(i,0)),e,nu)),0.0)
end do i
*
* Do a filter step to update the probabilities. The log likelihood
* element is returned in the LOGF option.
*
@MSFilterStep(logf=DuekerFilter) time fvec
*
* Take probability weighted averages of the h's for each regime.
*
compute ph=pt_t(time).*hvec
compute pdiv =%sumc(%reshape(pt_t(time),nstates,DFFilterSize))
compute phstar=%sumc(%reshape(ph,nstates,DFFilterSize))./pdiv
*
* Push them out into the HS vector
*
compute %pt(hs,t,phstar)
compute %pt(uus,t,evec.^2)
end
**************************************************************************
function DFStart
@MSFilterInit
end
**************************************************************************
frml LogDFFilter = DuekerFilter(t)
*
@MSFilterSetup(noem)
nonlin(parmset=fixgv) gv(2)=gv(1)
*
maximize(start=DFStart(),parmset=meanparms+garchparms+msparms+fixgv,$
pmethod=simplex,piters=5,method=bfgs) logDFFilter gstart gend
@MSSmoothed gstart gend psmooth
set p1 = psmooth(t)(1)
set p2 = psmooth(t)(2)
graph(max=1.0,footer="Probabilities of Regimes in Two Regime Gaussian model",$
style=stacked) 2
# p1
# p2

复制代码

[程序分享] Dueker JBES 1997 MS-GARCH models using Winrats [推广有奖]

经管之家送您一份

经管之家联合CDA

感谢您参与论坛问题回答

扫码加我拉你入群

相关帖子

本帖被以下文库推荐

浏览过的帖子

浏览过的版块

初级学术勋章

初级热心勋章

中级热心勋章

初级信用勋章

中级学术勋章

本版微信群

[程序分享] Dueker JBES 1997 MS-GARCH models using Winrats [推广有奖]

经管之家送您一份

经管之家联合CDA

感谢您参与论坛问题回答

扫码加我 拉你入群

相关帖子

本帖被以下文库推荐

浏览过的帖子

浏览过的版块

初级学术勋章

初级热心勋章

中级热心勋章

初级信用勋章

中级学术勋章

本版微信群

扫码加我拉你入群