数据格式转换

急盼高手相助解决

有这样一批数据，含有2个字符变量X,Y，一个数值变量n。格式如下
X    Y      n
a1   b1    2
a1   b2    0
a1   b3    5
.............
a1  b40   3
a2  b1     3
a2  b2     0
................
a2  b40   1
.................
.................
a60 b1    2
a60 b2    1
................
a60 b40  3

X代表a1-a60，Y代表b1-b40，X与Y一一对应，因此共有60*40=2400种组合，而n则代表每一种组合的数目，例如a1与b1的组合频数为2。

根据这样的数据，我们可以得到
（1）X与Y所有组合的频数，即对n求和N。
（2）X在每个取值时的频数，例如X=a1时的总个数（Y=b1,b2..........b40）
（3）Y在每个取值时的频数，例如Y=b1时的总个数（X=a1,a2..........a60）
（4）X与Y每种组合的数目，即原始n的数值



目标：
准换为含N （N为总频数）条记录，100个变量(a1,a2,a3......a60,b1,b2.......b40)的数据库。100个变量均为布尔逻辑（取值为0或1）。
新数据库为N行，100列。

要求：将原始信息（2）（3）（4）中各数值在新数据库中准确体现。注意：X与Y的组合信息。

11.xls (164.5 KB)

2010-1-6 17:08:29 上传

原始数据如附件

2# edragon1983

1. 
   
2. data a;
   
3. do i = 1 to 40;
   
4.   x = 'a'||put(i, best.-L);
   
5.   do j = 1 to 60;
   
6.    y = 'b'||put(j, best.-L);
   
7.    n = int(ranuni(1)*5);
   
8.    sum = sum(sum, n); *test variable;
   
9.    output;
   
10.   end;
    
11. end;
    
12. drop i j;
    
13. run;
    
14. *the value of SUM in last record should be the number of observations in the final dataset;
    
15. data c;
    
16. set a(where = (n ^= 0));
    
17. array arr(100) a1-a40 b1-b60 (100*0);
    
18. s = 0;
    
19. do i = 1 to dim(arr);
    
20.   arr(i) = (x = vname(arr(i)) or y = vname(arr(i)));
    
21.   s+arr(i);
    
22.   if s = 2 then leave; *leave the loop earlier;
    
23. end;
    
24. do i = 1 to n;
    
25.   output;
    
26. end;
    
27. drop i n sum s x y;
    
28. run;

复制代码

*I did not use the excel data;

不知道是不是你要的


data old;
input v1$ v2$ n;
datalines;
a1   b1    2
a1   b2    0
a1   b3    5
a1  b40   3
a2  b1     3
a2  b2     0
a2  b40   1
a60 b1    2
a60 b2    1
a60 b40  3
;
run;

data new;
set old;
do i=1 to n;
output;
end;
run;

option missing=0;
data new1(drop=v1 v2 n i);
set new;
array a{60} a1-a60;
array b{40} b1-b40;
a{substr(v1,2)}=1;
b{substr(v2,2)}=1;
run;

4# funnyxuke

oh. Yours is better-faster.

1. 
   
2. data c;
   
3. set a(where = (n ^= 0));
   
4. array arr(100) a1-a40 b1-b60 (100*0);
   
5. arr(substrn(x, 2)) = 1;
   
6. arr(substrn(y, 2)+40) = 1;
   
7. do i = 1 to n;
   
8.   output;
   
9. end;
   
10. drop i n sum  x y;
    
11. run;

复制代码

4 minutes later than your post.


5# jingju11

Here is the one that will do reasonable fast.

1) The idea is to have the table with all variables a1-a60 + b1-b40 with all values set to '0'.
2) check the observation with n >0
   if it is true, calculate the index for a and b to set the corresponding variables to 1, to repeat n times and to output it.
3) reset the updated variables in 2) to '0'




proc import datafile="C:\Downloads\100106170823e2156bd060f7b3.xls"
                    out=wksht
                    dbms=Excel replace;
run;

data needs;
array a(*) a1-a60;
array b(*) b1-b40;
retain a1-a60 b1-b40 (100*0);
set wksht;

if n>0 then do;
indexa=input(compress(upcase(x),'A'),best.);
indexb=input(compress(upcase(y),'B'),best.);
do i=1 to n;
       a(indexa) =1;
    b(indexb) =1;
    output;
end;
       a(indexa) =0;
    b(indexb) =0;
end;
keep a: b:;
run;

谢谢各位朋友的热心帮助！谢谢funnyxuke！bobguy！jingju11！
问题已解决！

版主，怎么把论坛币给热心人啊？