如何用SAS画统计图，这是我的学习分享！ - 第8页

71楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-13 14:22:51

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Column Lattice with Column Headings
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Column Lattice with Column Headings*/
proc template;
define statgraph Fig_5_4_4;
begingraph;
entrytitle 'Blood Pressure by Cholesterol';
layout lattice / rowdatarange=union order=columnmajor;/*左右单元结构*/
rowaxes;
rowaxis / display=(ticks tickvalues) griddisplay=on;
endrowaxes;
column2headers;
entry textattrs=graphlabeltext(weight=bold) 'Systolic';
entry textattrs=graphlabeltext(weight=bold) 'Diastolic';
endcolumn2headers;
layout overlay / xaxisopts=(griddisplay=on);
scatterplot x=cholesterol y=systolic / datatransparency=0.9
markerattrs=graphdata1(symbol=circlefilled);
endlayout;
layout overlay / xaxisopts=(griddisplay=on);
scatterplot x=cholesterol y=diastolic / datatransparency=0.9
markerattrs=graphdata1(symbol=circlefilled);
endlayout;
endlayout;
endgraph;
end;
run;
proc sgrender template=Fig_5_4_4 data=sashelp.heart;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

72楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-13 14:30:12

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Nested Lattice
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Nested Lattice*/
proc template; /*--SAS 9.4--*/
define statgraph Fig_5_4_5;
begingraph / subpixel=on;
entrytitle 'Car Statistics';
layout lattice / columns=2;
layout overlay / yaxisopts=(griddisplay=on)
xaxisopts=(griddisplay=on);
scatterplot x=horsepower y=mpg_city / filledoutlinedmarkers=true/*加浓*/
dataskin=gloss markerattrs=(size=13 symbol=circlefilled)
markerfillattrs=graphdata1;
regressionplot x=horsepower y=mpg_city / degree=2;
endlayout;
layout lattice / columndatarange=union;
columnaxes;
columnaxis;
endcolumnaxes;
layout overlay / yaxisopts=(griddisplay=on);
barchart x=origin y=mpg_city / stat=mean
dataskin=gloss fillattrs=graphdata3;
endlayout;
layout overlay / yaxisopts=(griddisplay=on);
boxplot x=origin y=mpg_city / fillattrs=graphdata5;
endlayout;
endlayout;
endlayout;
endgraph;
end;
run;
proc sgrender template=Fig_5_4_5 data=sashelp.cars; run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

73楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-13 14:37:06

Gridded Layout with Embedded Statistics Table

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Gridded Layout with Embedded Statistics Table
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Gridded Layout with Embedded Statistics Table*/
proc template; /*--SAS 9.4--*/
define statgraph Fig_5_4_6;
begingraph / subpixel=on;
entrytitle 'Car Statistics';
layout overlay / yaxisopts=(griddisplay=on)
xaxisopts=(griddisplay=on);
scatterplot x=horsepower y=mpg_city / filledoutlinedmarkers=true
dataskin=gloss markerattrs=(size=13 symbol=circlefilled)
markerfillattrs=graphdata1;
regressionplot x=horsepower y=mpg_city / degree=2;
layout gridded / rows=3 order=columnmajor border=true
autoalign=(topright topleft);/*topleft貌似没用*/
entry textattrs=(size=10) halign=right 'N = ';
entry textattrs=(size=10) halign=right 'Mean = ';
entry textattrs=(size=10) halign=right {unicode SIGMA} ' =';
entry textattrs=(size=10) halign=left
eval(strip(put(n(mpg_city),4.0)));/*需要进一步研究*/
entry textattrs=(size=10) halign=left
eval(strip(put(mean(mpg_city),4.1)));
entry textattrs=(size=10) halign=left
eval(strip(put(stddev(mpg_city),4.1)));
endlayout;
endlayout;
endgraph;
end;
run;
proc sgrender template=Fig_5_4_6 data=sashelp.cars;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

74楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-13 16:54:28

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Lab Values by Study Week
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
/*--Fig_5_5_1 Lab Values by Study Week--*/
data GTL_GS_Labs_by_Week;
label sgot="SGOT";
label aph="ALKPHOS";
label visit="Study Week";
input visit $ 1-10 treatment $ sgot aph;
datalines;
SCREENING PLACEBO . 108.943
WEEK 2 PLACEBO 10.2941 83.740
WEEK 4 PLACEBO 16.1765 76.423
WEEK 6 PLACEBO 17.6471 86.179
WEEK 8 PLACEBO 11.7647 67.480
WEEK 10 PLACEBO 14.7059 68.293
WEEK 12 PLACEBO 13.2353 73.171
WEEK 14 PLACEBO 12.5000 74.797
SCREENING ACTIVE 12.5000 66.667
WEEK 2 ACTIVE 17.3077 57.961
WEEK 4 ACTIVE 17.9487 68.873
WEEK 6 ACTIVE 26.9231 98.748
WEEK 8 ACTIVE 25.9615 98.211
WEEK 10 ACTIVE 27.2436 100.179
WEEK 12 ACTIVE 29.9679 104.293
WEEK 14 ACTIVE 26.9231 115.921
;
run;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Lab Values by Study Week*/
proc template;
define statgraph Fig_5_5_1_Lab_Values;
begingraph;
entrytitle "Lab Values by Study Week";
layout gridded / rowgutter=5;
layout datapanel classvars=(treatment) / columns=1
rowaxisopts=(griddisplay=on)
columnaxisopts=(tickvalueattrs=(size=5) griddisplay=on)
headerLabelDisplay=Value;
layout prototype / cycleattrs=true;
seriesPlot X=visit Y=sgot / primary=true display=(markers)
markerattrs=(size=9px weight=bold)
lineattrs=(thickness=2px) NAME="series1";
seriesPlot X=visit Y=aph / yaxis=y2 display=(markers)
markerattrs=(size=9px weight=bold)
lineattrs=(thickness=2px) NAME="series2";
endlayout;
endlayout;
DiscreteLegend "series1" "series2" /;
endlayout;
endgraph;
end;
run;
proc sgrender data=GTL_GS_Labs_by_Week template="Fig_5_5_1_Lab_Values";
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

75楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-13 17:02:30

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: LFT Safety Panel, Baseline versus Study
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
/*--Fig_5_5_2 LFT Lattice--*/
data GTL_GS_LFT_Lattice (keep=drug alat biltot alkph asat
palat pbiltot palkph pasat visitnum);
label alat="ALAT (/ULN)";
label biltot="BILTOT (/ULN)";
label alkph="ALKPH (/ULN)";
label asat="ASAT (/ULN)";
visitnum=1;
do i= 1 to 100;
palat = min (4, 2.5 * (abs(rannor(123))) / 3.0);
pbiltot = min (4, 2.5 * (abs(rannor(123))) / 3.0);
palkph = min (4, 2.5 * (abs(rannor(123))) / 3.0);
pasat = min (4, 2.5 * (abs(rannor(123))) / 3.0);
alat = min (4, 2.5 * (abs(rannor(345))) / 3.0);
biltot = min (4, 2.5 * (abs(rannor(345))) / 3.0);
alkph = min (4, 2.5 * (abs(rannor(345))) / 3.0);
asat = min (4, 2.5 * (abs(rannor(345))) / 3.0);
j = rannor(345);
if j > 0 then drug = "A";
else drug="B";
output;
end;
visitnum=2;
do i= 1 to 100;
palat = min (4, 2.5 * (abs(rannor(789))) / 3.0);
pbiltot = min (4, 2.5 * (abs(rannor(789))) / 3.0);
palkph = min (4, 2.5 * (abs(rannor(789))) / 3.0);
pasat = min (4, 2.5 * (abs(rannor(789))) / 3.0);
alat = min (4, 2.5 * (abs(rannor(567))) / 3.5);
biltot = min (4, 2.5 * (abs(rannor(567))) / 3.5);
alkph = min (4, 2.5 * (abs(rannor(567))) / 3.5);
asat = min (4, 2.5 * (abs(rannor(567))) / 3.5);
j = rannor(567);
if j > 0 then drug = "A";
else drug="B";
output;
end;
visitnum=3;
do i= 1 to 100;
palat = min (4, 2.5 * (abs(rannor(321))) / 3.0);
pbiltot = min (4, 2.5 * (abs(rannor(321))) / 3.0);
palkph = min (4, 2.5 * (abs(rannor(321))) / 3.0);
pasat = min (4, 2.5 * (abs(rannor(321))) / 3.0);
alat = min (4, 2.5 * (abs(rannor(975))) / 2.5);
biltot = min (4, 2.5 * (abs(rannor(975))) / 2.5);
alkph = min (4, 2.5 * (abs(rannor(975))) / 2.5);
asat = min (4, 2.5 * (abs(rannor(975))) / 2.5);
j = rannor(975);
if j > 0 then drug = "A";
else drug="B";
output;
end;
run;
proc format;
value wk
1='1 Week'
2='3 Months'
3='6 Months';
value lab
1='ALAT'
2='Bilirubin Total'
3='Alk Phosphatase'
4='ASAT';
value $trt
"A"="Drug A (n=240)"
"B"="Drug B (n=195)";
run;
data GTL_GS_LFT_Lattice2 (keep=visitnum drug labtest result pre);
format visitnum wk. labtest lab. drug $trt.;
label pre='Baseline (/ULN) *' result='Study (/ULN)';
set GTL_GS_LFT_Lattice;
pre=palat;
labtest=1;
result=alat;
output;
pre=pbiltot;
labtest=2;
result=biltot;
output;
pre=palkph;
labtest=3;
result=alkph;
output;
pre=pasat;
labtest=4;
result=asat;
output;
run;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*LFT Safety Panel, Baseline versus Study*/
proc template;
define statgraph Fig_5_5_2_LFT_Lattice;
begingraph;
entrytitle 'LFT Safety Panel, Baseline vs. Study';
layout datalattice rowvar=visitnum columnvar=labtest /
headerlabeldisplay=value
rowaxisopts=(linearopts=(viewmin=0 viewmax=4))
columnaxisopts=(linearopts=(viewmin=0 viewmax=4));
layout prototype;
scatterplot x=pre y=result / group=drug;
referenceline x=1 / lineattrs=(pattern=dash);
referenceline x=1.5 / lineattrs=(pattern=dash);
referenceline x=2 / lineattrs=(pattern=dash);
referenceline y=1 / lineattrs=(pattern=dash);
referenceline y=1.5 / lineattrs=(pattern=dash);
referenceline y=2 / lineattrs=(pattern=dash);
endlayout;
endlayout;
endgraph;
end;
run;
proc sgrender data=GTL_GS_LFT_Lattice2 template=Fig_5_5_2_LFT_Lattice;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

76楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-13 17:20:19

Most Frequent On-Therapy Adverse Events by Relative Risk

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Most Frequent On-Therapy Adverse Events by Relative Risk
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
/*--Fig_5_5_3 Most Frequend AE--*/
data GTL_GS_AE;
input ae $1-30 a b low mean high;
label a='Percent';
label b='Percent';
datalines;
ARTHRALGIA 1 3 1 7 48
NAUSIA 4 18 2 4 8
ANOREXIA 2 3 0.9 3.8 16
HEMATURIA 2 4 0.8 3.2 15
INSOMNIA 3 5.5 1.1 3.0 7
VOMITING 3.5 6 1.2 2.5 6
DYSPEPSIA 4 10 1.1 2.4 4.5
HEADACHE 7 10 0.8 1.1 2
BACK PAIN 5 6 0.8 1.04 2
COUGHING 8 8 0.5 1.0 2
MYALGEA 4 4 0.4 1.0 1.9
MELENA 4.5 4 0.4 0.9 2.2
RHINITIS 7 6 0.4 0.9 1.9
BRONCHITIS 5 3.5 0.3 0.7 2
CHEST PAIN 6 4 0.3 0.8 1.8
DYSPNEA 7 2.5 0.13 0.3 0.7
;
run;
proc sort data=GTL_GS_AE out=GTL_GS_AE;
by mean;
run;
data GTL_GS_AE_Ref;
set GTL_GS_AE;
if mod(_n_, 2) ne 0 then refae=ae;
run;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Most Frequent On-Therapy Adverse Events by Relative Risk*/
proc template;
define statgraph Fig_5_5_1_MostFreqAE;
begingraph / designwidth=8in designheight=4in;
entrytitle "Most Frequent On-Therapy AE Sorted by Relative Risk";
layout lattice / columns=2 rowdatarange=union;
rowaxes;
rowaxis / display=(ticks tickvalues line)
tickvalueattrs=(size=7);
endrowaxes;
layout overlay / xaxisopts=(displaysecondary=(ticks)
tickvalueattrs=(size=7) linearopts=(thresholdmax=1));
referenceline y=refae / lineattrs=(thickness=14)
datatransparency=0.8;
scatterplot x=a y=ae / name='a' legendlabel='Drug A (N=216)'
markerattrs=graphdata1(symbol=circlefilled size=10);
scatterplot x=b y=ae / name='b' legendlabel='Drug B (N=431)'
markerattrs=graphdata2(symbol=trianglefilled size=10);
discretelegend 'a' 'b' / border=false valueattrs=(size=5);
endlayout;
layout overlay / xaxisopts=(label='Relative Risk with 95% CL'
displaysecondary=(ticks) tickvalueattrs=(size=7)
type=log logopts=(base=2 viewmin=0.125 viewmax=64
tickintervalstyle=logexpand));
referenceline y=refae / lineattrs=(thickness=16)
datatransparency=0.8;
scatterplot x=mean y=ae / xerrorlower=low xerrorupper=high
markerattrs=(symbol=circlefilled size=10);
referenceline x=1 /
lineattrs=graphdatadefault(pattern=shortdash);
endlayout;
endlayout;
endgraph;
end; run;
proc sgrender data=GTL_GS_AE_Ref(obs=10) template=Fig_5_5_1_MostFreqAE;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

77楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-14 09:29:36

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Common Axis Features
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
/*--Fig_6_2_1 Common Axis Opts--*/
proc means data=sashelp.cars noprint;
class type;
var mpg_city;
output out=CarsMeanMileage
n=N
mean=Mean
median=Median;
run;
data GTL_GS_Cars;
format mean median 4.1;
set sashelp.cars CarsMeanMileage(where=(_type_ eq 1)
rename=(type=TypeMean));
if(typemean ne 'Hybrid');
if(type ne 'Hybrid');
NLabel='N'; meanLabel='Mean'; medianLabel='Median';
run;
/*proc print data=GTL_GS_Cars;run;*/
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Common Axis Features*/
proc template; /*--SAS 9.4--*/
define statgraph Fig_6_2_1;
begingraph / subpixel=on;
entrytitle 'Mileage by Type';
layout overlay / xaxisopts=(display=(ticks tickvalues))
yaxisopts=(label='Mean Mileage' griddisplay=on
offsetmin=0.25 labelposition=datacenter)
y2axisopts=(offsetmin=0.05 offsetmax=0.8
display=(ticks tickvalues));
barchart x=type y=mpg_city / stat=mean dataskin=sheen;
scatterplot x=typemean y=NLabel / markercharacter=n
labelstrip=true yaxis=y2;
scatterplot x=typemean y=meanLabel / markercharacter=mean
labelstrip=true yaxis=y2;
scatterplot x=typemean y=medianLabel / markercharacter=median
labelstrip=true yaxis=y2;
endlayout;
endgraph;
end;
run;
ods listing style=analysis;
proc sgrender template=Fig_6_2_1 data=GTL_GS_Cars;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

78楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-14 09:36:06

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Linear Axis Features
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
/*--Fig_6_2_1 Common Axis Opts--*/
proc means data=sashelp.cars noprint;
class type;
var mpg_city;
output out=CarsMeanMileage
n=N
mean=Mean
median=Median;
run;
data GTL_GS_Cars;
format mean median 4.1;
set sashelp.cars CarsMeanMileage(where=(_type_ eq 1)
rename=(type=TypeMean));
if(typemean ne 'Hybrid');
if(type ne 'Hybrid');
NLabel='N'; meanLabel='Mean'; medianLabel='Median';
run;
/*proc print data=GTL_GS_Cars;run;*/
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Linear Axis Features*/
proc template;
define statgraph Fig_6_2_2;
begingraph;
entrytitle 'Mileage by Horsepower';
layout overlay / xaxisopts=(griddisplay=on
linearopts=(tickvaluelist=(150 200 250 300 350)))
yaxisopts=(griddisplay=on
linearopts=(tickvaluepriority=true/*指定的tickvalue优先*/
tickvaluesequence=(start=0 end=50 increment=10)));
scatterplot x=horsepower y=mpg_city;
endlayout;
endgraph;
end;
run;
ods listing style=htmlblue;
proc sgrender template=Fig_6_2_2 data=GTL_GS_Cars;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

79楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-14 09:45:21

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Discrete Axis Features
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Discrete Axis Features*/
proc template; /*--SAS 9.4--*/
define statgraph Fig_6_2_3;
begingraph / subpixel=on;
entrytitle 'Mean Mileage by Make';
layout overlay / xaxisopts=(display=(tickvalues)
discreteopts=(tickvaluefitpolicy=split
tickvaluelist=('Acura' 'Audi' 'BMW' 'Lexus' 'Mercedes-Benz' 'Porsche')
tickdisplaylist=('Acura' 'Audi' 'BMW' 'Lexus' 'Mercedes Benz' 'Porsche')));
barchart x=make y=mpg_city / stat=mean dataskin=crisp
barlabel=true;
endlayout;
endgraph;
end;
run;
ods listing style=htmlblue;
proc sgrender template=Fig_6_2_3
data=sashelp.cars(where=(msrp > 60000));
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

80楼

l1i2n3i4n5g(未真实交易用户)

发表于 2018-3-14 09:51:04

%macro comment(); /*这是一种比较特殊的注释方式*/
Picture: Log Axis Features
(using template and sgrender procedure)
Software： SAS 9.4 TS Level 1M2
Name: justsoso
Date: 20180305
From: Getting Started with the Graph Template Language in SAS:
Examples, Tips, and Techniques for Creating Custom Graphs
History: 20180305;
%mend;
ods _all_ close; /*关闭所有ods destinations，避免不必要的输出，节省计算机资源*/
/*ods listing gpath='C:\Users\Administrator\Desktop\test20180305' image_dpi=300;*/
ods listing gpath='C:\Users\Administrator\Desktop\test20180305';
/*打开ods listing这一destination，指定图片保存路径，★★★★★需提前建立*/
/*ods graphics on / imagename="picture" outputfmt=pdf;*/
/*图片名称picture，输出类型pdf*/
ods graphics off;
/*Log Axis Features*/
proc template;
define statgraph Fig_6_2_4;
begingraph;
entrytitle 'MSRP by Horsepower';
layout overlay / xaxisopts=(type=log griddisplay=on
logopts=(base=2 tickintervalstyle=linear))
yaxisopts=(griddisplay=on
linearopts=(tickvaluepriority=true
tickvaluelist=(10000 50000 100000 200000)));
scatterplot x=horsepower y=msrp;
endlayout;
endgraph;
end;
run;
ods listing style=htmlblue;
proc sgrender template=Fig_6_2_4 data=sashelp.cars;
run;
ods _all_ close;
/*ods html; 最好将ods destination恢复至默认的html*/

复制代码

[学习分享] 如何用SAS画统计图，这是我的学习分享！ [推广有奖]

浏览过的帖子

浏览过的版块

本版微信群