word中的规则数据表格可否导入sas?

有大概一万个人的临床检验报告单，是word中的表格形式，如图所示，有几十个word文件，每个word中有这样的表格几百个，
每个表格上面的编号即id号为观测，几个检测指标为变量。
请问高手，像这样形式的数据，能否通过某种方法批量导入sas生成数据集!跪求帮助，如果要一个一个再输到excel中，太麻烦了。

Imasasor 发表于 2012-11-9 23:18
上述问题解决了，我用你的方法让它延迟了一会儿。
解决后，又出现错误，提示import时找不到example.xl ...

/*在下面的代码中增加了WINWORD退出机制*/
/*使用前建议重启一下PC*/
options noxwait noxsync;
%macro word2sas(in=, out=);
/*%let in=&fname;*/
/*%let out=example1;*/
%let rc=%sysfunc(system(start winword));
data  _null_;
   null= sleep(5);
run;
filename word DDE 'Winword|System';
data _null_;
file word;
put '[FileOpen.Name = "' "&in" '"]';
put "[EditSelectAll]";
put "[EditCopy]";
put '[FileClose]';
put '[AppMinimize]';
run;
%let rc=%sysfunc(system(start excel));
data  _null_;
   null= sleep(5);
run;
filename excel dde 'excel|system';
data _null_;
file excel;
put '[error(false)]';
put '[paste]';
put '[SAVE.AS("Example.xls")]';
put '[Select.Last.Cell()]';
put '[Copy]';
put '[quit]';
run;
%let rc=%sysfunc(system(taskkill/im winword.exe));
proc import datafile= "Example.xls" out=&out dbms=xls replace;
getnames=no;
mixed=yes;
run;
filename fd "Example.xls";
%let rc=%sysfunc(fdelete(fd));
filename _all_ clear;
%mend word2sas;
/*%word2sas(in=data1.doc, out=example1);*/

%let dirname = D:\Docs;
x "cd &dirname";
filename dirlist pipe "dir /B &dirname\*.doc";
data dirlist ;
     length fname $256;
     infile dirlist length=reclen ;
     input fname $varying256. reclen ;
run;
data _null_;
set dirlist end=last;
if last then call symput('nobs',_n_);
run;
%macro CAL;
%let number=1;
%do %while(&number le &nobs);
  data _null_;
  set dirlist(firstobs=&number obs=&number);
  call symput("fname",trim(fname));
  run;
  %word2sas(in=&fname, out=example1);
  proc datasets library=work nolist;
  append base=all_data data=example1;
  delete example1;
  quit;
%let number=%eval(&number+1);
%end;
%mend ;
%CAL;

你这个很简单
思路是先转成excel，然后倒入sas
按照这个思路，你自己试试

你这个如果有大批量的要做的话，终极解决办法是开发edc

luijb 发表于 2012-11-9 10:38
你这个很简单
思路是先转成excel，然后倒入sas
按照这个思路，你自己试试

如何把word转成excel?

x "cd d:\docs";
%macro word2sas(in=, out=);
/*%let in=data1.doc;*/
/*%let out=example1;*/
options noxwait noxsync;
%let rc=%sysfunc(system(start winword));
filename word DDE 'Winword|System';
data _null_;
file word;
put '[FileOpen.Name = "' "&in" '"]';
put "[EditSelectAll]";
put "[EditCopy]";
put '[FileClose]';
put '[AppMinimize]';
run;
%let rc=%sysfunc(system(start excel));
filename excel dde 'excel|system';
data _null_;
file excel;
put '[error(false)]';
put '[paste]';
put '[SAVE.AS("Example.xls")]';
put '[Select.Last.Cell()]';
put '[Copy]';
put '[quit]';
run;
proc import datafile= "Example.xls" out=&out dbms=xls replace;
getnames=no;
mixed=yes;
run;
filename fd "Example.xls";
%let rc=%sysfunc(fdelete(fd));
filename _all_ clear;
%mend word2sas;

%word2sas(in=data1.doc, out=example1);

data1.doc (24 KB)

2012-11-9 10:59:44 上传

好复杂啊，能不能简单些

不错，借鉴一下

WORD 另存为TXT可行不？

问题是，你这个word文档当中是只有表格，还是文表(其他图等)混排的，只有表格的话，按照davil2000的试一试啊！
先批量修改文件名(估计原来的文件名就是有规律的)，再加个文件名循环就差不多了