Generate left-truncated normal variate(rejection sampling)

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

This is a SAS provided example to generate left-truncated normal variate. It uses in MCMC procedures.

Follow the link for more details,
http://support.sas.com/documentation/cdl/en/statug/63962/HTML/default/viewer.htm#statug_mcmc_sect064.htm


options cmplib = (sasuser.funcs.temp);

proc fcmp outlib=sasuser.funcs.temp;;
   /******************************************/
   /* Generate left-truncated normal variate */
   /******************************************/
   function rltnorm(mu,sig,lwr);
   if lwr<mu then do;
      ans = lwr-1;
      do while(ans<lwr);
         ans = rand('normal',mu,sig);
      end;
   end;
   else do;
      mul = (lwr-mu)/sig;
      alpha = (mul + sqrt(mul**2 + 4))/2;
      accept=0;
      do while(accept=0);
         z = mul + rand('exponential')/alpha;
         lrho = -(z-alpha)**2/2;
         u = rand('uniform');
         lu = log(u);
         if lu <= lrho then accept=1;
      end;
      ans = sig*z + mu;
   end;
   return(ans);
   endsub;

run;

data t1;
   call streaminit(123);
   do i=1 to 10000;
      mu=0;sig=1;lwr=-1;
      x=rltnorm(mu,sig,lwr);
      output;
    end;
run;

proc print data=t1(obs=10);run;

proc univariate data=t1;
var x;
histogram  x/normal;
inset n mean std skewness kurtosis/pos=ne;
run;

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏0 回帖

关键词：truncated rejection generate Sampling Variate function generate provided details example