用SAS修改txt文本

想用SAS修改txt文档，就是删除txt文档中最后一句话
比如文档结构是这样的：
就想删除最后一行。S3300700 WITH S3304930;
用SAS应该怎么搞？或者有没有DOS命令可以用的？先谢过了~

data test;
  infile "e:\test.txt" end=last;
  input ;
  if not last then do;
       x=_infile_;
           output;
        end;
run;

data _null_;
   set test;
   file "e:\test.txt";
   put x;
run;

didn't work for me!

pobel 发表于 2013-1-7 21:21
data test;
  infile "e:\test.txt" end=last;
  input ;

可以用~灰常强大~但是如果最后行是空行的话，程序就只删除空行，我想连空行加最后有字符的一样全部删去，我就改了下程序
  data test;
  infile "C:\test.txt";
  input ;
       x=_infile_;
       if missing(x)=0 then    output;     
run;

data _null_;
   set test end= last;
if not last then  do;
file "C:\test.txt";
put x;
end;
run;
可以实现，不过略显繁琐，请问是不是有更简便的方法，比如直接在infile中添加某个选项什么的就能自动排除非空行的最后一行。
还有个问题，x=_infile_是不是等于就是把buffer中所有的东西赋值给x，不是很清楚_infile_的用法
谢谢

fallleafsean 发表于 2013-1-8 10:12
可以用~灰常强大~但是如果最后行是空行的话，程序就只删除空行，我想连空行加最后有字符的一样全部删去， ...

_infile_的值应该是input语句执行后当前那一行记录。

如果是input #1 var1  #2 var2 #3 var3；
那这句执行完后，_infile_的值应该是var3所在的那行记录。

非常感谢~！

pobel 发表于 2013-1-8 10:53
_infile_的值应该是input语句执行后当前那一行记录。

如果是input #1 var1  #2 var2 #3 var3；

想再问下~关于一段程序的，
%macro checknobs(dsn);
data _null_;
if nobs=0 then do;
file print notitles;
put "there are no observations in &dsn";
end;
set &dsn nobs=nobs;
run;
%mend checknobs;
----------------------------------------------------------------
%macro checknobs(dsn);
data _null_;
set &dsn nobs=nobs;
if nobs=0 then do;
file print notitles;
put "there are no observations in &dsn";
end;

run;
%mend checknobs;

者是数据集是否为空集的判断，同样的两段程序，仅仅把set语句的位置变换一下，下面那段就无法运行，请问这是怎么回事呢~

fallleafsean 发表于 2013-1-8 21:27
想再问下~关于一段程序的，
%macro checknobs(dsn);
data _null_;

这个问题涉及到数据步的“编译”和“执行”。

1. NOBS= 这个选项是SAS在数据步编译过程就能看到，并且得到所set的数据集有多少条记录。因此到了数据步的执行阶段，关于nobs的语句可以在set语句之前执行。所以上面那段程序是可以执行的。

2. 下面那段程序中，如果&dsn为空集，那么在执行set语句的时候发现&dsn中并没有数据可读，整个数据步的执行就到此结束了。
所以说SAS的运行是正常的。只不过是空集的时候，数据步在“if nobs=0”那一句之前就结束了；而在非空集的时候，“if nobs=0”的条件判断又是假的。因此FILE 和PUT那两句永远没有办法执行到。

pobel 发表于 2013-1-9 08:27
这个问题涉及到数据步的“编译”和“执行”。

1. NOBS= 这个选项是SAS在数据步编译过程就能看到，并且 ...

非常感谢~

不是无法运行，只是没得到你要的结果．是先后顺序问题．
如果先set，没有数据就不把这个obs输出了．
set在后面，是先运行了put，set后没数据，这个数据就不输出了