SAS 制作频数表（SOC/PT表格）

各位老师好，我问一下使用SAS制作table的问题（临床试验AE表格制作）
我的原始数据代码为：
data ae;
input soc:$20. pt $ level $ n;
cards;
感染及侵入类疾病 瘙痒 1级 5
感染及侵入类疾病 瘙痒 2级 5
感染及侵入类疾病 瘙痒 3级 2
感染及侵入类疾病 瘙痒 4级 3
感染及侵入类疾病 瘙痒 5级 5
感染及侵入类疾病 湿疹 1级 5
感染及侵入类疾病 湿疹 2级 5
感染及侵入类疾病 湿疹 3级 5
感染及侵入类疾病 湿疹 4级 2
感染及侵入类疾病 湿疹 5级 3
;
run;
我想得到如下的结果的表格，如何将soc pt level 三个变量 放到一个变量下？以及如何总数的计算：如瘙痒是20，湿疹是20，

  

感染及侵入类疾病是40。

SOC	例次
感染及侵入类疾病	40
瘙痒	20
1级	5
2级	5
3级	2
4级	3
5级	5
湿疹	20
1级	5
2级	5
3级	2
4级	3
5级	5

两个方案，第一个简单点，但soc pt level 三个变量不在一列；第二个方案多几个步骤，不知道别人能不能提供更简洁的步骤。

方案一：
proc report data=ae missing;
        column soc pt level n;
                        define soc/group;
                        define pt/group;
                        define level/group;
                        define n/analysis sum '例次';
                break before pt/summarize style=[backgroundcolor=#DBEEF4 color=blue];
        break before soc/summarize style=[backgroundcolor=#FFF2CC color=red fontweight=bold];
        title 'xxxx';
run;

方案二：
proc report data=ae missing;
        column soc pt level n;
                        define soc/group;
                        define pt/group;
                        define level/group;
                        define n/analysis sum '例次';
                break before pt/summarize;
        break before soc/summarize;
        ods output report=work.aaa;
        title 'xxxx';
run;
data work.aaa;
        retain var n;
        set aaa;
                array varlist[*] $ soc pt level;
                        do i=1 to dim(varlist) by 1;
                                if missing(varlist[i])=0 then var=varlist[i];
                        end;
                keep var n;
run;
proc print data=work.aaa;run;

zdl1225 发表于 2020-4-1 14:29
两个方案，第一个简单点，但soc pt level 三个变量不在一列；第二个方案多几个步骤，不知道别人能不能提供更 ...

谢谢！方案二帮上大忙了。老师，我想再问一下，实际过程中level并不会都是5级，如何标准化？
代码如下：
data ae;
input soc:$20. pt $ level $ n;
cards;
感染及侵入类疾病 瘙痒 1级 5
感染及侵入类疾病 湿疹 2级 5
感染及侵入类疾病 湿疹 3级 5
胃肠道疾病 呕吐 3级 1
胃肠道疾病 腹泻 1级 2
;
run;

目标结果：

soc	pt	level	n
感染及侵入类疾病	瘙痒	1级	5
感染及侵入类疾病	瘙痒	2级	0
感染及侵入类疾病	瘙痒	3级	0
感染及侵入类疾病	瘙痒	4级	0
感染及侵入类疾病	瘙痒	5级	0
感染及侵入类疾病	湿疹	1级	0
感染及侵入类疾病	湿疹	2级	5
感染及侵入类疾病	湿疹	3级	5
感染及侵入类疾病	湿疹	4级	0
感染及侵入类疾病	湿疹	5级	0
胃肠道疾病	呕吐	1级	0
胃肠道疾病	呕吐	2级	0
胃肠道疾病	呕吐	3级	1
胃肠道疾病	呕吐	4级	0
胃肠道疾病	呕吐	5级	0
胃肠道疾病	腹泻	1级	2
胃肠道疾病	腹泻	2级	0
胃肠道疾病	腹泻	3级	0
胃肠道疾病	腹泻	4级	0
胃肠道疾病	腹泻	5级	0

hmh3226@163.com 发表于 2020-4-1 22:25
谢谢！方案二帮上大忙了。老师，我想再问一下，实际过程中level并不会都是5级，如何标准化？
代码如下： ...

回答你第二个问题：方法可能原始了一点，没有高级的语法，供参考。

data work.aaa;
input soc: $20. pt $  level $ n;/*这一行发帖子后，SOC和pt后面的s符号显示有问题*/
cards;
感染及侵入类疾病 瘙痒 1级 5
感染及侵入类疾病 瘙痒 2级 5
感染及侵入类疾病 瘙痒 3级 2
感染及侵入类疾病 瘙痒 4级 3
感染及侵入类疾病 瘙痒 5级 5
感染及侵入类疾病 湿疹 1级 5
感染及侵入类疾病 湿疹 2级 5
感染及侵入类疾病 湿疹 3级 5
感染及侵入类疾病 湿疹 5级 3
胃肠道疾病 呕吐 3级 1
胃肠道疾病 呕吐 2级 5
胃肠道疾病 腹泻 1级 2
;
run;
data work.bbb;
n=0;
        do pt='瘙痒', '湿疹';
                        do level='1级', '2级', '3级', '4级', '5级';
                                soc='感染及侵入类疾病';
                                output;
                        end;
                output;        
        end;
        do pt='呕吐', '腹泻';
                        do level='1级', '2级', '3级', '4级', '5级';
                                soc='胃肠道疾病';
                                output;
                        end;
                output;
        end;
run;
data work.ccc;
        set work.aaa work.bbb;/*原始数据放前面，补充数据放后面*/
run;
proc sort data=work.ccc out=work.ddd nodupkey; by soc pt level; run;

zdl1225 发表于 2020-4-2 14:39
回答你第二个问题：方法可能原始了一点，没有高级的语法，供参考。

data work.aaa;

谢谢！