sas求前10行观测加总

如图，现在有date(日期）和sales(销售)数据，如何用sas来处理，构建新的变量求当前日期前10天总销售量。比如，构建新的变量total，11号的total等于1号到10号的sales加总。唯一能想的方法是lag10次，但太麻烦，请问大神们有什么简便方法。谢谢

1. data tmp;
   
2. var='01Jan2016'd;
   
3. do i=1 to 30;
   
4.         date=intnx('day',var,i-1);
   
5.         sales=i;
   
6.         output;
   
7. end;
   
8. drop var i;
   
9. format date yymmdd10.;
   
10. run;
    
11. 
    
12. proc sql;
    
13.         create table tmp1 as
    
14.         select a.date,b.date as lag_date,b.sales from tmp a left join  tmp b
    
15.         on 0<intck('day',b.date,a.date)<=10
    
16.         order by a.date,b.date;
    
17. 
    
18.         create table out as
    
19.         select date,sum(sales) as total from tmp1
    
20.         group by date
    
21.         having count(*)=10;
    
22. quit;

复制代码

mingfeng07 发表于 2016-8-10 10:25

厉害！

也可以试一下这个方法：

data test;
do date='01jan2016'd to '31jan2016'd;
  sale+1;
  output;
end;
format date yymmdd10.;
run;

data wanted;
set test;
retain _firstdate;
if _n_=1 then _firstdate=date;
call missing(total);
do i=1 to nobs;
  set test(rename=(date=_date sale=_sale)) point=i nobs=nobs;
  if date-_firstdate>=10 and 0<date-_date<=10 then total+_sale;
end;
drop _:;
run;

wwang111 发表于 2016-8-10 13:58
也可以试一下这个方法：

data test;

牛逼，谢谢！