请问如何一次性改变变量的名称？

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

请问如何将一个数据里的所有变量（上百个）： a， b， c， d， e， ...
一次全变成有规律的：例如：a1，a2,  a3,  a4,  a5,  ...

感谢您的赐教！

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏1 回帖

关键词：一次性 如何

data crackman;
input a b c d e f@@;
datalines;
1 2 3 4 5 6
4 6 7 8 9 9
9 8 7 6 5 4
;
run;
proc contents data=crackman out=a(keep=name) noprint;
run;
data _null_;
set a;
call symput('a'||left(_n_),trim(name));
run;
proc sql noprint;
select count(name) as n into:n from a ;
quit;
%macro rename;
data crackman;
set crackman;
rename
%do i=1 %to &n.;
&&a&i.=a&i.
%end; ;
run;
%mend rename;
%rename;

data crackman;
input a b c d e f@@;
datalines;
1 2 3 4 5 6
4 6 7 8 9 9
9 8 7 6 5 4
;
run;
proc contents data=crackman out=a(keep=name) noprint varnum;
run;
data _null_;
set a end=last;
if _n_=1 then  call execute("Proc datasets nolist; modify crackman; rename ");
call execute(" "||strip(name)||"=a"||strip(_n_));
if last then call execute("; run; quit;");
run;

3# pobel
谢谢这位高人的热心帮助！

2# crackman
多谢多谢！！学到了很多！

data a1;
input  a b c d @;
cards;
1        1  1  1
;
run;
proc contents data=a1 out=a2(keep=name type);
run;
data a3;
set a2;
new_name="name"||left(_n_);
run;
proc sql;
select trim(name)||"="||new_name  into: change_name SEPARATED BY " "
from a3;
quit;
%put &change_name.;
data final;
set a1;
rename &change_name.;
run;
有点小复杂 我写的

6# xiaoxiahu0571
谢谢！！大家都好厉害啊~

Valen860108 发表于 2010-8-30 00:02
请问如何将一个数据里的所有变量（上百个）： a， b， c， d， e， ...
一次全变成有规律的：例如：a1，a2,  a3,  a4,  a5,  ...

感谢您的赐教！

LZ,下面有一个偶认为更为简洁的程序，供参考：

data a;
input a b c d e f;
datalines;
1 2 3 4 5 6
;
proc transpose data=a out=b prefix=x;
proc transpose data=b out=b prefix=x;
data c(drop=_name_);
  set b;
proc print;
run;


下面是程序运行的结果：

                                         The SAS System      

                             Obs    x1    x2    x3    x4    x5    x6
                              1      1     2     3     4     5     6

3# pobel

谢谢，还请多多指教！