SAS导入文件夹所有excel数据的问题

我需要将一个文件夹中的excel全部导入到sas中，目前写了一个代码，把所有的路径都读取到sas数据中了，怎么根据sas数据中的路径实现数据的导入？
这个是读取文件路径的代码，保存到了filename中，是这样的，现在就是怎么利用这个数据，把这些数据导入到sas中？

%let path=C:\重要资料\2025\word;

filename temp pipe "dir ""&path.\*.xlsx"" /b";

data file_combine1;
  infile temp truncover;
  input path $100.;
run;

%let slash=%sysfunc(ifc(%index(&sysscp.,WIN),\,/));

data filename;
  length filenum 8 filepath $100.;
  dirref=filename('_dummy1_',"&path.");
  dirrc=dopen('_dummy1_');
  if dirrc then do;
    do filenum=1 to dnum(dirrc);
      filepath="&path.&slash."||dread(dirrc,filenum);
      if upcase(scan(filepath,-1,'.'))^="XLSX" then continue;

      *Ensure file can be accessed;
      filref=filename('_dummy2_',trim(filepath));
      filrc=fopen('_dummy2_');
      if filrc then do;
        filrc=fclose(filrc);
        output;
      end;

    end;
    dirrc=dclose(dirrc);
  end;
  keep filenum filepath;
run;

将filename做成一系列宏变量，宏程序里进行循环，%do ii=1 %to &max;

fp是filepath，dn是output出的sas数据集名称。

%let dirpath=d:\new;
filename temp pipe "dir ""&dirpath.\*.xlsx"" /b";
data a;
        infile temp truncover;
        input path $200.;
        fp="&dirpath.\"||strip(path);
        dn="i"||strip(_n_);
run;
data a;
        set a;
        call execute("proc import datafile='"||strip(fp)||"' out="||strip(dn)||" dbms=xlsx replace;getnames=NO;run;");
run;