请教一个call execute和宏引用的问题

data a;
input x $19.;
cards;
取"+"前面的数据
;
run;

%macro sh(note);
data b;
y="&note";
run;
%mend;

%sh(%nrbquote(取"+"前的数据));

data _null_;
set a;
call execute(%nrstr("%sh(")||%nrbquote(x)||%str(")"));
run;

上述代码，直接引用宏%sh可以运行成功，而用call execute则提示有问题
想问一下为什么，上面两个调用宏的代码不应该是完全一样的吗？
求高手悬赏388币之后，我再加100币，望高手相助，急！！！！

data a;
input x $19.;
cards;
a"+"aaaaa
c'+'cccc
haha"+"hahaha
;
run;

%macro sh(note);
data b;
y="&note";
run;
%mend;

data _null_;
set a;
call execute('%nrstr(%sh('||'%bquote('||strip(x)||")))");
run;

data a;
input x $19.;
cards;
A"+"B
;
run;

%macro sh(note);
data b;
y="&note";              /* the y hold character string */
put "y= " y;
run;
%mend;

%sh(%nrbquote(A"+"B));  
                                          /* OK ,    output: y = A"+"B  */
%sh( A);                   /*  OK,   output:  y = A  */
%sh(A"+"B);             /* error, Character values have been converted to numeric values */
                    /* reason:  the left " in %sh() was combine with the first " in %sh(A"+"B) and
                                     the right " in %sh() was combined with the second " in %sh(A"+"B) to produce
                                    "A"+"B" this caused the error since y want a character string   */         
%sh(A+B);           /*   OK,    output: y = A+B */
%sh(A+"B");        /* error:    Character values have been converted to numeric values */

data _null_;
set a;
* call execute(  '%sh(A"+"B)' );                        /* error: data b; y="A"+"B"; */
* call execute(  '%sh(%nrbquote(A"+"B))');     /* data b; y="A" + "B"; */
call execute(  '%sh(A+B)'  );                              /* OK  output: y=A+B */
run;              /* NOTE use single quotation around the macro %sh(A+B) */

From the log message, it seems that the quotation mark inside macro (ie.  Y=”&note”) were mixed up with the quotation mark in the CALL EXECUTE statement.
This is because the macro variable in CALL EXECUTE statement was resolved immediately.

个人认为这个问题的关键有两个地方：
1. 要使call execute中对宏的引用在数据步执行过程中执行；
2. 要使%bquote也作为宏引用中的一部分。也就是说%bquote要加引号使其作为字符串。

这太深了，不懂。学习下

pobel 发表于 2013-3-3 11:34
个人认为这个问题的关键有两个地方：
1. 要使call execute中对宏的引用在数据步执行过程中执行；
2. 要使 ...

看来我对宏的理解是白学了。

pobel 发表于 2013-3-3 11:34
个人认为这个问题的关键有两个地方：
1. 要使call execute中对宏的引用在数据步执行过程中执行；
2. 要使 ...

代码确实可用，不过还是没有很好的理解，有时间再好好研究一下

yongyitian 发表于 2013-3-3 11:17
data a;
input x $19.;
cards;

你说的这些我也发现了，可是还是没有能很好地解决问题

pobel 发表于 2013-3-2 22:44
data a;
input x $19.;
cards;

大侠能不能把这些 '' ｜｜ ｜｜＇＇讲详细点

yongyitian 发表于 2013-3-3 12:33
大侠能不能把这些 '' ｜｜ ｜｜＇＇讲详细点

||只是连接字符串的符号。
几个字符串通过||连接到一起后再作为call execute（）的参数去执行