批量修改变量名

有一数据库，变量名没有规律，现想把所有变量（除ID）后面加“_1”，就是由d a b c d e f g h变成id a_1 b_1 c_1 d_1 e_1 f_1 g_1 h_1，程序怎样实现？

data a;
input id a b c d e f g h@@;
datalines;
1 2 3 4 5 6 7 8 9 0
1 3 5 5 6 8 0 5 2 3
;
run;

1. data a;
   
2. input id a b c d e f g h ;
   
3. datalines;
   
4. 1 2 3 4 5 6 7 8 9 0
   
5. 1 3 5 5 6 8 0 5 2 3
   
6. ;
   
7. run;
   
8. 
   
9. proc sql;
   
10. create table b as select * from dictionary.columns
    
11. where libname="WORK" and memname="A";
    
12. quit;  /*提取数据集所有变量生成b*/
    
13. 
    
14. proc sql;
    
15. select count(*) into:n from b;
    
16. quit; /*计算变量个数，赋值给宏变量n*/
    
17. 
    
18. proc sql;
    
19. select name into: var1-:var%left(&n) from b;
    
20. quit; /*将全部变量赋给n个宏变量*/
    
21. 
    
22. %macro rename;
    
23. data a;
    
24. set a;
    
25. %do i=1 %to &n;
    
26. rename &&var&i=&&var&i.._1;
    
27. %end;
    
28. run;
    
29. %mend; /*宏循环*/
    
30. %rename

复制代码

谢谢，楼上可以解决。

http://blog.sina.com.cn/s/blog_41889b90010153bh.html

webgu 发表于 2012-10-16 08:01
http://blog.sina.com.cn/s/blog_41889b90010153bh.html

我对宏比较难理解，就这例子，下面程序怎样修改实现？

************************;
***macro definition;
************************;
%macro renamevar(dslib,dsname,prefix,suffix,fromnum,tonum) ;
ods   listing close;
ods trace on;
ods output variables=varlist  ;
proc contents data=&dslib..&dsname;
run;
ods trace off;
ods listing;

proc sql;
  select  cats(variable,"=","&prefix._",variable,"_&suffix")
            into :renamelist  separated by " "
from  varlist
where num between &fromnum and &tonum;
quit;

*********************************************************************;
*** thanks for  Malcolm's suggestion; proc datasets is more efficient.
***********************************************************************;
proc datasets lib=&dslib ;
  modify  &dsname;
  rename &renamelist;
run;
%mend renamevar;

******************;
*** do it;
*****************;

%renamevar(sashelp,class,pre,suf,3,5);

************************;
***macro definition;
************************;
%macro renamevar(dslib,dsname,prefix,suffix,fromnum,tonum) ;
ods   listing close;
ods trace on;
ods output variables=varlist  ;
proc contents data=&dslib..&dsname;
run;
ods trace off;
ods listing;

proc sql;
   select  cats(variable,"=","&prefix.",variable,"&suffix")
             into :renamelist  separated by " "
from  varlist
where num between &fromnum and &tonum;
quit;

proc datasets lib=&dslib ;
   modify  &dsname;
   rename &renamelist;
run;
quit;
%mend renamevar;

******************;
*** do it;
*****************;
***%rename(库名，dataset,前缀，后缀，startvar,endvar)
%renamevar(work,a,,_1,2,8);

谢谢以上2位，更灵活。

Rock2000 发表于 2012-10-16 18:40
谢谢以上2位，更灵活。

客气啦，共同学习。

跟着学习。

Imasasor 发表于 2012-10-15 17:57

深入浅出 简单有效