数据排列结构的转换

我有个数据需要转换 结构但是自己编了一下，总是不能得到自己想要的结果，求大神指教！
具体的情况是：

1.原来的数据结构：

date	ptvb1	ri1	mv1	ptvb2	ri2	mv2	ptvb3	ri3	mv3
1979-12-31		78.6	1630.38		124.28	1668.97		43.84	319.78
1980-1-31	0.3	76.63	1579.98		125.88	1678.95	0.31	44.19	322.3
1980-2-29	0.28	71.06	1454.56		122.73	1626.75	0.32	44.76	326.5
1980-3-31	0.25	65.51	1330.1		115.23	1515.1	0.29	40.85	297.96
1980-4-30	0.28	72.23	1454.72		126.81	1653.08	0.3	42.52	310.13
1980-5-30	0.27	70.5	1408.04		121.92	1575.92	0.31	43.76	316.84
1980-6-30	0.26	68.72	1361.4		132.51	1699.38	0.3	43.18	310.13
1980-7-31	0.29	76.45	1501.43		138.37	1760.2	0.31	44.7	318.1

2.我想要的结构：

我想得到的结构是：五列数据，上面的ptvb(ri  mv)后面的数字表示 公司的 代码（firm id），并且这个数字就顺序编码的，中间不会有中断 跳跃的 情况。

firm_Id      date             ptvb        ri         mv

1            1979-12-31      .           78.6    1630.38

省略其他时间的值

2          1979-12-31         .         124.28  1668.97  

请大神 下载 实验数据 test.xls,  转化为 CSV 后导入 SAS, 导入的程序也粘贴上了。
谢谢大神的指导。。。跪谢！！！！！！！！

1. PROC IMPORT OUT=A
   
2.             DATAFILE= "D:\test.csv"
   
3.             DBMS=CSV REPLACE;
   
4.     GETNAMES=YES;
   
5. RUN;

复制代码

1. * in the imported dataset, only ID 1, 3, 6 are numeric data;
   
2. * other IDs contain character variables, you need to change these to numeric data
   
3. * The ID generated by the following code are not correct;
   
4. 
   
5. data want;
   
6.     set test;
   
7.       array prm{3,3} ptvb1 ri1 mv1
   
8.                   /* ptvb2 ri2 mv2 */
   
9.                      ptvb3 ri3 mv3
   
10.                   /* ptvb4 ri4 mv4 */
    
11.                   /* ptvb5 ri5 mv5 */
    
12.                      ptvb6 ri6 mv6;
    
13.       do I = 1 to 3;
    
14.          id = i;
    
15.        ptvm = prm[i,1];
    
16.          ri = prm[i,2];
    
17.          mv = prm[i,3]; output;
    
18.         end;
    
19.     keep id date_ ptvm ri mv;
    
20. run;

复制代码

*easy question! i think . Try the following method;

PROC IMPORT  DATAFILE= "d:\test.xls"  DBMS= xls REPLACE  OUT=test;
    SHEET= test;
    GETNAMES=YES;
    GUESSINGROWs=32767;
RUN;
data test2;
  set test;
  array ptvb_a ptvb1-ptvb6;
  array ri_a ri1-ri6;
  array mv_a mv1-mv6;
  do firm_Id = 1 to 6;
   ptvb= ptvb_a[firm_Id];
   ri= ri_a[firm_Id];
   mv= mv_a[firm_Id];
   output;
  end;
  keep firm_Id date ptvb ri mv;
run;

1. data _null_;
   
2.     set a(firstobs=1 obs=6) end=eot;
   
3.     num=strip(put(_n_,best.));
   
4.     if _n_=1 then call execute('data want(keep=firm_id date ptvb ri mv); length firm_id 8; set');
   
5.     call execute('a(rename=(ptvb'||num||'=ptvb ri'||num||'=ri mv'||num||'=mv))');
   
6.     if eot then call execute('; by date; firm_id=_n_ ; run;');
   
7. run;

复制代码

我给你一个笨方法，不用数组就可以实现你的目的，而且易懂：

1. proc import
   
2.                         datafile = "C:\Documents and Settings\Administrator\桌面\test.xls"
   
3.                         out = test
   
4.                         dbms = xls replace;
   
5.                 sheet = "test";
   
6. run;
   
7. %macro test(dataset = );
   
8.         %let i = 1;
   
9.         %do i = 1 %to 6 ;
   
10.                 data &&dataset.&i.(label = no);
    
11.                         set &dataset.(keep = DATE_AND_SETTINGS_ADMINISTRATOR_ PTVB&i. RI&i. MV&i.
    
12.                                                 rename = (DATE_AND_SETTINGS_ADMINISTRATOR_ = date
    
13.                                                         PTVB&i. = PTVB
    
14.                                                         RI&i. = RI
    
15.                                                         MV&i. = MV
    
16.                                                         ));
    
17.                         firm_id = &i.;
    
18.                         i = i + 1;
    
19.                         drop i;
    
20.                 run;
    
21.         %end;
    
22. %mend;
    
23. %test(dataset = test);
    
24. 
    
25. data test_all(label = no);
    
26. retain firm_id date ptvb ri mv ;
    
27.         merge test1 test2 test3 test4 test5 test6 ;
    
28.         by firm_id;
    
29.         label ptvb = ptvb
    
30.                   ri = ri
    
31.                   mv = mv
    
32.                   ;
    
33. run;

复制代码

zhanglianbo35 发表于 2014-7-14 00:23
*easy question! i think . Try the following method;

PROC IMPORT  DATAFILE= "d:\test.xls"  DBMS= x ...

很好，谢谢大神

920240553 发表于 2014-7-15 16:12
我给你一个笨方法，不用数组就可以实现你的目的，而且易懂：

这个方法也不错，谢谢您

论坛好多大神啊~