怎么不用排序的情况下更新数据？

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

data idwrong;
input id name $ birth;
cards;
1 张三 88
2 李四 87
4 周看 90
12 李四 85
;

data idright;
input id name $ birth;
cards;
3 李四 85
5 周看 90
;

简单来说，每个数据集的id号没有重复的，idwrong中有些id是错误的，要用idright中的正确的id来替换它，判断两个数据集中属于同一个人的标志是name和birth相同。
最后的结果应该是
1 张三 88
2 李四 87
5 周看 90
3 李四 85



怎么不对数据集sort的情况下实现上述需求？

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享0 收藏1 回帖

关键词：Birth RIGHT Input cards wrong

补充说明：
因为我的数据idwrong比较大，idright很少，所以我不想改变现有idwrong的观测顺序
下面一个代码，改变了原来idwrong的观测顺序，有没有什么办法改进？
proc sql;
create table final as
select a.*,b.id as id2 from idwrong a left join idright b
on a.name=b.name and a.birth=b.birth;
quit;
data final;
set final;
if id2^=. then id=id2;
drop id2;
run;

data idwrong;
input id name $ birth;
cards;
1 张三 88
2 李四 87
4 周看 90
12 李四 85
;

data idright;
input id name $ birth;
cards;
3 李四 85
5 周看 90
;
run;

proc sql;
create table test as
select (case when b.id is missing then a.id else b.id end ) as id ,a.name,a.birth from
idwrong a left join  idright b
on a.name=b.name and a.birth=b.birth
order by a.id;
quit;

ziyenano 发表于 2012-12-11 15:46
data idwrong;
input id name $ birth;
cards;

唉，对sql不是太熟悉，忘了order by 语句。
请问一下高手：sql选择观测的原理是什么？
为什么不用order by时观测的顺序是那样的，而不是跟第一个数据集的一致？

data wanted;
  if 0 then set idright;
   *** define Hash object;
   declare hash h(dataset:'idright');
        h.definekey('name','birth');
                h.definedata('id');
                h.definedone();

   do until(last);
      set idwrong end=last;
          _n_=h.find();
          output;
          end;
        stop;
run;

Imasasor 发表于 2012-12-11 16:06
唉，对sql不是太熟悉，忘了order by 语句。
请问一下高手：sql选择观测的原理是什么？
为什么不用order ...

根据唯一主键匹配，通常用的算法是B-Tree，
或者根据hash算法，
对B-Tree的算法我也不是很清楚~
其实很多数据库可以用基于两张表的update，
这样原数据集的顺序是不会变的，
只是SAS sql中基于两张表的update不怎么好用

pobel 发表于 2012-12-11 16:11
data wanted;
  if 0 then set idright;
   *** define Hash object;

Hash 在merge数据时，常被遗忘。虽然吃内存厉害，若是其实一个数据大，一个数据小时，用着很合适。

pobel 发表于 2012-12-11 16:11
data wanted;
  if 0 then set idright;
   *** define Hash object;

谢谢你，但是我不知道为什么你写这么多
我删了一些看不太懂的，剩下这些，也是可以的啊？
data wanted;
if _n_=1 then do;
declare hash a(dataset:'idright');
        a.definekey('name','birth');
                a.definedata('id');
                a.definedone();
                                end;
      set idwrong;
          _n_=a.find();
run;

pobel 发表于 2012-12-11 16:11
data wanted;
  if 0 then set idright;
   *** define Hash object;

请pobel大牛解释下程序

第一，其中的do until(last)，然后end=last有什么作用？
set idwrong不就是从_N_=1循环到_N_=last了吗？

第二，还有stop的作用是什么？

十分感谢！