[原创博文] 用什么方法可以估计数据的概率密度函数 [推广有奖]

你可以先判断是否服从正态分布，然后计算出均值和方差，再代入公式求解

正态分布是最简单的情况，如果是伽马分布，K分布，对数正态等呢？

貌似SAS没有现成的proc，你要自己编程实现

4# honghejing 那也太悲剧了

Here is an example to estimate ditribution parameters by maximizing log-likehood. The sample data is Laplace ditribution.

data t1;
    mu=10; b=1;
   do i=1 to 1500;
      U=ranuni(998)-0.5;
      x=mu - b*sign(u)*log(1-2*abs(u));
   output;
end;
KEEP X;
run;
proc univariate data=t1 noprint;
histogram x/normal;
inset n mean std skewness kurtosis;
run;
proc univariate data=t1 noprint;
histogram x/gamma;
inset n mean std skewness kurtosis;
run;
proc nlmixed data=t1;
parms a=1 b=2;
loglik=log(pdf('laplace', x, a, b));
MODEL X ~ GENERAL (loglik);
RUN;

6# bobguy 谢谢!

学习一下，关于概率密度函数我是一点都不懂，但是最近要用

It needs to use likelihood estimation. Many SAS procedures can do it.

Here is an example for gamma distribution with shape=7 and scale=2.

data gamma;
a=7;  s=2; seed=123;
CALL STREAMINIT(seed);
do i=1 to 1000;
   x= s*RAND('GAMMA',a) ;
   output;
end;
keep x;
run;


proc nlmixed data=gamma;
parms a=1  lamda=1;
p=PDF('GAMMA',x,a,lamda ) ;
ll=log(p);
model x ~general(ll);
run;