楼主: l1i2n3i4n5g
48361 125

[学习分享] 如何用SAS画统计图，这是我的学习分享！   [推广有奖]

21楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-2-6 09:38:59
BUTTERFLY GROUP BAR CHART
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: BUTTERFLY GROUP BAR CHART (Clinical Trial Reporting)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180205
  6.    From: Clinical Trial Reporting Using SAS/GRAPH? SG Procedures
  7.          http://support.sas.com/resources/papers/proceedings09/174-2009.pdf
  8.    History: 20180205;
  9. %mend;

  11. /*建立数据集cancer,用于后续画图*/
  12. data cancer;
  13. /*label response = 'Mean Clinical Response'    label会体现在图的x、y轴label
  14.       visit    = 'Visit';*/
  15. input cause :$20.
  16.       mcases
  17.       fcases
  18.       mdeaths
  19.       fdeaths
  20.       deaths;
  21. cards;
  22. Lung_Cancer -114760 98620 -89510 70880 160390
  23. Colorectal_Cancer -55290 57050 -26000 26180 52180
  24. Breast_Cancer -2030 178480 -450 40460 40910
  25. ;
  26. run;

  28. proc format;
  29. picture positive low-<0='000,000'
  30. 0<-high='000,000';
  31. run;
  32. proc sort data=cancer;
  33. by descending deaths;
  34. run;

  36. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  37. ods listing gpath='C:\Users\Administrator\Desktop\test20180205';
  38. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  39. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  40. ods graphics off;

  42. /*BUTTERFLY GROUP BAR CHART*/
  43. proc sgplot data=cancer;
  44.    format mcases mdeaths
  45.    fcases fdeaths positive.;
  46.    hbar cause / response=mcases
  47.    fillattrs=graphdata1 transparency=.65
  48.    legendlabel="New Cases (Male)"
  49.    name="mcases" ;
  50.    hbar cause / response=mdeaths
  51.    barwidth=.5
  52.    fillattrs=graphdata1 transparency=.25
  53.    legendlabel="Deaths (Male)"
  54.    name="mdeaths" ;
  55.    hbar cause / response=fcases
  56.    fillattrs=graphdata2 transparency=.65
  57.    legendlabel="New Cases (Female)"
  58.    name="fcases";
  59.    hbar cause / response=fdeaths
  60.    barwidth=.5
  61.    fillattrs=graphdata2 transparency=.25
  62.    legendlabel="Deaths (Female)"
  63.    name="fdeaths";
  64.    keylegend "mcases" "fcases" "mdeaths"
  65.    "fdeaths" / across=2;
  66.    xaxis label=" " grid;
  67.    yaxis label=" " discreteorder=data;
  68. run;

  70. ods _all_ close;
  71. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
22楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-2-6 13:55:03
Logarithmic Scale on the Y Axis
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Logarithmic Scale on the Y Axis (Clinical Trial Reporting)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180206
  6.    From: Clinical Trial Reporting Using SAS/GRAPH? SG Procedures
  7.          http://support.sas.com/resources/papers/proceedings09/174-2009.pdf
  8.    History: 20180206;
  9. %mend;

  11. /*建立数据集diabetes,用于后续画图*/
  12. data diabetes;
  13. /*label response = 'Mean Clinical Response'    label会体现在图的x、y轴label
  14.       visit    = 'Visit';*/
  15. input age Cpeptide;
  16. cards;
  17. 5.2 4.8
  18. 8.8 4.1
  19. 10.5 5.2
  20. 10.6 5.5
  21. 1 3
  22. 1.5 4
  23. 8 4.9
  24. 10 5.9
  25. 10.8 5.8
  26. 15 5.9
  27. 14.8 5.8
  28. 3 5.9
  29. 4 5.8
  30. 5 5.9
  31. 12.8 5.8
  32. ;
  33. run;

  35. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  36. ods listing gpath='C:\Users\Administrator\Desktop\test20180206';
  37. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  38. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  39. ods graphics off;

  41. /*Logarithmic Scale on the Y Axis*/
  42. proc sgplot data=diabetes;
  43.    pbspline x=age y=Cpeptide /
  44.    clm="99% CLM" cli="99% CLI"
  45.    markerattrs=(symbol=squarefilled);
  46.    refline 4.4817 / label='1.5'
  47.    labelpos=min;
  48.    yaxis type=log logbase=e
  49.    logstyle=logexponent
  50.    label='log (base e) C-peptide';
  51. run;

  53. ods _all_ close;
  54. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
23楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-2-6 14:17:32
Customized GTL Code_before GTL Customized GTL Code_after GTL
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Customized GTL Code (Clinical Trial Reporting)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180206
  6.    From: Clinical Trial Reporting Using SAS/GRAPH? SG Procedures
  7.          http://support.sas.com/resources/papers/proceedings09/174-2009.pdf
  8.    History: 20180206;
  9. %mend;

  11. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  12. ods listing gpath='C:\Users\Administrator\Desktop\test20180206_1';
  13. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  14. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  15. ods graphics off;

  17. /*Customized GTL Code*/
  18. proc sgplot data=sashelp.class;
  19.    scatter x=weight y=height;
  20.    refline 100 / axis=x labelloc=inside label='Weight=100 lb' ;
  21. run;

  23. proc template;
  24.    define statgraph mysgplot;
  25.    begingraph;
  26.       layout overlay;
  27.          ScatterPlot X=Weight Y=Height / primary=true LegendLabel="Height" name="scatter";
  28.          ReferenceLine x=100 / clip=true CurveLabel="Weight=100 lb"
  29.          CurveLabelLocation=Inside curvelabelattrs=(color=red style=italic size=12pt);
  30.       endlayout;
  31.    endgraph;
  32.    end;
  33. run;

  35. proc sgrender data=sashelp.class
  36.    template=mysgplot;
  37. run;

  39. ods _all_ close;
  40. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
24楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 10:38:54
20180229_Scatter Plot (using template and sgrender procedure)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Scatter Plot (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  12. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  13. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  14. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  15. ods graphics off;

  17. /*Scatter Plot*/
  18. proc template; /*建立模板*/
  19. define statgraph Fig_4_2_1;   /*模板名为Fig_4_2_1*/
  20. begingraph;
  21. entrytitle 'Weight by Height';   /*指定title*/
  22. layout overlay / xaxisopts=(griddisplay=on) yaxisopts=(griddisplay=on); /*画网格*/
  23.    scatterplot x=height y=weight / group=sex datalabel=name name='a';/*画散点图*/
  24.    discretelegend 'a' / location=inside title='Sex:' halign=right valign=bottom ;/*图例*/
  25. endlayout;
  26. endgraph;
  27. end;
  28. run;
  29. proc sgrender data=sashelp.class template= Fig_4_2_1;
  30. run;

  32. ods _all_ close;
  33. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
25楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 10:59:35
Series Plot (using template and sgrender procedure)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Series Plot (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. /*建立数据集diabetes,用于后续画图*/
  12. data GTL_GS_SeriesGroup;
  13. format Date Date9.;
  14. do i=0 to 334 by 30;
  15.    date='01jan2009'd+i;
  16.    if mod (i, 30) =0 then freq=1; else freq=0;
  17.    Drug='Drug A'; Val = 16+ 3*sin(i/90+0.5) + 1*sin(3*i/90+0.7); output;
  18.    Drug='Drug B'; Val = 10+ 3*sin(i/90+0.5) + 1*cos(3*i/90+0.7); output;
  19.    Drug='Drug C'; Val =  6+ 3*cos(i/90+0.5) + 1*sin(3*i/90+0.7); output;
  20. end;
  21. run;

  23. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  24. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  25. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  26. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  27. ods graphics off;

  29. /*Series Plot*/
  30. proc template;
  31. define statgraph Fig_4_2_2;
  32. dynamic _title;/*有用吗？*/
  33. begingraph / subpixel=on;/*配合smoothconnect=true，使图片更加光滑*/
  34. entrytitle 'Response by Time by Treatment';
  35. layout overlay / yaxisopts=(griddisplay=on label='Response')
  36.    xaxisopts=(griddisplay=on display=(ticks tickvalues));
  37.    seriesplot x=date y=val / group=drug curvelabel=drug display=(markers)/*marker为drug值*/
  38.       smoothconnect=true lineattrs=(thickness=2);/*smoothconnect类似样条曲线*/
  39. endlayout;
  40. endgraph;
  41. end;
  42. run;
  43. proc sgrender data=GTL_GS_SeriesGroup template=Fig_4_2_2;
  44. run;

  46. ods _all_ close;
  47. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
26楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 11:19:39
Step Plot (using template and sgrender procedure)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Step Plot (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. /*建立数据集diabetes,用于后续画图*/
  12. data GTL_GS_stepGroup;
  13. format Date Date9.;
  14. do i=0 to 334 by 40;
  15.    date='01jan2009'd+i;
  16.    if mod (i, 30) =0 then freq=1; else freq=0;
  17.    Drug='Drug A'; Val = 16+ 3*sin(i/90+0.5) + 1*sin(3*i/90+0.7);
  18.    upper=val*1.1; lower=val*0.95; output;
  19.    Drug='Drug B'; Val = 11+ 3*sin(i/90+0.5) + 1*cos(3*i/90+0.7);
  20.    upper=val*1.1; lower=val*0.95; output;
  21.    if i > 150 and i < 210 then val=.;
  22.    else Val = 7+ 3*cos(i/90+0.5) + 1*sin(3*i/90+0.7);
  23.    Drug='Drug C'; upper=val*1.1; lower=val*0.95; output;
  24. end;
  25. run;

  27. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  28. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  29. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  30. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  31. ods graphics off;

  33. /*Step Plot*/
  34. proc template;
  35. define statgraph Fig_4_2_3;
  36. begingraph;
  37. entrytitle 'Response and CL by Time and Treatment';
  38. layout overlay / xaxisopts=(display=(ticks tickvalues line))
  39.    yaxisopts=(display=(ticks tickvalues line));
  40.    stepplot x=date y=val / group=drug name='s' errorupper=upper
  41.             errorlower=lower lineattrs=(pattern=solid) justify=center
  42.             display=(markers) markerattrs=(symbol=circlefilled) break=true
  43.             curvelabel=drug curvelabelposition=min;
  44. endlayout;
  45. endgraph;
  46. end;
  47. run;
  48. proc sgrender data=GTL_GS_stepGroup template=Fig_4_2_3;
  49. run;

  51. ods _all_ close;
  52. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
27楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 11:30:56
Band Plot (using template and sgrender procedure)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Band Plot (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. /*建立数据集GTL_GS_bandGroup,用于后续画图*/
  12. data GTL_GS_bandGroup;
  13. format Date Date9.;
  14. do i=0 to 334 by 1;
  15.    date='01jan2009'd+i;
  16.    if mod (i, 30) =0 then freq=1; else freq=0;
  17.    Drug='Drug A'; Val = 16+ 3*sin(i/90+0.5) + 1*sin(3*i/90+0.7); upper=val*1.1; lower=val*0.95; output;
  18.    Drug='Drug B'; Val = 11+ 3*sin(i/90+0.5) + 1*cos(3*i/90+0.7); upper=val*1.1; lower=val*0.95; output;
  19.    Drug='Drug C'; Val = 12+ 3*cos(i/90+0.5) + 1*sin(3*i/90+0.7); upper=val*1.1; lower=val*0.95; output;
  20. end;
  21. run;

  23. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  24. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  25. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  26. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  27. ods graphics off;

  29. /*Band Plot*/
  30. proc template;
  31. define statgraph Fig_4_2_4;
  32. dynamic _title;
  33. begingraph / subpixel=on;
  34. entrytitle 'Response over Time';
  35. layout overlay / yaxisopts=(label='Response') xaxisopts=(display=(ticks tickvalues));
  36.    bandplot x=date limitupper=upper limitlower=lower /
  37.             group=drug display=(fill outline)
  38.             outlineattrs=(pattern=solid thickness=2)
  39.             fillattrs=(transparency=0.5) name='a';
  40.    discretelegend 'a' / location=inside halign=right valign=top across=1;
  41. endlayout;
  42. endgraph;
  43. end;
  44. run;
  45. proc sgrender data=GTL_GS_bandGroup template=Fig_4_2_4;
  46. run;

  48. ods _all_ close;
  49. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
28楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 14:20:29
High Low Plot (TYPE = Bar)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: High Low Plot (TYPE = Bar) (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. /*建立数据集GTL_GS_highlow,用于后续画图*/
  12. data GTL_GS_highlow;
  13. length cap $ 12;
  14. input drug $ low high cap $;
  15. datalines;
  16. A      10 20 NONE
  17. A      30 60 NONE
  18. B      20 35 NONE
  19. B      50 75 NONE
  20. C      30 90 FILLEDARROW
  21. ;
  22. run;

  24. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  25. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  26. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  27. /*ods graphics on / imagename="picture" outputfmt=pdf;     图片名称picture，输出类型pdf*/
  28. ods graphics off;

  30. /*High Low Plot (TYPE = Bar)*/
  31. proc template; /*--SAS 9.4--*/
  32. define statgraph Fig_4_2_6;
  33. begingraph;
  34. entrytitle 'Treatment by Days';
  35. layout overlay / xaxisopts=(griddisplay=on label='Days')
  36.    yaxisopts=(label='Treatment');
  37.    highlowplot y=drug high=high low=low / highcap=cap
  38.       highlabel=high type=bar group=drug dataskin=sheen
  39.       outlineattrs=(pattern =solid) barwidth=0.6
  40.       labelattrs=(size=10);
  41. endlayout;
  42. endgraph;
  43. end;
  44. run;
  45. proc sgrender data=GTL_GS_highlow template=Fig_4_2_6;
  46. run;

  48. ods _all_ close;
  49. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
29楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 14:51:46
Bubble Plot (using template and sgrender procedure)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Bubble Plot (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  12. /*ods listing gpath='C:\Users\Administrator\Desktop\test20180229' image_dpi=100;*/
  13. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  14. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  15. /*ods graphics on / imagename="picture" outputfmt=pdf width=4in height=2.5in;*/
  16. /*ods graphics on / imagename="picture" outputfmt=pdf;*/
  17. /*图片名称picture，输出类型pdf*/
  18. ods graphics off;

  20. /*Bubble Plot*/
  21. proc template; /*--SAS 9.4--*/
  22. define statgraph Fig_4_2_7;
  23. begingraph / subpixel=on;
  24. entrytitle 'Age by Height and Weight';
  25. layout overlay / xaxisopts=(griddisplay=on)
  26.    yaxisopts=(griddisplay=on);
  27.    bubbleplot x=height y=weight size=age / group=sex
  28.       dataskin=gloss name='a';
  29.    discretelegend 'a' / location=inside valign=bottom
  30.       halign=right title='Sex:';
  31. endlayout;
  32. endgraph;
  33. end;
  34. run;
  35. proc sgrender data=sashelp.class template=Fig_4_2_7;
  36. run;

  38. ods _all_ close;
  39. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
30楼
l1i2n3i4n5g(未真实交易用户) 在职认证  发表于 2018-3-1 15:18:05
Needle Plot (using template and sgrender procedure)
  1. %macro comment();    /*这是一种比较特殊的注释方式*/
  2.    Picture: Needle Plot (using template and sgrender procedure)
  3.    Software： SAS 9.4 TS Level 1M2
  4.    Name: justsoso
  5.    Date: 20180229
  6.    From: Getting Started with the Graph Template Language in SAS:
  7.          Examples, Tips, and Techniques for Creating Custom Graphs
  8.    History: 20180229;
  9. %mend;

  11. /*建立数据集GTL_GS_highlow,用于后续画图*/
  12. data GTL_GS_NeedleLabel;
  13. format Date Date9.;
  14. format a 4.3;
  15. do i=0 to 334 by 30;
  16.    date='01jan2009'd+i; A = 16+ 3*sin(i/90+0.5) + 1*sin(3*i/90+0.7); output;
  17. end;
  18. run;

  20. ods _all_ close;     /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
  21. /*ods listing gpath='C:\Users\Administrator\Desktop\test20180229' image_dpi=100;*/
  22. ods listing gpath='C:\Users\Administrator\Desktop\test20180229';
  23. /*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
  24. /*ods graphics on / imagename="picture" outputfmt=pdf width=4in height=2.5in;*/
  25. /*ods graphics on / imagename="picture" outputfmt=pdf;*/
  26. /*图片名称picture，输出类型pdf*/
  27. ods graphics off;

  29. /*Needle Plot*/
  30. proc template;
  31. define statgraph Fig_4_2_8;
  32. dynamic _title;
  33. begingraph;
  34. entrytitle 'Response over Time';
  35. layout overlay / xaxisopts=(display=(ticks tickvalues))
  36.    yaxisopts=(label='Response' offsetmin=0);
  37.    needleplot x=date y=a / display=(markers)
  38.       lineattrs=(thickness=3) datalabel=a
  39.       markerattrs=(symbol=circlefilled size=11)
  40.       datalabelposition=top datalabelattrs=(size=5);
  41. endlayout;
  42. endgraph;
  43. end;
  44. run;
  45. proc sgrender data=GTL_GS_NeedleLabel template=Fig_4_2_8;
  46. run;

  48. ods _all_ close;
  49. /*ods html;      最好将ods destination恢复至默认的html*/
复制代码
返回列表
12345678910... 13下一页
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 我要注册

本版微信群
加好友,备注cda
拉您进交流群

京ICP备16021002号-2 京B2-20170662号 京公网安备 11010802022788号 论坛法律顾问：王进律师 知识产权保护声明   免责及隐私声明

GMT+8, 2025-12-6 08:41