sas数据集，批量更改观测

   比如我有一个 数据集。里面有100个变量。其中有40个变量的名字是*_number 。就是以_number结尾的这些变量。
   我想把所有以number结尾的变量  乘以 一个0.8 然后赋值给自己。
   就是 这样
  比如
    data  a；
    input  id, a_number,b_number,c_number ;
    cards;
    1 100 200 300
    2 200 330 400
;
run;
    我就是要把 a_number,b_number,c_number 这三个变量 乘以 0.8 之后再赋值给a_number,b_number,c_number。
   就是 a_number = 0.8* a_number;
    因为数据集有很多个，而且每个数据集有很多 这样的变量，一个一个写很麻烦，想弄个宏， 就是_number结尾的自动 乘以0.8
    有没有大神解决下！！！

参考了一个国外文献


data  a;
input  id  a_number b_number c_number ;
cards;
1 100 200 300
2 200 330 400
;
run;

proc contents data = a
out=var_names(keep = name) noprint;
run;

data change;
set var_names;
where substr(name,length(name)-6) = "_number";
run;

data _null_;
file 'c:\change';
set change end = eof;
if _n_ = 1 then put '%let allthev= ';
put name;
if eof then do;
call symput('num' , compress(_n_));
put ';';
put 'run;';
end;
run;

%include 'c:\change';


data result;
set a;
array x[&num] &allthev;
do i = 1 to #
x{i}=0.8*x{i};
end;
drop i;
run;

有没有人

如果你的id是character variable 用array即可实现

data two;
set a ;
array change {*} _numeric_;
do i=1 to dim(change);
change{i}=0.8*change{i};
end;drop i;
run;

额抱歉啊 没看清楚 你是100个变量 只有40个需要求 但不需要求的变量里也有数值型变量是吗
我再继续想想

sas那个石家庄人 发表于 2015-6-17 10:52
如果你的id是character variable 用array即可实现

data two;

是的啊呀。

sas那个石家庄人 发表于 2015-6-17 10:39
参考了一个国外文献

很完美的解决了问题，
改进的地方有，data _null_ 这一步，可以不用，直接 proc sql ；
select name into :list separated by ' ' from change ;
select count(*) into :count from change;
quit;
allthev 对应list
num 对应 count

maomaokii 发表于 2015-6-17 15:29
很完美的解决了问题，
改进的地方有，data _null_ 这一步，可以不用，直接 proc sql ；
select name in ...

赞 用proc sql生成macro variable确实更方便！

1. data  a;
   
2.     input  id a_number b_number c_number ;
   
3.     cards;
   
4.     1 100 200 300
   
5.     2 200 330 400
   
6. ;
   
7. run;
   
8. 
   
9. data b;
   
10.   set a;
    
11. 
    
12.   array x _numeric_;
    
13.   do over x;
    
14.     x = ifn(index(vname(x),'_number'),x * 0.8,x);
    
15.   end;
    
16. run;

复制代码