如何使多副图在一副图中显示？

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

想问一下可不可以在一幅图中同时显示4个图呢？不是sgpanel的命令，而是用sgscatter之类的作图之后想让它们在一副图中显示，谢谢~

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏1 回帖

关键词：Scatter Panel SCAT pane GPA 如何

data ex;
do x=1 to 4;
y=2*x;
output;
end;
run;

ods graphics on /reset=all;
ods html path="E:\" body="b.htm";
ods layout Start width=10in height=8in columns=2 rows=2
column_gutter=.5in row_gutter=.8in row_heights=(3.5in 3.5in);;
ods region row=1 column=1  ;
proc sgplot data=ex;
scatter x=x y=y;
run;
ods region row=1 column=2 ;
proc sgplot data=ex;
scatter x=x y=y;
run;
ods region row=2 column=1 ;
proc sgplot data=ex;
scatter x=x y=y;
run;
ods region row=2 column=2 ;
proc sgplot data=ex;
scatter x=x y=y;
run;
run;
ods layout end;
ods html close;
quit;

ziyenano 发表于 2012-12-7 21:29
data ex;
do x=1 to 4;
y=2*x;

谢谢~

另一种方法，例子：

/* Data preparation*/
data sasuser.class (drop=name );
length Gender $ 6;
set sashelp.class;
if sex="F" then Gender="Female";
else Gender="Male";
run;
proc sort data=sasuser.class out=sasuser.class;
by weight height;
run;
/* global setting*/
goptions reset=all hsize=2.75in vsize=2.06in;
ods html close;
ods listing;
axis1 label=none style=0 major=none value=none;
axis2 label=("Age");

axis3 label=("Height") order=50 to 75 by 5;
axis4 label=("Weight") order=50 to 150 by 25 minor=(n=1);
legend1 label=none value=("Male" "Female") Position=(right middle outside)
across=1;
legend2 label=none value=("Male" "Female");
symbol i=join;
/*draw chart or plot*/
proc gchart data=sasuser.class gout=sasuser.excat;
vbar age/discrete hminor=0 subgroup=gender
inside=freq raxis=axis1 maxis=axis2
noframe legend=legend1;
run;
hbar age/ discrete sumvar=height mean
meanlabel="Avg.Height" vminor=0
raxis=axis1 maxis=axis2;
run;
pie gender/ noheading legend=legend1 percent=inside;
run;
proc gplot data=sasuser.class gout=sasuser.excat;
plot height*weight=gender/ vminor=1 vaxis=axis3
haxis=axis4 legend=legend2;
run;
quit;
goptions reset=all hsize=5.5in vsize=4.12in;

/*put them together*/
proc greplay gout=sasuser.excat igout=sasuser.excat nofs
tc=sashelp.templt template=l2r2;
device win;
treplay 1:gchart 2:gchart1 3:gchart2 4:gplot;
quit;
ods listing close;
ods html;

webgu 发表于 2012-12-8 11:41
另一种方法，例子：

/* Data preparation*/

学习了！！谢谢^^

学习了。一直不善于用SAS做图，要努力了。

webgu 发表于 2012-12-8 11:41
另一种方法，例子：

/* Data preparation*/

今天看到一个更简单的做法：

ods graphics / imagename="regplot" imagefmt=png;
ods listing gpath="D:\***";
ods listing on;
proc template;
  define statgraph intro;
    begingraph;
      entrytitle "Simple 3x2 Lattice with Five Cells Populated";
       layout gridded / columns=3;
  
  /* stand-alone plot statements define cells 1-3 */
  boxplot x=sex y=age;
  boxplot x=sex y=height;
  boxplot x=sex y=weight;
  /* overlay blocks define cells 4-5 */
  layout overlay;
    scatterplot y=weight x=height;
    pbsplineplot y=weight x=height;
    entry halign=right "Spline" / valign=bottom;
  endlayout;
  layout overlay;
    scatterplot y=weight x=height;
    loessplot y=weight x=height;
    entry halign=right "Loess " / valign=bottom;
  endlayout;
        endlayout;
    endgraph;
  end;
run;
proc sgrender data=sashelp.class template=intro;
run;

ziyenano 发表于 2012-12-7 21:29
data ex;
do x=1 to 4;
y=2*x;

今天看到一个用proc template做得方法，在7楼~

ziyenano 发表于 2012-12-7 21:29
data ex;
do x=1 to 4;
y=2*x;

row_gutter后面的那个in好像总会报错……去掉就好了……

若水烟寒 发表于 2012-12-21 12:08
今天看到一个用proc template做得方法，在7楼~

感谢分享！