编写无放回取数程序

请高手编写如下程序:从1-100个整数中随机无放回取20个数字.要求用SAS来编写.

额 不要钱了友情赠送了

data a;
do x=1 to 100;
output;
end;
run;
proc sql;                                                                     
    create view temp as                                                
       select *, RANUNI(0) as _ran_ from a                              
    order by calculated _ran_;                                                
quit;                                                                        
data aa1;                                                            
    set temp(obs = 100);                                                  
    drop _ran_;                                                               
run;
data _null_;
set aa1 end=a;
if a=1 then call symput('total',ceil(_n_/20));
run;
%macro test;
%do i=0 %to %eval(&total);
data out&i;
set aa1 ;
if  (_n_>20*&i and _n_<=20*(&i+1)) then output out&i;
%end;
proc sql;drop table out%eval(&total),a,aa1;quit;
%mend;
%test;

Splus or R:sample(100,20)
最简单

人家要的是SAS哦

是啊,高手帮忙啊

是一个数据集,是从1-100中随机选20个就行了,无放回,

额 不要钱了 友情赠送了
data a;
do x=1 to 100;
output;
end;
run;
proc sql;                                                                     
    create view temp as                                                
       select *, RANUNI(0) as _ran_ from a                              
    order by calculated _ran_;                                                
quit;                                                                        
data aa1;                                                            
    set temp(obs = 20);                                                  
    drop _ran_;                                                               
run;

谢谢,我怎么把100币给你呢

1# harlon1976

Here is an faster way to a random sample without replacement.

data t1;
   do i = 1 to 100;
      output;
   end;
run;

%let size=20;

data t2;
   set t1 nobs=nobs;
   if _n_=1 then do;
       _n=nobs;size=&size;
   end;
   if ranuni(-1) <=size/_n then do;
      size+(-1);
      output;
  end;
  _n+(-1);
  if size=0 then stop;
run;

proc print ;run;

The best and easy way is to use proc surveyselect. Here is the code. Method=srs specifies simple random sampling as the sample selection method. There are more options for different sampling methods that can be found from sas documents.  

proc surveyselect data=a
      method=srs n=20
      out=b;
   run;