如何用宏变量获得某变量的标签

如题，例如我有数据库a，变量b，它的 label 叫做c。

%macro m（n）；
%let abc=&n；
（如何取得b的标签c，将它存为一个宏变量，例如x）
%put x=&x;（则显示“x=c”）
%mend；

谢谢：）

data a;
  b=1;
  label b='C';
run;

data _null_;
   if 0 then set a;
   call symputx('x',vlabel(b));
   stop;
run;
%put x=&x;

data test;
        label b = "TestLabel";
        b = "test";
run;

%macro getlabel(dsin=,var=);
        %let dsid=%sysfunc(open(&dsin.,i));
        %if &dsid %then %do;
              %let vlabel=%sysfunc(varlabel(&dsid, %sysfunc(varnum(&dsid,&var.))));
                %let rc=%sysfunc(close(&dsid));
               %end;
        %put &vlabel;
%mend;

%getlabel(dsin=test,var=b);

pobel 发表于 2013-8-2 20:44
data a;
  b=1;
  label b='C';

正解。我想追问两个问题：

1.if 0 ... 是什么意义呢？

2.能否给我点一下stop是干什么？

Tigflanker 发表于 2013-8-3 10:40
正解。我想追问两个问题：

1.if 0 ... 是什么意义呢？

if 0 then set 是让sas不去读取数据集中的记录。
stop 是让sas停止这个data步的运行。

pobel 发表于 2013-8-4 09:45
if 0 then set 是让sas不去读取数据集中的记录。
stop 是让sas停止这个data步的运行。

谢谢，stop我明白了，非常精细，我还是有些不是特别明白的是：if 0。这个0是定式还是什么？我的意思是：那么if 1，if 2行不行呢？因为我觉得0是代表布尔的否定，if 0给人一种感觉直接否定了。

pobel 发表于 2013-8-4 09:45
if 0 then set 是让sas不去读取数据集中的记录。
stop 是让sas停止这个data步的运行。

谢谢，stop我明白了，非常精细，我还是有些不是特别明白的是：if 0。这个0是定式还是什么？我的意思是：那么if 1，if 2行不行呢？因为我觉得0是代表布尔的否定，if 0给人一种感觉直接否定了。

追加：难道这个0是仅读取变量？if 1就是仅读取完第一条观测？？

Tigflanker 发表于 2013-8-5 09:29
谢谢，stop我明白了，非常精细，我还是有些不是特别明白的是：if 0。这个0是定式还是什么？我的意思是：那 ...

if 0 只是说判断语句中的条件是“假”的，then后面的语句不执行。

比如：a=1; b=2;        if a=b then ...;
如果a 永远不等于b，那么then后面的语句是没有机会执行的。
这个判断语句就相当于 if 0 then ...

既然楼主只是想找到某个变量的label，所以也就没有必要去读取（set语句）变量的值了

Tigflanker 发表于 2013-8-5 09:28
谢谢，stop我明白了，非常精细，我还是有些不是特别明白的是：if 0。这个0是定式还是什么？我的意思是：那 ...

IF 0就不读了，但是有进行编译。没有看到有用IF 1的。

pobel 发表于 2013-8-5 09:57
if 0 只是说判断语句中的条件是“假”的，then后面的语句不执行。

比如：a=1; b=2;        if a=b the ...

谢谢pobel，if 0 明白了，不过总感觉怪怪的，if 0 ，直接就把后面的语句扼杀了，感觉set 语句没有被sas读到，还需要自己再多体会。。。谢谢