Tutorials: Using Multilevel Models to Analyze Marital

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

Tutorials: Using multilevel models to analyze marital

Atkins, D. C. (2005). Using multilevel models to analyze marital and family treatment data: Basic and advanced issues. Journal of Family Psychology, 19, 98-110.

[Paper]
[Data]
[R code]
[SPSS code]

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏0 回帖

关键词：Multilevel Tutorials Tutorial Marital analyze Journal family issues

1. *** SPSS Syntax to accompany .
   
2. *.
   
3. *** Atkins, D. C. (2005). Using multilevel models to analyze couple and family
   
4. *** treatment data: Basic and advanced issues.  Journal of Family Psychology, 19,
   
5. *** 98-110.
   
6. *.
   
7. *** Introductory: The following SPSS syntax demonstrates how to fit the models for
   
8. *** the examples from the article mentioned above, with the exception of the
   
9. *** simulations described in the power/sample size section, which is only available
   
10. *** in R.  I have tried to make this file as clear as possible, but please don't
    
11. *** hesitate to contact me with questions and/or clarifications (or suggestions for
    
12. *** improvement!).
    
13. *.
    
14. *** Best, Dave Atkins (datkins@fuller.edu)
    
15. *.
    
16. *** Import data .
    
17. *.
    
18. *** NOTE: You'll need to change the /FILE to indicate where the file is saved .
    
19. ***                on your computer .
    
20. GET DATA  /TYPE = TXT
    
21. /FILE = 'C:\Temp\Atkins JFP data.dat'
    
22. /DELCASE = LINE
    
23. /DELIMITERS = "\t"
    
24. /QUALIFIER = '"'
    
25. /ARRANGEMENT = DELIMITED
    
26. /FIRSTCASE = 2
    
27. /IMPORTCASE = ALL
    
28. /VARIABLES =
    
29. id F2.1
    
30. sex F1.0
    
31. therapy F2.1
    
32. time F1.0
    
33. das F2.1
    
34. pilot F16.2
    
35. miss F1.0
    
36. m.ind F1.0
    
37. .
    
38. CACHE.
    
39. EXECUTE.
    
40. 
    
41. *** Save data after import .
    
42. *.
    
43. *** NOTE: Again, change location to where you'd like to save it .
    
44. SAVE OUTFILE='C:\Temp\JFP data.sav'
    
45. /COMPRESSED.
    
46. 
    
47. *** Value labels for therapy .
    
48. Value Labels  therapy  
    
49.      -0.5 "Tx1" 0.5 "Tx2" .
    
50. 
    
51. *** Value labels for sex .
    
52. Value Labels  sex  
    
53.      0 "Husband" 1 "Wife" .
    
54. 
    
55. ************************ Two Level Example ******************* .
    
56. *.
    
57. *** In SPSS, we need to explicitly create quadratic .
    
58. COMPUTE time2 = time**2 .
    
59. EXECUTE .
    
60. 
    
61. *** To restrict analyses to Wives, need to "filter" Husbands .
    
62. USE ALL.
    
63. COMPUTE filter_$=(sex=1).
    
64. VARIABLE LABEL filter_$ 'sex=1 (FILTER)'.
    
65. VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
    
66. FORMAT filter_$ (f1.0).
    
67. FILTER BY filter_$.
    
68. EXECUTE .
    
69. 
    
70. *** Run the following command to "turn off" case selection (when you want to) .
    
71. FILTER OFF.
    
72. USE ALL.
    
73. EXECUTE .
    
74. 
    
75. *** Next, run HLM analysis with random intercept, slope, and quadratic .
    
76. MIXED
    
77.   das BY id WITH therapy time time2
    
78.   /FIXED = therapy time time2 therapy*time therapy*time2 | SSTYPE(3)
    
79.   /METHOD = REML
    
80.   /PRINT = CORB COVB SOLUTION TESTCOV
    
81.   /RANDOM INTERCEPT time time2 | SUBJECT(id) COVTYPE(UN) .
    
82. 
    
83. *** NOTE: the above code treats "therapy" as a contiuous variable .
    
84. ***                if we treat it as categorical (factor), SPSS gives the .
    
85. ***                variable a different set of contrasts; this way we .
    
86. ***                retain the -0.5, 0.5 contrasts .
    
87. *.
    
88. *** NOTE: You can use the /TEST command to get specific contrasts.
    
89. ***                For example, you might try inserting the following .
    
90. ***                commands after the /RANDOM statement above, but don't .
    
91. ***                forget to move the "." to the end of the command .
    
92. *.
    
93. *** /TEST 'SLOPE - TX1-EST'  time 1 therapy*time 1 0
    
94. *** /TEST 'SLOPE - TX2-EST'  time 1 therapy*time 0 1
    
95. *** /TEST 'CONTRAST SLOPE '  therapy*time  1 -1
    
96. *** /TEST 'POOLED SLOPE' time 1 therapy*time 0.5 0.5
    
97. 
    
98. ******* Multilevel Models for Longitudinal Couple and Family Data ****** .
    
99. *.
    
100. *** To run the model in equation 5, first turn off the "case selection" .
     
101. *** that we ran earlier to select only Wives (if you haven't already) .
     
102. MIXED
     
103.   das BY id sex WITH therapy time time2
     
104.   /FIXED = therapy time time2 therapy*time therapy*time2 | SSTYPE(3)
     
105.   /METHOD = REML
     
106.   /PRINT = COVB SOLUTION TESTCOV
     
107.   /RANDOM INTERCEPT | SUBJECT(id*sex) COVTYPE(UN)
     
108.   /RANDOM INTERCEPT time time2 | SUBJECT(id) COVTYPE(UN)
     
109.   /SAVE RESID .
     
110. 
     
111. *** NOTE: The command above saves the level-1 residuals via the /SAVE .
     
112. *** statement.  This creates a new column in the datafile with the level-1 .
     
113. *** residuals, which can then be used to examine the distributional .
     
114. *** assumptions.  Unfortunately, it is not straightforward to have SPSS .
     
115. *** save the Empirical Bayes residuals of the level-2 and level-3 .
     
116. *** random-effects.  In a very thorough review of the MIXED command in .
     
117. *** SPSS, Alastair Leyland shows how it is possible to calculate the .
     
118. *** EB residuals: http://multilevel.ioe.ac.uk/softrev/index.html .
     
119. *.
     
120. *** To fit the multivariate model in equation 6, we need to create vectors .
     
121. *** that specify male intercept, female intercept, male slope, and female slope .
     
122. *.
     
123. *** We can recode from our sex variable to create the intercepts .
     
124. RECODE sex (0=0) (1=1) INTO f.int .               
     
125. RECODE sex (0=1) (1=0) INTO m.int .               
     
126. EXECUTE .
     
127. 
     
128. *** Now, slopes .
     
129. COMPUTE f.slope = f.int*time .
     
130. COMPUTE m.slope = m.int*time .
     
131. EXECUTE .
     
132. 
     
133. *** Now we can run the multivariate model; notice that we exclude the intercept .
     
134. *** from both the /FIXED and /RANDOM statements .
     
135. MIXED
     
136.   das BY id WITH f.int m.int f.slope m.slope
     
137.   /FIXED = f.int m.int f.slope m.slope | NOINT SSTYPE(3)
     
138.   /METHOD = REML
     
139.   /PRINT = COVB CORB SOLUTION TESTCOV
     
140.   /RANDOM f.int m.int f.slope m.slope  | SUBJECT(id) COVTYPE(UN) .
     
141. 
     
142. *** We could easily extend this model to include quadratic effects and .
     
143. *** interactions with therapy.  However, the random-effects parameters .
     
144. *** in multivariate models grow very quickly.  You can end up "over-fitting" .
     
145. *** your data, leading to convergence problems and ill-conditioned .
     
146. *** random-effects matrices .
     
147. *.
     
148. 
     
149. ********************* Missing Data Example *******************************.
     
150. *.
     
151. *** The missing data section doesn't really require any special models; if you .
     
152. *** wish to reproduce the analyses in the manuscript, use the "miss" variable to select only .
     
153. *** those cases with a value of 0 (to mimic missing data); then, m.ind is the .
     
154. *** the missing data indicator variable (our pattern) .
     
155. *.
     
156. *** To restrict analyses to miss = 0 .
     
157. USE ALL.
     
158. COMPUTE filter_$=(miss=0).
     
159. VARIABLE LABEL filter_$ 'miss=0 (FILTER)'.
     
160. VALUE LABELS filter_$  0 'Not Selected' 1 'Selected'.
     
161. FORMAT filter_$ (f1.0).
     
162. FILTER BY filter_$.
     
163. EXECUTE .
     
164. 
     
165. *** Run the following command to "turn off" case selection (when you want to) .
     
166. FILTER OFF.
     
167. USE ALL.
     
168. EXECUTE .
     
169. 
     
170. *** Here's the command to run the model in equation 7 .
     
171. MIXED
     
172.   das BY id sex WITH therapy m.ind time
     
173.   /FIXED = therapy m.ind therapy*m.ind time therapy*time m.ind*time therapy*m.ind*time | SSTYPE(3)
     
174.   /METHOD = REML
     
175.   /PRINT = COVB SOLUTION TESTCOV
     
176.   /RANDOM INTERCEPT | SUBJECT(id*sex) COVTYPE(UN)
     
177.   /RANDOM INTERCEPT time | SUBJECT(id) COVTYPE(UN) .
     
178. 
     
179. *** Use the output from the above command along with the description in the text .
     
180. *** to estimate the pattern-mixture models .
     
181. *.
     
182. *** Simulation and power: These analyses are only possible using R; however, I have .
     
183. *** recently discovered that Raudenbush, Liu, and Congdon have extended the power .
     
184. *** analyses functions of their Optimal Design software to handle some 3-level .
     
185. *** models.  The program and manual can be downloaded here:
     
186. *.
     
187. *** http://www.ssicentral.com/other/hlmod.htm
     
188. .

复制代码