SAS能自己编写函数么?

是 否 +2 论坛币

k人 参与回答

经管之家送您一份

应届毕业生专属福利!

求职就业群

赵安豆老师微信：zhaoandou666

经管之家联合CDA

送您一个全额奖学金名额~ !

立即领取

感谢您参与论坛问题回答

经管之家送您两个论坛币！

+2 论坛币

偶然情况下载help里面看到的一个过程步proc fcmp;就到网上查了些资料，原来SAS也可以编写自己的function并调用，可以使复杂的函数瞬间变简单有木有！！！

1. proc fcmp outlib=function.funcsol.conversion
   
2.   function change(lb);
   
3.   kg=lb/2.2;
   
4.   return (kg);
   
5.   endsub;
   
6.   run;

复制代码

恭喜大家，这样已经定义了一个属于你自己的函数了，名字叫做change，储存在function.funcsol.conversion 里面；需要注意的是储存的文件夹，也就是function.funcsol.conversion 一定是由三个目录组成的，WHY？
大家可以定义了这个函数之后自己去打开文件看一下，首先是主文件夹function（相当于work）, 然后是funcsol（相当于数据集）,
而conversion就相当于数据集里的索引了，我个人觉得SAS储存函数还是与储存数据是一样的，把编译了的函数储存在数据集里相当于，个人理解，希望大神指正，这样想便于理解嘛；

语法方面并不是很复杂，我就随便说一下；
相当于do循环有end;
function 有 endsub;如果大家会VB的话，对sub肯定不陌生吧？打VBA天天打有木有~~~
剩下的就简单了，定义一个变量，计算，然后返回计算出来的值，函数结束；


接下来就和format一样，（或者是matlab里面的path），你要告诉SAS到哪里去找你定义的函数;

1. options cmplib=(function.funcsol);

复制代码

OK, 这样子SAS应该已经知道到哪里去找了；
接下来试一下效果：

1. data a;
   
2. set sashelp.class(keep=name age weight);
   
3. kilos=change(weight);
   
4. run;

复制代码

这样我们就成功的调用了自己定义的函数；

最简单的例子就是这样了，接下来是进阶教程：

1. proc fcmp outlib=function.funcsol.conversions;
   
2.         function lb2kgc(lb) $;
   
3.                 length kg $10;
   
4.                 kg = catt(put((lb/2.2),6.2),'kg');
   
5.                 return (kg);
   
6.         endsub;
   
7. run;

复制代码

这个是什么？和前面不同的只有一点，就是return的不是一个数值型变量而是一个字符型变量；
SO，和定义变量一样，加一个 $ 就好；
其他的语法都是一样的，只是一个catt的连接函数而已；

1. options cmplib=(function.funcsol);
   
2. 
   
3. data b;
   
4.         set sashelp.class(keep=name age weight);
   
5.         kilos=change(weight);
   
6.         kg_c=lb2kgc(weight);
   
7. run;

复制代码

一样的，试一下；

1. proc fcmp outlib=function.funcsol.conversions;
   
2.         function bmi(lb,ht);
   
3.                 return((lb*703)/(ht*ht));
   
4.         endsub;
   
5.         run;
   
6. 
   
7. options cmplib=(function.funcsol);
   
8. 
   
9. data bmi;
   
10. set sashelp.class(keep=name age weight height);
    
11. bmi=bmi(weight,height);
    
12. run;

复制代码

OK，两个自变量，right?


接下来两个例子我觉得写得爆赞，可以一窥函数定义的妙处所在；

1. proc fcmp outlib=function.funcsol.conversions;
   
2.         subroutine biomassindex(w,h,b);
   
3.                 outargs b;
   
4.                 b= ((w*703)/(h*h));
   
5.         endsub;
   
6.         run;
   
7. 
   
8. options cmplib=(function.funcsol);
   
9. 
   
10. data bmi;
    
11.         set sashelp.class(keep=name age weight height);
    
12.         bmindex=.;
    
13.         call biomassindex(weight,height,bmindex);
    
14. run;

复制代码

几个重要一点的point；
1、 subroutine 这里可以把自变量和return值放在一起；然后通过 outargs来确定输出值是哪一个；看看例子大家一定会明白吧，所以用一个 call function 就可以完成对输出值的赋值；

1. proc fcmp outlib=function.funcsol.conversions;
   
2.         function fromto(code $,v);
   
3.                 if upcase(code)='LB2KG' then r=V/2.2;
   
4.                 else if upcase(code)='KG2LB' then r=v*2.2;
   
5.                 else r=.;
   
6.                 return (r);
   
7.         endsub;
   
8.         run;
   
9. 
   
10. option cmplib=(function.funcsol);
    
11. 
    
12. data conv;
    
13.         set sashelp.class(keep=name age weight);
    
14.         kilos=fromto('lb2kg',weight);
    
15.         pounds=fromto('kg2lb',kilos);
    
16.         run;

复制代码

没有错，函数里面是可以用逻辑语句的，想怎么编就怎么编，接下来大家可能会想怎么样才能够做的更复杂，接下来的例子就是在函数里引入macro， macro本来就是为了使语句更加简化而生的，碰上个一样目的的函数过程步，不能再简化了有木有~~

1. %macro printit();
   
2. %put &lib &dsn;
   
3.         %let lib = %sysfunc(dequote(&lib));
   
4.         %let dsn = %sysfunc(dequote(&dsn));
   
5.         %let num = %sysfunc(dequote(&num));
   
6.         %if &num = %then %let num=max;
   
7.         title2 "&lib..&dsn";
   
8.         title3 "first &num observations";
   
9.         proc print data=&lib..&dsn(obs=&num);
   
10.                 run;
    
11. %mend printit;
    
12. 
    
13. proc fcmp outlib=function.funcsol.utilities;
    
14.         subroutine printN(lib $, dsn $, num);
    
15.                 rc=run_macro('printit',lib,dsn,num);
    
16.         endsub;
    
17.         run;

复制代码

这里有一个错误使用macro的误区，我来说说我的看法吧，如果你在fcmp里面使用%macro来调用宏的话，就会存在一个编译错误的问题，具体的机制我也不甚清楚，但是可以肯定的是，这样子的宏是没法编译的，因为编译函数我觉得可能在编译宏之前，那样函数的编译就会出错；

所以使用run_macro ('printit',...);
来输入宏和宏变量；

剩下两个例子我个人觉得有点鸡肋，不过用处还是有的，如果你想定义非常复杂的format的话，这个还是有用的吧；

1. proc format;
   
2.         value pounds2kg
   
3.                 other=[change()];
   
4.         run;
   
5. 
   
6. options cmplib=(function.funcsol);
   
7. 
   
8. title2 'Weight in Kg';
   
9. proc print data=sashelp.class;
   
10.         var name age weight;
    
11.         format weight pounds2kg.;
    
12.         run;

复制代码

大家看到了，就是起到了一个定义format里面格式的作用，把所有的格式都定义为change里面的return值，但是数据集里的值是不变的；

当然，fcmp是可以输出多个值得，用subroutine就好了不是么？

1. proc fcmp outlib=function.funcsol.conversions;
   
2.         subroutine metric_hwbmi(h,w,mh,mw,bmi);
   
3.                 outargs mh,mw,bmi;
   
4.                 mh = h*.0254;
   
5.                 mw = w*.4536;
   
6.                 bmi = mw/(mh*mh);
   
7.         endsub;
   
8.         run;
   
9. 
   
10. options cmplib = (function.funcsol);
    
11. 
    
12. data multiple;
    
13.         set sashelp.class(keep=name age height weight);
    
14.         heightmeters=.;
    
15.         weightkilos=.;
    
16.         bmi=.;
    
17.         call metric_hwbmi(height,weight,heightmeters,weightkilos,bmi);
    
18.         run;

复制代码

%sysfunc 和 %call，能调用普通函数的工具当然也能调用我们定义的函数；

1. options cmplib=(function.funcsol);
   
2. 
   
3. %let ht = 69;
   
4. %let wt = 112.5;
   
5. %let bmi = %sysfunc(bmi(&wt,&ht));
   
6. %put &bmi;

复制代码

最后一点，定义的函数怎么去除，easy, delete 掉就好（deletefunc）

1. proc fcmp outlib=function.funcsol.conversions;
   
2.         deletefunc lb2kgc;
   
3.         deletefunc biomassindex;
   
4.         run;

复制代码

定义了的函数可以一直调用而且也可以给别人使用；
但是根据我自己的试验，这个因为是储存成字符，英文版和中文版定义的函数是不能通用的哦~~~~希望大家能把自己的code写的越来越简单，越来越漂亮~~~~

翻译自：https://bbs.pinggu.org/thread-3102197-1-1.html ——Arthur:L.Carpenter（希望我理解的木有错）

扫码加我 拉你入群

请注明：姓名-公司-职位

以便审核进群资格，未注明则拒绝

分享1 收藏17 回帖

关键词：observations observation conversion Utilities Carpenter function change return 文件夹 网上

第一次知道还有这个功能，谢谢分享

哇，这个好

好东西,感谢分享~~~

正需要，非常感谢

你好~请问索引要事先建立好吗？如果别人要用我的函数，那逻辑库数据集索引是不是也要改成别人SAS里的？重新启动SAS要重新定义函数吗？

多谢指点！

点赞，用这个求BS隐含波动率妥妥的

谢谢分享 厉害

这是在干嘛？