怎么将宏变量倒转过来？

%let a=you are how;
怎么生成宏变量b变成 how are you
求助...........

方法太多了，提供两个思路
1：按一个记录读进去，然后while kscan按空格分隔输出，最后将数据库按ID倒序 输出；
2：直接按空格分别读进去，然后倒序输出；

大概写了下，仅作参考

    data demo(drop=words);
    infile datalines dlm=",";
    length words $ 100;
    input  words $;
     i=1;
    do while (kscan(words,i,' ' )^='');
       word=kscan(words,i,' ');
      output;
       i+1;
    end;
    datalines;
    how are you now  fine
    ;

    proc sort data=demo  out=want (keep=word);
       by descending i;
    run;

%macro inverse;
%let name=you are how;
%let i=1;
%let var=1;
%do %while(&var^=);
%let var=%scan(&name,&i);
%if &i=1 %then %do;
%let name1=;
%end;
%let name1=&var　&name1  ;
%let i=%eval(&i+1);
%end;
%put &name1;
%mend;

%inverse

怎么把悬赏赏给自己，还有没有很简单的方法？

简单查了下，SAS的REVERSE函数只能反字母，不能反单词，变通了下，效率应该还可以

%macro ReverseString(InputString,OutputString);

%let InputString_Temp=%SYSFUNC(REVERSE(&InputString));
%let &OutputString=;

%do i=1 %to %EVAL(%SYSFUNC(COUNT(&InputString,%STR( )))+1);
        %let &OutputString=&&&OutputString. %SYSFUNC(REVERSE(%SCAN(&InputString_Temp,&i)));
%end;

%mend;

%let InputString=you are how;
%let OutputString=a;
%ReverseString(&InputString,&OutputString);

%put &a;

countw是个非常好用的函数

Try this:

%let a=you are how;
%put &a;

data b;
format d $100.;
k=countw("&a");
do i=1 to k;
   c=" "||scan("&a",-i," ");
   d=catt(d,c);
end;
run;

proc sql;
  select d into :reverse from b;
quit;

%put &reverse;

Here is a little clear version.

%macro inverse(varlist=you are how);

%let n= %eval(%sysfunc(countc(%cmpres(&varlist),%str( )))+ (%length(&varlist) gt 0) );
%let name1=;
%do i=&n %to 1 %by -1;
        %let name1=&name1 %scan(&varlist,&i) ;
%end;
&name1;
%mend;

%let rev_var=%inverse(varlist=you are how);

%put <varlist=you are how> <rev_var=&rev_var>;